Topic: Changing the Layout Tabs Color with a Lisp

[MSTG007]

I am trying to get  a lisp to change the layout tab color from the "Display Plot Styles" Color White; to "Turn off Display Plot Styles" Color Black.

Lisp to Show Plot Styles On

Code - Auto/Visual Lisp: [Select]

1. (Defun showpstyle ( / DOC LAYOUTS)
2.   (setq doc (vla-get-activedocument (vlax-get-acad-object))
3.         layouts (vla-get-layouts doc)
4.         ); setq
5.   (vlax-for n layouts
6.     (vl-catch-all-apply 'vla-put-showplotstyles (list n :vlax-true))
7.     ); vlax-for
8.   (vla-regen doc acAllViewports)
9.   (mapcar 'vlax-release-object (list layouts doc))
10.   (princ)
11.   ); defun
12. (showpstyle)
13.  
14. (setq DisplayObj
15. (vla-get-Display
16. (vla-get-Preferences
17. (vlax-get-acad-object)
18. )))
19. (vlax-put-property DisplayObj 'Layoutbackground 7)
20.  
21. (vlax-release-object DisplayObj)

Lisp to Turn off Plot Styles

Code - Auto/Visual Lisp: [Select]

1. (Defun showpstyle ( / DOC LAYOUTS)
2.   (setq doc (vla-get-activedocument (vlax-get-acad-object))
3.         layouts (vla-get-layouts doc)
4.         ); setq
5.   (vlax-for n layouts
6.     (vl-catch-all-apply 'vla-put-showplotstyles (list n :vlax-false))
7.     ); vlax-for
8.   (vla-regen doc acAllViewports)
9.   (mapcar 'vlax-release-object (list layouts doc))
10.   (princ)
11.   ); defun
12. (showpstyle)
13.  
14. (setq DisplayObj
15. (vla-get-Display
16. (vla-get-Preferences
17. (vlax-get-acad-object)
18. )))
19. (vlax-put-property DisplayObj 'Layoutbackground 0)
20.  
21. (vlax-release-object DisplayObj)

[MSTG007]

I found an answer and would like to share it


Found here: http://forums.autodesk.com/t5/Visual-LISP-AutoLISP-and-General/Update-this-LISP-for-Display-Plot-Styles-in-2012/td-p/3807876

Code - Auto/Visual Lisp: [Select]

1. ;-------------------------------------------------------
2. ; DPS - DisplayPlotStyles
3. ; 04/03/10 ruul at ctr.co.at
4. ; nomen est omen - toggles display of plotstyles...
5. ;-------------------------------------------------------
6. ; Updated 110208 by Mike Sweeney
7. ; Added code to change background color of layout tabs to black or white (depending on state of 'Display Plot Styles')
8. ; Added (BGWhite) and (BGBlack) sub-routines
9. ;-------------------------------------------------------
10.  
11.  
12. (defun DPS_Post ()
13.   (setvar "cmdecho" 0)
14.   (command "_.regenall")
15.   (setvar "cmdecho" 1)
16.   (princ)
17. )
18. ;-------------------------------------------------------
19. (defun c:DPSON ()
20.   (rm:displayplotstyles t nil)
21.   (BGWhite)
22.   (DPS_Post)
23. )
24. ;-------------------------------------------------------
25. (defun c:DPSONALL ()
26.   (rm:displayplotstyles t t)
27.   (BGWhite)
28.   (DPS_Post)
29. )
30. ;-------------------------------------------------------
31. (defun c:DPSOFF ()
32.   (rm:displayplotstyles nil nil)
33.   (BGBlack)
34.   (DPS_Post)
35. )
36. ;-------------------------------------------------------
37. (defun c:DPSOFFALL ()
38.   (rm:displayplotstyles nil t)
39.   (BGBlack)
40.   (DPS_Post)
41. )
42. ;-------------------------------------------------------
43. ;
44. ;
45. (defun rm:displayplotstyles (bshow ball / acapp acdoc layouts layout bvshow)
46.    (princ "\n...Display plotstyles ")
47.    (vl-load-com)
48.    (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
49.  
50.    (setq layouts (vla-get-layouts acdoc))
51.    (setq bvshow (if bshow :vlax-true :vlax-false))
52.    (princ (if bshow "ON" "OFF"))
53.    (cond
54.       (ball
55.          (vlax-for layout layouts
56.             (if (/= (vla-get-name layout) "Model")
57.             (vla-put-ShowPlotStyles layout bvshow))
58.          )
59.       (princ " in all layouts.\n")
60.       )
61.       (T (setq layout (vla-get-ActiveLayout acdoc))
62.          (vla-put-ShowPlotStyles layout bvshow)
63.          (princ " in current layout.\n")
64.       )
65.    )
66.    (prin1)
67. )
68.  
69.  
70. ; Set the background in model and paper space to white
71. (defun BGWhite ()
72.   (vl-load-com)
73.   (setq disp (vla-get-display (vla-get-preferences (vlax-get-acad-object))))
74.   (vla-put-GraphicsWinLayoutBackgrndColor disp 16777215)
75. )
76.  
77. ; Set the background in model and paper space to black
78. (defun BGBlack  ()
79.   (vl-load-com)
80.   (setq disp (vla-get-display (vla-get-preferences (vlax-get-acad-object))))
81.   (vla-put-GraphicsWinLayoutBackgrndColor disp 0)
82. )
83. ;---------------------------------------------- ---------
84. (princ (strcat "\n...DisplayPlotStyles is loaded || DPSON, DPSONALL, DPSOFF, DPSOFFALL...\n"))
85. (prin1)
86. ;--------------------------------------------- ----------[\code]

[BlackBox]

[Edit] - Looks like you found the right Property while I composed my post.


The Property you're after is the GraphicsWinLayoutBackgrndColor, methinks... Here's a quickly written toggle routine:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun c:ShowPlotStyle (/ *error* _ShowPlotStyle acApp acDoc acDispPrefs)
4.  
5.   (defun *error* (msg)
6.     (if acDoc
7.       (vla-regen acDoc acallviewports)
8.     )
9.     (cond ((not msg))                                                   ; Normal exit
10.           ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
11.           ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
12.     )
13.     (princ)
14.   )
15.  
16.   (defun _ShowPlotStyle (acDoc value)
17.     (vlax-for x (vla-get-layouts acDoc)
18.       (vl-catch-all-apply 'vla-put-showplotstyles (list x value))
19.     )
20.   )
21.  
22.   (if
23.     (and (setq acApp (vlax-get-acad-object))
24.          (setq acDoc (vla-get-activedocument acApp))
25.          (setq acDispPrefs (vla-get-display (vla-get-preferences acApp)))
26.     )
27.      (if *GraphicsWinLayoutBackgrndColor*
28.        (progn                                                           ; disable
29.          (setq *GraphicsWinLayoutBackgrndColor*
30.                 (vla-put-graphicswinlayoutbackgrndcolor
31.                   acDispPrefs
32.                   *GraphicsWinLayoutBackgrndColor*
33.                 )
34.          )
35.          (_ShowPlotStyle acDoc :vlax-false)
36.        )
37.        (progn                                                           ; enable
38.          (setq *GraphicsWinLayoutBackgrndColor*
39.                 (vla-get-graphicswinlayoutbackgrndcolor
40.                   acDispPrefs
41.                 )
42.          )
43.          (vla-put-graphicswinlayoutbackgrndcolor
44.            acDispPrefs
45.            16777215
46.          )
47.          (_ShowPlotStyle acDoc :vlax-true)
48.        )
49.      )
50.   )
51.   (*error* nil)
52. )
53.  

... If this is a critical setting, I'd also suggest you incorporate an Event handler which restores your original options prior to the Application closing.

Cheers