Topic: Find 2 nearest intersection point from text insertion

[m4rdy]

How do we find two nearest intersection point from text insertion point?
Thank you.


m4rdy

[Lee Mac]

• Make a SelectionSet of all candidate lines
• Find all points of intersection between all objects within such a SelectionSet (example here)
• Sort the list of intersection points by distance to a certain point.

[Kerry]

Not covered by the spec' ..
will the text always be parallel with the concrete beam centerLine ( I assume you are endeavouring to extract the beam length)

I can see some problems with just accepting the closest points to the text.
Perhaps determine the closest centerline then find the intersection of intersecting candidates ... etc

[m4rdy]

Hi Kerry

...
will the text always be parallel with the concrete beam centerLine ( I assume you are endeavouring to extract the beam length)
....

Yes, the text always be parallel with the concrete beam centerline.
And Yes, i need to make polylines from those 2 points and the end result is finding the beam length.

...
I can see some problems with just accepting the closest points to the text.
Perhaps determine the closest centerline then find the intersection of intersecting candidates ... etc

Yes again, that's my problem.

So far, this is my pseudo code:
1. Get all insertion point of texts in "BEAM" layer
2. Get all intersection points of line in "GRID" layer
3. Find the nearest GRID line from each of insertion text
4. Find 2 nearest intersection point from result no.3
5. Make polyline from result no.4

I hope that makes more clearly (or not... )

Thank you Lee Mac and Kerry.

m4rdy

[Lee Mac]

Draft of my pseudo code - as Kerry states though, this method is not bullet-proof.

Code: [Select]

(defun c:test ( / pt ss in ) (vl-load-com)
  (if
    (and
      (setq pt (getpoint "\nPoint to Test: "))
      (setq ss (ssget "_X" '((0 . "LINE") (8 . "GRID"))))
      (setq in (LM:GetIntersectionsinSS ss))
      (< 1 (length in))
    )
    (progn
      (setq pt (trans pt 1 0)
            in (vl-sort in '(lambda ( a b ) (< (distance a pt) (distance b pt))))
      )
      (foreach x (list (car in) (cadr in))
        (entmakex (list (cons 0 "POINT") (cons 10 x)))
      )
    )
  )
  (princ)
)

[m4rdy]

Wow, so fast reply.
Thank you Lee.
Much appreciated.

m4rdy

[CAB]

So what are you doing with the text you collect?

[m4rdy]

So what are you doing with the text you collect?

Hi Alan,
For finding insertion point of each text as base point to find two nearest intersection points.

m4rdy

[m4rdy]

Code: [Select]

;; Entmake lwpolyline
(defun LWPoly (lst cls)
  (entmakex
    (append (list (cons 0 "LWPOLYLINE")
 (cons 100 "AcDbEntity")
 (cons 100 "AcDbPolyline")
 (cons 90 (length lst))
 (cons 70 cls);_0 = open 1 = closed
 (cons 40 10.)
 (cons 41 10.)  
   )
   (mapcar (function (lambda (p) (cons 10 (trans p 0 1)))) lst)
    )
  )
)

;; Get insertion point of text
;; Return : ((ename1 (ins_point1)) (ename2 (ins_point2))...)

(defun get-ins-txt (sset / i j ent sset entl ins_point)
  (setq i -1)
  (while (setq ent (ssname sset (setq i (1+ i))))
    (setq entl (entget ent)
 ins_point (cons (cons ent (list (cdr (assoc 10 entl))))  ins_point)
    )
  )
)

;; Original from Lee mac
;; modified by m4rdy

(defun c:beam (/ pt ss1 ss2 in ins_txt)
  (vl-load-com)
  (princ "SELECT BEAM TEXT")
  (setq ss1 (ssget "_X" '((0 . "LINE") (8 . "GRID"))))
  (setq ss2 (ssget '((0 . "TEXT") (8 . "BEAM"))))
  (setq in (LM:GetIntersectionsinSS ss1))
  (setq ins_txt (get-ins-txt ss2))
  (if (and ss1 ss2 (< 1 (length in)))
    (progn
      (foreach x ins_txt
(setq pt (trans (cadar ins_txt) 1 0)
     in (vl-sort in
 '(lambda (a b) (< (distance a pt) (distance b pt)))
)
)
(LWPoly (list (car in) (cadr in)) 0)
      ) ;_foreach
    ) ;_progn
  ) ;_if
  (princ)
)
I have some troubles with 'foreach'.
If anybody can help..
Thank you

m4rdy

[Lee Mac]

Hi M4rdy,

Perhaps try something like this:

Code: [Select]

;; Entmake lwpolyline
(defun LWPoly (lst cls)
  (entmakex
    (append (list (cons 0 "LWPOLYLINE")
  (cons 100 "AcDbEntity")
  (cons 100 "AcDbPolyline")
  (cons 90 (length lst))
  (cons 70 cls);_0 = open 1 = closed
  (cons 40 10.)
  (cons 41 10.)  
    )
    (mapcar (function (lambda (p) (cons 10 (trans p 0 1)))) lst)
    )
  )
)

(defun LM:GetTextInsertion ( eList )
  (cdr
    (assoc
      (if
        (and
          (zerop (cdr (assoc 72 elist)))
          (zerop (cdr (assoc 73 elist)))
        )
        10 11
      )
      elist
    )
  )
)

;; Original from Lee Mac
;; modified by m4rdy

(defun c:beam ( / ss1 ss2 in en pt i ) (vl-load-com)

  (princ "\nSelect Beam Text: ")
  (if
    (and
      (setq ss1 (ssget "_X" '((0 . "LINE") (8 . "GRID"))))
      (setq ss2 (ssget '((0 . "TEXT") (8 . "BEAM"))))
      (setq in (LM:GetIntersectionsinSS ss1))
      (< 1 (length in))
    )
    (repeat (setq i (sslength ss2))
      (setq en (ssname ss2 (setq i (1- i)))
            pt (trans (LM:GetTextInsertion (entget en)) en 0)
            in (vl-sort in '(lambda ( a b ) (< (distance a pt) (distance b pt))))
      )
      (LWPoly (list (car in) (cadr in)) 0)
    )
  )
  (princ)
)

[m4rdy]

Hi M4rdy,

Perhaps try something like this:

Code: [Select]

;; Entmake lwpolyline
(defun LWPoly (lst cls)
  (entmakex
    (append (list (cons 0 "LWPOLYLINE")
  (cons 100 "AcDbEntity")
  (cons 100 "AcDbPolyline")
  (cons 90 (length lst))
  (cons 70 cls);_0 = open 1 = closed
  (cons 40 10.)
  (cons 41 10.)  
    )
    (mapcar (function (lambda (p) (cons 10 (trans p 0 1)))) lst)
    )
  )
)

(defun LM:GetTextInsertion ( eList )
  (cdr
    (assoc
      (if
        (and
          (zerop (cdr (assoc 72 elist)))
          (zerop (cdr (assoc 73 elist)))
        )
        10 11
      )
      elist
    )
  )
)

;; Original from Lee Mac
;; modified by m4rdy

(defun c:beam ( / ss1 ss2 in en pt i ) (vl-load-com)

  (princ "\nSelect Beam Text: ")
  (if
    (and
      (setq ss1 (ssget "_X" '((0 . "LINE") (8 . "GRID"))))
      (setq ss2 (ssget '((0 . "TEXT") (8 . "BEAM"))))
      (setq in (LM:GetIntersectionsinSS ss1))
      (< 1 (length in))
    )
    (repeat (setq i (sslength ss2))
      (setq en (ssname ss2 (setq i (1- i)))
            pt (trans (LM:GetTextInsertion (entget en)) en 0)
            in (vl-sort in '(lambda ( a b ) (< (distance a pt) (distance b pt))))
      )
      (LWPoly (list (car in) (cadr in)) 0)
    )
  )
  (princ)
)

Thank you very much, Lee Mac.
Now, It's done very well.

m4rdy

[Lee Mac]

You're welcome M4rdy, happy to help you along the way