Topic: (cdddddddddddddddr Lst)

[Grrr1337]

Hi guys,
Any idea how to write such function that returns a list starting from nth x position ?

Code: [Select]

Lst ; a 1
(cdr Lst) ; b 2
(cddr Lst) ; c 3
(cdddr Lst) ; d 4
(cddddr Lst) ; e 5

Code: [Select]

(cdddddr Lst) ; f 6 ???
(cddddddr Lst) ; g 7 ???
                ...My brain is stuck today.
EDIT:
Figured something with an old function I had:

Code: [Select]

_$ (defun ShiftListRightRepeat ( n Lst / nLst )
(if (and (= 'INT (type n)) (listp Lst))
(progn
(setq nLst Lst)
(repeat n (setq nLst (append (cdr nLst) (list (car nLst)))))
)
)
nLst
); defun ShiftListRightRepeat
SHIFTLISTRIGHTREPEAT
_$ (setq Lst (mapcar 'chr (vl-string->list "ABCDEFGHIJKLMNOPQ")))
("A" "B" "C" "D" "E" "F" "G" "H" "I" "J" "K" "L" "M" "N" "O" "P" "Q")
_$ (ShiftListRightRepeat 1 Lst)
("B" "C" "D" "E" "F" "G" "H" "I" "J" "K" "L" "M" "N" "O" "P" "Q" "A")
_$ (ShiftListRightRepeat 2 Lst)
("C" "D" "E" "F" "G" "H" "I" "J" "K" "L" "M" "N" "O" "P" "Q" "A" "B")
_$ (ShiftListRightRepeat 3 Lst)
("D" "E" "F" "G" "H" "I" "J" "K" "L" "M" "N" "O" "P" "Q" "A" "B" "C")
_$ (ShiftListRightRepeat 4 Lst)
("E" "F" "G" "H" "I" "J" "K" "L" "M" "N" "O" "P" "Q" "A" "B" "C" "D")
_$ (ShiftListRightRepeat 5 Lst)
("F" "G" "H" "I" "J" "K" "L" "M" "N" "O" "P" "Q" "A" "B" "C" "D" "E")
_$ 

[CAB]

Look at this old thread http://www.theswamp.org/index.php?topic=50539

[MP]

There are an abundant number of ways to do it but a simple, nominal code, recursively flavored one might be:

Code: [Select]

(defun cdrn ( n lst )
    (if (and lst (< 0 n))
        (cdrn (1- n) (cdr lst))
        lst
    )
)
(cdrn 7 '(0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15))

>> (7 8 9 10 11 12 13 14 15)

It's not overly efficient but sometimes uber efficient is not needed. Anyways ... cheers.

[Grrr1337]

Thanks alot guys!

[ribarm]

Maybe just :

Code: [Select]

(defun cdrn ( n l )
  (repeat n
    (setq l (cdr l))
  )
  l
)


[Grrr1337]

Maybe just :

Code: [Select]

(defun cdrn ( n l )
  (repeat n
    (setq l (cdr l))
  )
  l
)


Thats even simplier, reminds me about iterating thru list!
By the way should "l" be localised ? (defun cdrn (n l / l) ... ) - no?

[MP]

it's already localised

[MP]

i.e.

(setq lst '(0 1 2 3 4 5 6 7))

(princ (cdrn 3 lst)) >> (3 4 5 6 7)

(princ lst)          >> (0 1 2 3 4 5 6 7)

[Grrr1337]

Thanks mr.Puckett, I'm still a dummy lisper.

[MP]

You are no dummy and you are most welcome.

[Lee Mac]

Another, for a minor increase in performance for long lists:

Code - Auto/Visual Lisp: [Select]

1. (defun cdrn ( n l )
2.     (repeat (/   n 4) (setq l (cddddr l)))
3.     (repeat (rem n 4) (setq l (cdr    l)))
4.     l
5. )

[Lee Mac]

And another:

Code - Auto/Visual Lisp: [Select]

1. (defun cdrn ( n l )
2.     (vl-member-if '(lambda ( x ) (minusp (setq n (1- n)))) l)
3. )

[Grrr1337]

And another:

Code: [Select]

(defun cdrn ( n Lst )
(member (nth n Lst) Lst)
)

[roy_043]

@Grrr1337:
Your last suggestion is problematic if the list contains duplicate items.

[Grrr1337]

@Grrr1337:
Your last suggestion is problematic if the list contains duplicate items.

Damn, you are correct.