Topic: intersect line draw

[dussla]

sorry sorry for many ask   
really sorry

i am making  patter line
if you see my attached file . you can understand my work
in my work , that pattern is used often
it is difficult  to make that pattern withmy poor lisp skill

pls  can you make me that lisp

[irneb]

Try this one:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun c:PatternLine  (/ p1 p2 ss en par baseline dir wid ptlst n pt)
4.   (if (and (setq p1 (getpoint "Pick 1st point of crossing line: "))
5.            (setq p2 (getpoint p1 "Pick 2nd point of crossing line: "))
6.            (setq ss (ssget "_F" (list p1 p2) '((0 . "LWPOLYLINE")))))
7.     (progn (setq ss       (ssnamex ss)
8.                  en       (cadar ss)
9.                  par      (vlax-curve-getParamAtPoint en (cadr (cadddr (car ss))))
10.                  wid      (/ (- (vlax-curve-getDistAtParam en (1+ (fix par))) (vlax-curve-getDistAtParam en (fix par))) 2.)
11.                  dir      (apply 'angle
12.                                  (list (vlax-curve-getPointAtParam en par)
13.                                        (vlax-curve-getPointAtParam
14.                                          en
15.                                          (if (< (- par (fix par)) 0.5)
16.                                            (fix par)
17.                                            (1+ (fix par))))))
18.                  baseline (list (polar p1 dir wid) (polar p2 dir wid))
19.                  n        0
20.                  ptlst    (list (car baseline)))
21.            (foreach lst  ss
22.              (setq en    (cadr lst)
23.                    pt    (vlax-curve-getClosestPointTo en (cadr (cadddr lst)) t)
24.                    p1    (apply 'inters (append baseline (list pt (polar pt dir wid))))
25.                    p2    (polar p1 dir wid)
26.                    ptlst (if (= (rem n 2) 0)
27.                            (cons p2 (cons p1 ptlst))
28.                            (cons p1 (cons p2 ptlst)))
29.                    n     (1+ n)))
30.            (setq ptlst (cons (if (= (rem n 2) 0)
31.                                (cadr baseline)
32.                                (polar (cadr baseline) dir wid))
33.                              ptlst))
34.            (entmake
35.              (append '((0 . "LWPOLYLINE") (100 . "AcDbEntity"))
36.                      (list (cons 67
37.                                  (if (> (getvar 'CVport) 1)
38.                                    0
39.                                    1))
40.                            (cons 8 (getvar 'CLayer)))
41.                      '((100 . "AcDbPolyline"))
42.                      (list (cons 90 (length ptlst)))
43.                      '((70 . 0) (43 . 0.0) (38 . 0.0) (39 . 0.0))
44.                      (apply 'append
45.                             (mapcar '(lambda (pt) (cons (cons 10 pt) '((40 . 0.0) (41 . 0.0) (42 . 0.0) (91 . 0))))
46.                                     (reverse ptlst)))
47.                      '((210 0.0 0.0 1.0))))))
48.   (princ))