Topic: Tag width adjusted in Title Block attribute

[jlogan02]

Micheal Puckett wrote this piece of code for me earlier this year and I've updated a couple of times to my liking. I just added the ability to let the user pick the TitleLine whose width they want to adjust.

It works fine in that it adjusts a TitleLine that extends outside the title block. However, it doesn't seem to matter where on the attribute a user picks. The routine simply adjust whichever TitleLine overruns the title block. So if TitleLine1 is wider than the title block and a user picks TitleLine4 or just somewhere on the attribute, the routine adjusts TitleLine1. But that's not how it should work. It should be, Pick the TitleLine you want to adjust. Not just pick anywhere. Or maybe it shouldn't. As long as it's working. My guess is that any text that is wider than 5.25 gets adjust down. I haven't tried expanding any of the other attribute lines to see because their width will never be larger than what is already specified. The concern is really just TitleLines1,2, & 3

At any rate. I'd like to know where I've gone wrong.

Code - Auto/Visual Lisp: [Select]

1. ;;Adjusts any selected TitleLine whose text is wider than the defined width of the title block.
2. ;;User selects the STA_TW button and then selects desired text.
3. ;;
4. ;;4-12-2018 Routine created by Michael Puckett @ CAD ANALYST
5. ;;4-12-2018 Modified by Jerry Logan
6. ;;4-12-2018 Added functionality for use with dimscale.
7. ;;9-28-2018 Added user selection to change width of any tag that is outside the title block lines.
8. ;;
9. ;;After select STA_TW button select attribute. The routine will find any TitleLine that is wider than the
10. ;;title block allows and adjust it's width to fit inside the title block.
11. ;;
12. ;;Command: STA_ATT_WIDTH
13. ;;
14. ;;
15.  
16.  
17. (defun mpx-get-bounding-box ( object / a b )
18.     (vl-catch-all-apply 'vlax-invoke-method (list object 'GetBoundingBox 'a 'b))
19.     (if a (mapcar 'vlax-safearray->list (list a b)))
20. )
21.  
22. (defun mpx-restrict-attrib-widths ( block-reference tag-spec max-width / bb dx ratio flag )
23.     (and
24.         (eq 'vla-object (type block-reference))
25.         (eq "AcDbBlockReference" (vla-get-objectname block-reference))
26.         (eq :vlax-true (vla-get-hasattributes block-reference))
27.         (setq tag-spec (strcase (if (eq 'str (type tag-spec)) tag-spec "*")))
28.         (foreach a (vlax-invoke block-reference 'GetAttributes)
29.             (and
30.                 (wcmatch (vla-get-tagstring a) tag-spec)
31.                 (setq bb (mpx-get-bounding-box a))
32.                 (setq dx (abs (apply '- (mapcar 'car bb))))
33.                 (< 1.0 (setq ratio (/ dx max-width)))
34.                 (setq flag t)
35.                 (vla-put-scalefactor a (* (vla-get-scalefactor a) (/ 1.0 ratio)))
36.             )
37.        
38.         )
39.         (if flag (vla-update block-reference))
40.     )
41.     (princ)
42. )
43.  
44. (defun c:STA_ATT_WIDTH ( / block-spec tag-spec max-width ss i )
45.  
46.  (vl-load-com)
47.    (setq temperr *error*)
48.    (setq *errer* trap1)
49.    (setq oldecho (getvar "cmdecho"))
50.    (setvar "cmdecho" 0)
51. ;;--------------------------------
52. ;;This was Micheal's original code
53. ;;(setq
54.        ;;block-spec "TBLK_ATT_CTL"
55.         ;;tag-spec   "Desired TitleLine tag goes here"
56.         ;;max-width  (* 5.25 (getvar 'dimscale));;multiply 5.25 dimscale
57.         ;;)
58.  
59. ;;--------------------------------
60. ;;This is how I changed it
61. (setq
62.         block-spec "TBLK_ATT_CTL"
63.         max-width  (* 5.25 (getvar 'dimscale));;multiply 5.25 dimscale
64.         )
65.    (setq tag-spec (entsel "\nselect TitleLine: ")  ;;removed tag-spec "TitleLine#"
66.        
67.         )
68. ;;------------------------------
69.    
70.  (if (setq ss (ssget "x" (list '(0 . "insert")'(66 . 1)(cons 2 block-spec))))
71.         (repeat (setq i (sslength ss))
72.             (mpx-restrict-attrib-widths
73.                 (vlax-ename->vla-object (ssname ss (setq i (1- i))))
74.                 tag-spec
75.                 max-width
76.             )
77.         )
78.     )
79.     (setvar "cmdecho" oldecho)
80.     (princ)
81.    
82. )
83.  
84. (defun trap1 ( / errmsg)
85.     (command "u" "b")
86.     (setvar "cmdecho" oldecho)
87.     (setq *errer* temperr)
88.     (prompt "\nResetting System Variables ")
89.   (princ)
90. )

J. Logan

[Dlanor]

Just an observation from my initial scanning of the code, but in MP's original code "tag-spec" variable was set to a string. Your modification is setting it to an entsel selection list.

To select an attribute within a block you need to use nentsel and then get the tagstring.

Line No 65

Code - Auto/Visual Lisp: [Select]

1.  (setq tag-spec (vlax-get-property (vlax-ename->vla-object (car (nentsel "\nselect TitleLine: "))) 'tagstring))