Topic: mleader with lenght field

[sport]

I´m trying to create a lisp, by try and error, and copy paste of several sources (sorry if i dont put the credits here... i dont remember, any way. I want to be able to click a polyline and add an mleader with its area or length as a field. But i cant make it work. Can you please help me

(defun c:test (/ p1 p2 obj )
 (vl-load-com)
 (if (and (setq p1 (getpoint "\nPick First Point: "))
          (setq p2 (getpoint "\nPick Next Point: " p1))
     )
 

   (progn
     (setq obj
            (vlax-invoke
              (vlax-get (vla-get-ActiveDocument (vlax-get-acad-object))
                        (if (= 1 (getvar 'CVPORT))
                          'PaperSpace
                          'ModelSpace
                        )
              )
              'AddMLeader
              (append p1 p2)
              0
            )
     )
 
   (setq s
                              (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                                      (itoa (vla-get-objectid (vlax-ename->vla-object (car (entsel "\nSeleccione Objeto: ")))))
                                      ">%).Area \\f \"%lu2%pr2%th44\">%"
                                      " m{\\H0.7x;\\S2^;}")))
   
   
 )
    (vla-put-textstring obj s)
 (princ)
)

[ronjonp]

Welcome  to TheSwamp .. give this a try:

Code - Auto/Visual Lisp: [Select]

1. (defun c:test (/ e obj p1 p2 s)
2.   (vl-load-com)
3.   (while (and (setq e (entsel "\nSeleccione Objeto: "))
4.               (setq p1 (cadr e))
5.               (vlax-property-available-p (setq e (vlax-ename->vla-object (car e))) 'area)
6.               (setq p2 (getpoint p1 "\nPick a point: "))
7.               (setq obj (vlax-invoke
8.                           (vlax-get (vla-get-activedocument (vlax-get-acad-object))
9.                                     (if (= 1 (getvar 'cvport))
10.                                       'paperspace
11.                                       'modelspace
12.                                     )
13.                           )
14.                           'addmleader
15.                           (append p1 p2)
16.                           0
17.                         )
18.               )
19.          )
20.     (vla-put-textstring
21.       obj
22.       (strcat "%<\\AcObjProp Object(%<\\_ObjId "
23.               (itoa (vla-get-objectid e))
24.               ">%).Area \\f \"%lu2%pr2%th44\">%"
25.               " m{\\H0.7x;\\S2^;}"
26.       )
27.     )
28.     (command "_.regen")
29.   )
30.   (princ)
31. )

[sport]

Thanks ronjonp!!! It works perfect

Welcome  to TheSwamp .. give this a try:

Code - Auto/Visual Lisp: [Select]

1. (defun c:test (/ e obj p1 p2 s)
2.   (vl-load-com)
3.   (while (and (setq e (entsel "\nSeleccione Objeto: "))
4.               (setq p1 (cadr e))
5.               (vlax-property-available-p (setq e (vlax-ename->vla-object (car e))) 'area)
6.               (setq p2 (getpoint p1 "\nPick a point: "))
7.               (setq obj (vlax-invoke
8.                           (vlax-get (vla-get-activedocument (vlax-get-acad-object))
9.                                     (if (= 1 (getvar 'cvport))
10.                                       'paperspace
11.                                       'modelspace
12.                                     )
13.                           )
14.                           'addmleader
15.                           (append p1 p2)
16.                           0
17.                         )
18.               )
19.          )
20.     (vla-put-textstring
21.       obj
22.       (strcat "%<\\AcObjProp Object(%<\\_ObjId "
23.               (itoa (vla-get-objectid e))
24.               ">%).Area \\f \"%lu2%pr2%th44\">%"
25.               " m{\\H0.7x;\\S2^;}"
26.       )
27.     )
28.     (command "_.regen")
29.   )
30.   (princ)
31. )

[alanjt]

I like to use this subroutine to mimic the mleader command - I mainly just like seeing the arrow and landing as I'm picking it's location.

Code: [Select]

(defun AT:MLeaderDraw (point / *error* elast)
  ;; Dynamically place a Multileader and have EName returned
  ;; point - starting point (must be UCS)
  ;; Alan J. Thompson, 04.11.11
  (defun *error* (m) (and cmd (setvar 'CMDECHO cmd)) elast)
  (if (and (vl-consp point) (getcname "mleader"))
    (progn (setq cmd (getvar 'CMDECHO))
           (setq elast (entlast))
           (setvar 'CMDECHO 0)
           (princ "\nSpecify other point: ")
           (vl-cmdf "_.mleader" "_non" point PAUSE)
           (while (eq 1 (logand 1 (getvar 'CMDACTIVE))) (vl-cmdf ""))
           (and (equal elast (setq elast (entlast))) (setq elast nil))
           (*error* nil)
    )
  )
)

[ronjonp]

Thanks ronjonp!!! It works perfect

Welcome  to TheSwamp .. give this a try:

Code - Auto/Visual Lisp: [Select]

1. ...

Glad to help