Topic: redefine offset command

[Lupo76]

Hello to all,
I need to define the offset command, because I'd like to do some operations to results objects.
I wish the user could use all of the offset command options (Point / Delete / Multiple Layer ... ... etc.)
Unfortunately I have no idea how to do.

Code: [Select]

(defun c:newoffset ()
   (command "_.offset" pause pause pause ??????)
   (setq newogg (??????)
  [code that will handle the selection set 'newogg']

Can you help me?

[roy_043]

Here is a solution:

Code - Auto/Visual Lisp: [Select]

1. (defun c:NewOffset ( / doc enm ss tmp)
2.   (if
3.     (or
4.       (setq enm (entlast))
5.       (progn
6.         (princ "\nNo entity available for offset ")
7.         nil
8.       )
9.     )
10.     (progn
11.       (setq doc (vla-get-activedocument (vlax-get-acad-object)))
12.       (if (= 8 (logand (getvar 'undoctl) 8))
13.         (vla-endundomark doc)
14.       )
15.       (vla-startundomark doc)
16.       (while (setq tmp (entnext enm))
17.         (setq enm tmp)
18.       )
19.       (command "_.offset")
20.       (while (/= 0 (logand (getvar 'cmdactive) 3))
21.         (command pause)
22.       )
23.       (setq ss (ssadd))
24.       (while (setq enm (entnext enm))
25.         (ssadd enm ss)
26.       )
27.       (if (/= 0 (sslength ss))
28.         (sssetfirst nil ss)
29.       )
30.       (vla-endundomark doc)
31.     )
32.   )
33.   (princ)
34. )

[Lupo76]

Here is a solution:

Code - Auto/Visual Lisp: [Select]

1. (defun c:NewOffset ( / doc enm ss tmp)
2.   (if
3.     (or
4.       (setq enm (entlast))
5.       (progn
6.         (princ "\nNo entity available for offset ")
7.         nil
8.       )
9.     )
10.     (progn
11.       (setq doc (vla-get-activedocument (vlax-get-acad-object)))
12.       (if (= 8 (logand (getvar 'undoctl) 8))
13.         (vla-endundomark doc)
14.       )
15.       (vla-startundomark doc)
16.       (while (setq tmp (entnext enm))
17.         (setq enm tmp)
18.       )
19.       (command "_.offset")
20.       (while (/= 0 (logand (getvar 'cmdactive) 3))
21.         (command pause)
22.       )
23.       (setq ss (ssadd))
24.       (while (setq enm (entnext enm))
25.         (ssadd enm ss)
26.       )
27.       (if (/= 0 (sslength ss))
28.         (sssetfirst nil ss)
29.       )
30.       (vla-endundomark doc)
31.     )
32.   )
33.   (princ)
34. )

Hello Roy,
thanks for your code!
It works very well but it has a small problem in AutoCAD, it does not display the preview of the result

Can you also solve this? 

[Lupo76]

I realized just now of a more serious problem.
With your code I can control the user-selected object only after the command has been completed.
In my first post I explained the problem badly.

I have to check that each user-selected object is confirmed to my needs.
A practical example is the OFFSET command that always works, except when the user selects an object LINE.

can you do this?

[roy_043]

It works very well but it has a small problem in AutoCAD, it does not display the preview of the result

Can you also solve this? 

In BricsCAD V16 there is a preview. I don't know why AutoCAD behaves in this manner or how to solve it.

[roy_043]

I realized just now of a more serious problem.
With your code I can control the user-selected object only after the command has been completed.
In my first post I explained the problem badly.

I have to check that each user-selected object is confirmed to my needs.
A practical example is the OFFSET command that always works, except when the user selects an object LINE.

can you do this?

If you want to validate the source entities, something like the code below will work. But it does not expose all options of the OFFSET command.

Code - Auto/Visual Lisp: [Select]

1. (defun c:NewOffset2 ( / N_GetEntity N_GetDistance dist doc enm enmOffset pt ss tmp)
2.  
3.   (defun N_GetEntity ( / enm)
4.     (if
5.       (and
6.         (setq enm (car (entsel "\nSelect entity: ")))
7.         (vl-position
8.           (vla-get-objectname (vlax-ename->vla-object enm))
9.           '("AcDb2dPolyline" "AcDbArc" "AcDbCircle" "AcDbEllipse" "AcDbLine" "AcDbPolyline" "AcDbSpline")
10.         )
11.       )
12.       enm
13.     )
14.   )
15.  
16.   (defun N_GetDistance ( / dist)
17.     (initget 6)
18.     (setq dist
19.       (getdist
20.         (if (< 0 (getvar 'offsetdist))
21.           (strcat "\nOffset distance <" (rtos (getvar 'offsetdist)) ">: ")
22.           "\nOffset distance: "
23.         )
24.       )
25.     )
26.     (cond
27.       (dist
28.         (setvar 'offsetdist dist)
29.         dist
30.       )
31.       ((< 0 (getvar 'offsetdist))
32.         (getvar 'offsetdist)
33.       )
34.     )
35.   )
36.  
37.   (if
38.     (or
39.       (setq enm (entlast))
40.       (progn
41.         (princ "\nNo entity available for offset ")
42.         nil
43.       )
44.     )
45.     (progn
46.       (setq doc (vla-get-activedocument (vlax-get-acad-object)))
47.       (if (= 8 (logand (getvar 'undoctl) 8))
48.         (vla-endundomark doc)
49.       )
50.       (vla-startundomark doc)
51.       (while (setq tmp (entnext enm))
52.         (setq enm tmp)
53.       )
54.       (if (setq dist (N_GetDistance))
55.         (while
56.           (and
57.             (setq enmOffset (N_GetEntity))
58.             (setq pt (getpoint "\nSide for parallel copy: "))
59.           )
60.           (setvar 'cmdecho 0)
61.           (command "_.offset" dist enmOffset pt "")
62.           (setvar 'cmdecho 1)
63.         )
64.       )
65.       (setq ss (ssadd))
66.       (while (setq enm (entnext enm))
67.         (ssadd enm ss)
68.       )
69.       (if (/= 0 (sslength ss))
70.         (sssetfirst nil ss)
71.       )
72.       (vla-endundomark doc)
73.     )
74.   )
75.   (princ)
76. )

[ChrisCarlson]

What additional functions do you want?

[Lupo76]

If you want to validate the source entities, something like the code below will work. But it does not expose all options of the OFFSET command.

The problem is just that!
I would like to validate the source objects and keep all the OFFSET command options