Topic: How do I know witch action produced the error????

[LogicTools]

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun c:ErrorTest  (/ ActiveDocument Utility the_prompt MyError object base_point)
4.  (setvar "errno" 0)
5.  (setq
6.   ActiveDocument (vla-get-activedocument (vlax-get-acad-object))
7.   Utility        (vla-get-utility ActiveDocument)
8.   the_prompt     "Select object"
9.   MyError        (vl-catch-all-apply 'vla-getentity (list Utility 'object 'base_point the_prompt))
10.   )
11.  (while (not MyError)
12.   (print object)
13.   (setq
14.    MyError (vl-catch-all-apply 'vla-getentity (list Utility 'object 'base_point the_prompt))
15.    )
16.   )
17.  (print (getvar "errno"))
18.  (print (vl-catch-all-error-message MyError))
19.  (setvar "errno" 0)
20.  (princ)
21.  )
22.  

Running ErrorTest:
If selecting 2 objects an a third object is not pickup, the function returns:

Code - Auto/Visual Lisp: [Select]

1. #<VLA-OBJECT IAcad3DSolid 0000024deaca5358>
2. #<VLA-OBJECT IAcad3DSolid 0000024deaca5358>
3. 7
4. "Automation Error. Description was not provided."
5.  

If after selecting 2 objects ESC is pressed, the function returns:

Code - Auto/Visual Lisp: [Select]

1. #<VLA-OBJECT IAcad3DSolid 0000024deaca5358>
2. #<VLA-OBJECT IAcad3DSolid 0000024deaca5358>
3. 52
4. "Automation Error. Description was not provided."
5.  

If after selecting 2 objects ENTER is pressed, the function returns:

Code - Auto/Visual Lisp: [Select]

1. #<VLA-OBJECT IAcad3DSolid 0000024deaca5358>
2. #<VLA-OBJECT IAcad3DSolid 0000024deaca5358>
3. 52
4. "Automation Error. Class not registered\r\n"
5.  

By the value of "errno" 7 I am able to identify the reason when the error happens if an object is not pickup but the "errno" value 52 is the same for the other two reasons.
For these the error message is different, but is shows in the installer local language so, how do I know what the translation is for the message in other languages or, is there any other way to identify the difference ?
Any ideas will be greatly appreciated.

[BIGAL]

If you want solids use ssget with the correct filter this will force select "solid" the ssget can have multi filters so then can check Objectname and do correct code.

[LogicTools]

Thank you Bigal for your suggestion, but my problem is to detect it the user hits ESC, ENTER or any other action.
Perhaps this part:

Code - Auto/Visual Lisp: [Select]

1. (setq
2.    MyError (vl-catch-all-apply 'vla-getentity (list Utility 'object 'base_point the_prompt))
3.    )
4.   )

should be like:

Code - Auto/Visual Lisp: [Select]

1. (setq
2.   the_prompt     "Select object, ESC to exit, or ENTER to continue"
3.    MyError (vl-catch-all-apply 'vla-getentity (list Utility 'object 'base_point the_prompt))
4.    )
5.   )

If the option is ENTER then the program will proceed with the objects selected. Any other option will exit.
Also, in my case the objects must be selected one by one to be able to be arranged in a certain order.
Thank you again for your help.

[roy_043]

You can switch to entsel. This will return nil in case of a miss or if enter is pressed.

Code - Auto/Visual Lisp: [Select]

1. (vl-catch-all-apply 'entsel)

[LogicTools]

Thanks roy_043, but with entsel I don't have the possibility of distinguishing between a pick miss or entering ESC, ENTER or SPC because all of them return nil.
So I came to this solution that retrieves the objects' list if the user presses  ENTER, SPC, or ESC and filters pick misses and objects names.
I am open to any other, simpler solution.

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun c:ErrorTest  (/ object_list ActiveDocument Utility the_prompt return_list object object_name object_list)
3.  (setvar "errno" 0)
4.  (setq
5.   ActiveDocument (vla-get-activedocument (vlax-get-acad-object))
6.   Utility        (vla-get-utility ActiveDocument)
7.   object_list    '()
8.   the_prompt     "Select object"
9.   return_list    (getentity the_prompt)
10.   )
11.  (while (and return_list (< (car return_list) 52))
12.   (if (= (car return_list) 0)
13.    (progn
14.     (setq
15.      object      (cadr return_list)
16.      object_name (vla-get-objectname object)
17.      )
18.     (if (/= object_name "AcDb3dSolid")
19.      (alert "Selected object was not a 3DSolid")
20.      (setq
21.       object_list (append object_list (list object))
22.       )
23.      )
24.     )
25.    (alert "No object was selected")
26.    )
27.   (setq
28.    the_prompt  "\nSelect next object or ESC, SPC or ENTER to end selection"
29.    return_list (getentity the_prompt)
30.    )
31.   )
32.  object_list
33.  )
34.  
35. (defun getentity  (the_prompt / error object base_point return errno)
36.  (setvar "errno" 0)
37.  (setq
38.   error (vl-catch-all-apply 'vla-getentity (list Utility 'object 'base_point the_prompt))
39.   )
40.  (if (not error)
41.   (setq
42.    return (list 0 object base_point)
43.    )
44.   (setq
45.    errno  (getvar "errno")
46.    return (list errno nil nil)
47.    )
48.   )
49.  )

[Marc'Antonio Alessi]

I did not understand well what you need, maybe this can give you some ideas

Code: [Select]

; Function: ALE_SsGetFilter
;
; Version 1.00 - 22/02/2005
; Version 1.01 - 04/03/2006 - added (setvar "ERRNO" 0)
; Version 1.02 - 13/09/2007 - removed "ERRNO" > do not work with multiple objects
;                             but only with (ssget "_:E:S") or similar
; Description:
;   Ssget with filter list
;
; Arguments:
;   PrmStr = User prompt [STR]
;   FltLst = ssget filter list [LIST] or nil for no filter
;
; Example:
;  (ALE_SsGetFilter "Select attibuted block(s)" '((0 . "INSERT") (66 . 1)))
;
; Return Values:
;   [PICKSET] Selection set
;
(defun ALE_SsGetFilter (PrmStr FltLst / FlgSlt SelSet)
    (princ "\n_ ")
    (prompt (setq PrmStr (strcat "\n" PrmStr ": ")))
    (while (not FlgSlt)
      (if (setq SelSet (ssget FltLst))
        (setq FlgSlt T)
;|e|;   (prompt (strcat "\nNo valid objects, try again!" PrmStr))
      )
    )
    SelSet
)

[roy_043]

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / err sel)
2.   (setvar 'errno 0)
3.   (setq sel (vl-catch-all-apply 'entsel))
4.   (cond
5.     ((vl-catch-all-error-p sel)
6.       (princ "\nEsc was pressed ")
7.     )
8.     (sel
9.       (princ "\nSucces! ")
10.     )
11.     ((= (setq err (getvar 'errno)) 52)
12.       (princ "\nEnter was pressed ")
13.     )
14.     ((= err 7)
15.       (princ "\nMissed it! Try again please: ")
16.     )
17.   )
18.   (princ)
19. )

[LogicTools]

Grazie Marco. Nice way of using ssget an filters for the purpose.
Also, perhaps a simpler way to do it with entsel instead of vla-getentity as suggested by roy_043.
Thank you guys!!!!

[Marc'Antonio Alessi]

Maybe this was the right tip for your use…  IMHO using vla-get-objectname is a little less practical 

Code: [Select]

; Function: ALE_EntSelFilter
;
; Version 1.00 - 22/02/2005
; Version 1.01 - 04/03/2006 - added (setvar "ERRNO" 0)
;
; Description:
;   Ssget for one entity with filter list
;
; Arguments:
;   PrmStr = User prompt [STR]
;   FltLst = ssget filter list [LIST]
;
; Example:
;  (ALE_EntSelFilter "Select attibuted block" '((0 . "INSERT") (66 . 1)))
;
; Return Values:
;   [ENAME] Entity name
;   nil if user press 'Return' or 'Space'

(defun ALE_EntSelFilter (PrmStr FltLst / FlgSlt EntNam)
    (setvar "ERRNO" 0)
    (princ "\n_ ")
    (prompt (setq PrmStr (strcat "\n" PrmStr ": ")))
    (if
      (while (not FlgSlt)
        (if (setq EntNam (ssget "_:E:S" FltLst))
          (not (setq FlgSlt T))
          (if (= 52 (getvar "ERRNO"))
            (setq FlgSlt T)
            (prompt (strcat "\nNo objects selected or valid, try again!" PrmStr))
          )
        )
      )
      (not (princ "\nFunction cancelled.  "))
      (ssname EntNam 0)
    )
)

[LogicTools]

Molto interesante Marco.
My purpose to start with was to distinguish when the user was hitting SPC, ESC or ENTER to end the loop.
The last prompt should have been: "Select next object or ENTER to end selection", if at that point SPC or ESC were hit the function will quit, if ENTER is pressed then the function will proceed with the selected objects list.
But that's my problem, I don't know how to differentiate which key has been pressed to end the loop.

[PKENEWELL]

Just as a side note: When troubleshooting an error, you can add the Visual Lisp function (vl-bt) into your error handler. This will provide a full backtrace of the error.

As an example - I use this command to clear my global error handlers and add backtrace when I'm troubleshooting an AutoLISP function

Code - Auto/Visual Lisp: [Select]

1. (defun c:pjk-errnil ()
2.     (setq *error* nil pjk-error nil pjk:debugflag T)
3.     (setvar "cmdecho" 1)
4.     (defun *error* (msg)(vl-bt))
5.     (defun pjk-error (msg)(vl-bt))
6.     (princ)
7. )
8.  

[Lee Mac]

My purpose to start with was to distinguish when the user was hitting SPC, ESC or ENTER to end the loop.
The last prompt should have been: "Select next object or ENTER to end selection", if at that point SPC or ESC were hit the function will quit, if ENTER is pressed then the function will proceed with the selected objects list. But that's my problem, I don't know how to differentiate which key has been pressed to end the loop.

Under most circumstances, SPACE, ENTER & right-click are equivalent & indistinguishable; unless you opt to roll your own selection function through the use of grread to monitor and differentiate between all forms of user input - but even given the work involved to implement this, having the function quit on the user pressing SPACE, but continue on ENTER is counter to standard AutoCAD behaviour and will confuse long time users.

[Marc'Antonio Alessi]

Under most circumstances, SPACE, ENTER & right-click are equivalent & indistinguishable; unless you opt to roll your own selection function through the use of grread to monitor and differentiate between all forms of user input - but even given the work involved to implement this, having the function quit on the user pressing SPACE, but continue on ENTER is counter to standard AutoCAD behaviour and will confuse long time users.

I fully agree, I always use the space bar and use the enter key only when necessary… and so do everyone I know. 

[LogicTools]

PKENEWELL thanks for pointing out that your very useful function and thank you Carlo and Lee for your observations.
So my question is how do I know when the user is finishing selecting objects and continue to proceed them or is entering ESC, for instance, because he wants to cancel and not continuing with the selection?

[LogicTools]

So, as there is not possibility of knowing when the user is finishing selecting objects and proceed or when he/she wants to cancel, I opted for asking to enter the total number of objects to be selected and processed at the beginning of the function.
Like this:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun c:ErrorTest  (/ object_list ActiveDocument Utility obj_num getobj_list the_prompt return_list object object_name)
3.  (if (null g::obj_num)
4.   (setq
5.    object_list nil
6.    g::obj_num  3
7.    )
8.   )
9.  (setq
10.   ActiveDocument (vla-get-activedocument (vlax-get-acad-object))
11.   Utility        (vla-get-utility ActiveDocument)
12.   )
13.  (initget 6)
14.  (setq
15.   obj_num (getint (strcat "Number of objects to be selected" ": <" (itoa g::obj_num) ">"))
16.   )
17.  (if (not obj_num)
18.   (setq
19.    obj_num g::obj_num
20.    )
21.   (setq
22.    g::obj_num obj_num
23.    )
24.   )
25.  (if obj_num
26.   (progn
27.    (setq
28.     object_list '()
29.     the_prompt  "Select first object"
30.     obj_count   0
31.     )
32.    (while (< obj_count obj_num)
33.     (setq
34.      getobj_list (getobj the_prompt object_list)
35.      )
36.     (if (and getobj_list (car getobj_list))
37.      (progn
38.       (setq
39.        obj_count  (+ (car getobj_list) obj_count)
40.        the_prompt (strcat "\n" (itoa obj_count) " of " (itoa obj_num) " objects selected"
41.                           "\n Select next object :")
42.        )
43.       (if (> (car getobj_list) 0)
44.        (setq
45.         object_list (append object_list (list (last getobj_list)))
46.         )
47.        )
48.       )
49.      (setq
50.       obj_count obj_num
51.       object_list nil
52.       )
53.      )
54.     )
55.    )
56.   )
57.  object_list
58.  )
59.  
60. (defun getobj  (the_prompt object_list / return error object base_point object_name)
61.  (setvar "errno" 0)
62.  (setq
63.   return nil
64.   error  (vl-catch-all-apply 'vla-getentity (list Utility 'object 'base_point the_prompt))
65.   )
66.  (if (not error)
67.   (progn
68.    (setq
69.     object_name (vla-get-objectname object)
70.     )
71.    (cond
72.     (
73.      (/= object_name "AcDb3dSolid")
74.      (setq
75.       return (list 0 nil)
76.       )
77.      (alert "Selected object was not a 3DSolid")
78.      )
79.     (
80.      (member object object_list)
81.      (setq
82.       return (list 0 nil)
83.       )
84.      (alert "Object was previously selected")
85.      )
86.     )
87.    )
88.   (progn
89.    (if (< (getvar "errno") 52)
90.     (progn
91.      (setq
92.       return (list 0 nil)
93.       )
94.      (alert "No object was selected")
95.      )
96.     (progn
97.      (setq
98.       return (list nil nil)
99.       )
100.      (alert "Not enougth data to proceed")
101.      )
102.     )
103.    )
104.   )
105.  (if (not return)
106.   (setq
107.    return (list 1 object)
108.    )
109.   )
110.  return
111.  )
112.  

CAUTION: The code had not been fully tested !!!!