Author Topic: Toggle background fill color on a Dimension (Read 7408 times)

Mark · « **on:** August 13, 2012, 11:19:20 AM »

I want to write a program to toggle the background color of a dimension, ie. background mask. I want to use Fill Color of 'Background'. When I dump properties on a dimension I don't see TextFillColor change from 0 or TextFill change from 0.

Example (no background fill):
; TextColor = 0
; TextFill = 0
; TextFillColor = 0

Example (background fill color 1):
; TextColor = 0
; TextFill = -1
; TextFillColor = 1

Example (background fill color 'Background'):
; TextColor = 0
; TextFill = 0
; TextFillColor = 0

So how is one supposed to toggle this using autolisp?

CAB · « **Reply #1 on:** August 13, 2012, 11:40:00 AM »

Haven't tried it:
http://www.theswamp.org/index.php?topic=39217.0

Did you need plain lisp only?

Mark · « **Reply #2 on:** August 13, 2012, 11:44:45 AM »

Thanks Alan, i'll look it over.

Don't know why i didn't do a search. oop's

Lee Mac · « **Reply #3 on:** August 13, 2012, 12:33:56 PM »

To toggle the background fill on/off, you should be able to use simply:

Code - Auto/Visual Lisp: [Select]

(defun c:dimmask ( / en ob )
    (if
        (and
            (setq en (car (entsel "\nSelect Dimension: ")))
            (wcmatch (cdr (assoc 0 (entget en))) "*DIMENSION")
            (setq ob (vlax-ename->vla-object en))
        )
        (vlax-put ob 'textfill (~ (vlax-get ob 'textfill)))
    )
    (princ)
)

Mark · « **Reply #4 on:** August 13, 2012, 01:08:04 PM »

Quote from: Lee Mac on August 13, 2012, 12:33:56 PM

To toggle the background fill on/off, you should be able to use simply:

that sets Fill Color to 'ByBlock'.

Mark · « **Reply #5 on:** August 13, 2012, 01:20:55 PM »

I don't see anyway of knowing when the dim has fill color set to 'background'.

Lee Mac · « **Reply #6 on:** August 13, 2012, 01:25:26 PM »

Quote from: Mark on August 13, 2012, 01:08:04 PM

Quote from: Lee Mac on August 13, 2012, 12:33:56 PM
To toggle the background fill on/off, you should be able to use simply:
that sets Fill Color to 'ByBlock'.

Sorry, I should have clarified - it will simply switch the Text Fill on and off, the Text fill will use the fill colour as set in the Dim Style or by an Override. I think I misunderstood your intention

Mark · « **Reply #7 on:** August 13, 2012, 01:31:40 PM »

Quote from: Lee Mac on August 13, 2012, 01:25:26 PM

Quote from: Mark on August 13, 2012, 01:08:04 PM
Quote from: Lee Mac on August 13, 2012, 12:33:56 PM
To toggle the background fill on/off, you should be able to use simply:
that sets Fill Color to 'ByBlock'.

Sorry, I should have clarified -

No problem.

I can use the dimstyle setting and forget about programming for now.

Lee Mac · « **Reply #8 on:** August 13, 2012, 01:33:56 PM »

Quote from: Mark on August 13, 2012, 01:20:55 PM

I don't see anyway of knowing when the dim has fill color set to 'background'.

It would appear that the Dimension Style Override for a Background Text Fill Colour is Override Code 69:

Code - Auto/Visual Lisp: [Select]

  (
    (0 . "DIMENSION")
    (5 . "52F")
 
 ... < irrelevant group codes removed > ...
 
    (100 . "AcDbRotatedDimension")
    (-3
      (
        "ACAD"
        (1000 . "DSTYLE")
        (1002 . "{")
        (1070 . 69) ;; <--------------- Background Text Fill Colour
        (1070 . 1)  ;; <--------------- Background Text Fill Colour
        (1002 . "}")
      )
    )
  )

Mark · « **Reply #9 on:** August 13, 2012, 01:37:04 PM »

Thank ya sir!

kruuger · « **Reply #10 on:** August 13, 2012, 03:34:54 PM »

Quote from: Lee Mac on August 13, 2012, 12:33:56 PM

To toggle the background fill on/off, you should be able to use simply:

Code - Auto/Visual Lisp: [Select]
(defun c:dimmask ( / en ob )
(if
(and
(setq en (car (entsel "\nSelect Dimension: ")))
(wcmatch (cdr (assoc 0 (entget en))) "*DIMENSION")
(setq ob (vlax-ename->vla-object en))
)
(vlax-put ob 'textfill (~ (vlax-get ob 'textfill)))
)
(princ)
)

this one work well <=2009. from 2010 autodesk messed up :realmad: textfill

i'm using this. little bit crappy but works for 90% cases:

Code - Auto/Visual Lisp: [Select]

(Defun C:BMM (/ lst object SC STYL)
  (vl-load-com)
  (setq lst (entsel "\nSelect dimension object: "))
  (setq object (car lst))
  (setq object (vlax-ename->vla-object object))
  (if (wcmatch (vla-get-objectname object) "AcDb*Dimension")
    (progn
      (setq STYL (vla-get-StyleName object))
      (command ".dimstyle" "r" STYL)
      (setq SC (vla-get-ScaleFactor object))
      (setvar "dimscale" SC)
      (setvar "dimtfill" 1)
      (command "DIM1" "UPDATE" lst "")
      (command ".draworder" (car lst) "" "front")
      (setvar "dimtfill" 0)
    );progn
  );if
)

kruuger

kruuger · « **Reply #11 on:** August 13, 2012, 03:57:43 PM »

Quote from: kruuger on August 13, 2012, 03:34:54 PM

messed up

Quote from: kruuger on August 13, 2012, 03:34:54 PM

crappy

rlxozzang · « **Reply #12 on:** August 16, 2012, 03:04:37 AM »

my routine is

Code: [Select]

(defun c:TextFill (/ ent)
	(setq ent (nentsel));mtext,dimension
	(if (= (vla-get-backgroundfill (vlax-ename->vla-object (car ent))) :vlax-false)
		(progn
			(vla-put-backgroundfill (vlax-ename->vla-object (car ent)) :vlax-true)
			(entmod (subst (cons 45 1.1) (assoc 45 (entget (car ent))) (entget (car ent))))
		)
		(vla-put-backgroundfill (vlax-ename->vla-object (car ent)) :vlax-false)
	)
	(vla-regen (vla-get-activedocument (vlax-get-acad-object)) acActiveViewport)
	(princ)
)

News: