Topic: Detect AutoCAD version

[Daniel J. Ellis]

I've been using R2011, which has a wonderful feature as part of its hatch routine to specify the layer the hatch's going to be inserted on.

This is great, until you have a routine that sets the current to where you want the hatch to go to and freezes off the random layer you had been hatching on!

I'm the only one in the office using R2011 (everyone else uses R2010) so I need a way to detect which version of AutoCAD is being run so I can do the appropriate thing with my hatch command!

Is this something that can be done with LISP?

dJE

[CAB]

http://en.wikipedia.org/wiki/.dwg

No info on 2011 yet.

There are many ways to do it.

Drawing version
http://www.theswamp.org/index.php?topic=6774.msg333989#msg333989

ACAD version

Code: [Select]

((= (rtos(atof(getvar "ACADVER"))2 2) "15.00") 2000))
 ((= (rtos(atof(getvar "ACADVER"))2 2) "15.05") 2000i))
 ((= (rtos(atof(getvar "ACADVER"))2 2) "15.06") 2002))
 ((= (rtos(atof(getvar "ACADVER"))2 2) "16.00") 2004))
 ((= (rtos(atof(getvar "ACADVER"))2 2) "16.10") 2005))
 ((= (rtos(atof(getvar "ACADVER"))2 2) "16.20") 2006))
 ((= (rtos(atof(getvar "ACADVER"))2 2) "17.00") 2007)) ; 7 8 9
 ((= (rtos(atof(getvar "ACADVER"))2 2) "18.00") 2010))

[VVA]

Code: [Select]

(defun whatAcadVer ( / Aver)
(setq Aver (atof (substr (getvar "ACADVER") 1 4)))
(cond
((= Aver 18.0) 2010) 
((= Aver 17.2) 2009)
((= Aver 17.1) 2008)
((= Aver 17.0) 2007)
((= Aver 16.2) 2006)   
((= Aver 16.1) 2005)
((= Aver 16.0) 2004)
((= Aver 15.06) 2002)
(t 2011)
)
)

[alanjt]

Code: [Select]

(defun Version? (/)
  (cdr (assoc (atof (substr (getvar 'ACADVER) 1 4))
              '((18.1 . 2011)
                (18.0 . 2010)
                (17.2 . 2009)
                (17.1 . 2008)
                (17.0 . 2007)
                (16.2 . 2006)
                (16.1 . 2005)
                (16.0 . 2004)
                (15.06 . 2002)
               )
       )
  )
)

[yarik]

Hi, maybe this can help

Code: [Select]



(defun acadvers()
(setq acad(atof(vlax-get-property (vlax-get-acad-object) 'version)))
(if (= acad 18.1)
(setq vers "ACAD2011")
)
(if (= acad 18.0)
(setq vers "ACAD2010")
)
vers
)


[ronjonp]

Another approach ... although I'm sure it can be broken 

Code: [Select]

(defun getacadversion (/ path)
  (if (setq path (findfile "acad.exe"))
    (apply
      'strcat
      (mapcar 'chr (vl-remove-if-not '(lambda (x) (and (> x 47) (< x 58))) (vl-string->list path)))
    )
  )
)
(getacadversion)

;;Returns "2009"

[alanjt]

Another approach ... although I'm sure it can be broken 

Code: [Select]

(defun getacadversion (/ path)
  (if (setq path (findfile "acad.exe"))
    (apply
      'strcat
      (mapcar 'chr (vl-remove-if-not '(lambda (x) (and (> x 47) (< x 58))) (vl-string->list path)))
    )
  )
)
(getacadversion)

;;Returns "2009"

Code: [Select]

Command: (findfile "acad.exe")
"C:\\Program Files\\Autodesk\\AutoCAD Civil 3D 2011\\acad.exe"Returns: "32011"

Very cool idea. Way to think outside the box.

[ronjonp]

Another approach ... although I'm sure it can be broken 

Code: [Select]

(defun getacadversion (/ path)
  (if (setq path (findfile "acad.exe"))
    (apply
      'strcat
      (mapcar 'chr (vl-remove-if-not '(lambda (x) (and (> x 47) (< x 58))) (vl-string->list path)))
    )
  )
)
(getacadversion)

;;Returns "2009"

Code: [Select]

Command: (findfile "acad.exe")
"C:\\Program Files\\Autodesk\\AutoCAD Civil 3D 2011\\acad.exe"Returns: "32011"

Very cool idea. Way to think outside the box.

Thanks Alan ... perhaps this will fix it:

Code: [Select]

(defun getacadversion (/ path)
  (and (setq path (findfile "acad.exe"))
       (setq path (vl-remove-if-not '(lambda (x) (and (> x 47) (< x 58))) (vl-string->list path)))
       (setq path (apply 'strcat (mapcar 'chr path)))
       (setq path (substr path (- (1+ (strlen path)) 4)))
  )
  path
)
(getacadversion)

[alanjt]

Another approach ... although I'm sure it can be broken 

Code: [Select]

(defun getacadversion (/ path)
  (if (setq path (findfile "acad.exe"))
    (apply
      'strcat
      (mapcar 'chr (vl-remove-if-not '(lambda (x) (and (> x 47) (< x 58))) (vl-string->list path)))
    )
  )
)
(getacadversion)

;;Returns "2009"

Code: [Select]

Command: (findfile "acad.exe")
"C:\\Program Files\\Autodesk\\AutoCAD Civil 3D 2011\\acad.exe"Returns: "32011"

Very cool idea. Way to think outside the box.

Thanks Alan ... perhaps this will fix it:

Code: [Select]

(defun getacadversion (/ path)
  (and (setq path (findfile "acad.exe"))
       (setq path (vl-remove-if-not '(lambda (x) (and (> x 47) (< x 58))) (vl-string->list path)))
       (setq path (apply 'strcat (mapcar 'chr path)))
       (setq path (substr path (- (1+ (strlen path)) 4)))
  )
  path
)
(getacadversion)

Slight variant...

Code: [Select]

(defun getacadversion (/ path)
  (if (setq path (findfile "acad.exe"))
    ((lambda (str) (substr str (- (1+ (strlen str)) 4)))
      (vl-list->string
        (vl-remove-if-not (function (lambda (x) (and (> x 47) (< x 58)))) (vl-string->list path))
      )
    )
  )
)

[Chris]

personally I prefer this:

Code: [Select]

(atoi (vl-string-right-trim " (en)" (vl-string-left-trim "Visual LISP " (ver))))

[alanjt]

personally I prefer this:

Code: [Select]

(atoi (vl-string-right-trim " (en)" (vl-string-left-trim "Visual LISP " (ver))))

Code: [Select]

(defun getacadversion (/)
  (vl-list->string
    (vl-remove-if-not (function (lambda (x) (and (> x 47) (< x 58)))) (vl-string->list (ver)))
  )
)

[Lee Mac]

 :ugly:

Code: [Select]

(defun version nil
  (cdr
    (assoc
      (atof
        (
          (lambda ( key )
            (substr
              (setq key
                (substr key 1
                  (vl-string-position 92 key nil t)
                )
              )
              (+ 3 (vl-string-position 92 key nil t))
            )
          )
          (vlax-product-key)
        )
      )
     '(
        (18.1  . 2011)
        (18.0  . 2010)
        (17.2  . 2009)
        (17.1  . 2008)
        (17.0  . 2007)
        (16.2  . 2006)
        (16.1  . 2005)
        (16.0  . 2004)
        (15.06 . 2002)
      )
    )
  )
)

[alanjt]

:ugly:

Code: [Select]

(defun version nil
  (cdr
    (assoc
      (atof
        (
          (lambda ( key )
            (substr
              (setq key
                (substr key 1
                  (vl-string-position 92 key nil t)
                )
              )
              (+ 3 (vl-string-position 92 key nil t))
            )
          )
          (vlax-product-key)
        )
      )
     '(
        (18.1  . 2011)
        (18.0  . 2010)
        (17.2  . 2009)
        (17.1  . 2008)
        (17.0  . 2007)
        (16.2  . 2006)
        (16.1  . 2005)
        (16.0  . 2004)
        (15.06 . 2002)
      )
    )
  )
)

LoL, I think I'll stick with (getvar 'ACADVER).   Nice work either way.

[Lee Mac]

LoL, I think I'll stick with (getvar 'ACADVER).

   Me too 

[ElpanovEvgeniy]

my version

Code: [Select]

(atoi (substr (ver) 13))