Topic: invalid index

[ronjonp]

Why would objects really far away from 0,0 cause this code to bonk out?

Code: [Select]

  (vlax-safearray->list
    (vlax-variant-value
      (vla-intersectwith
(vlax-ename->vla-object (car (entsel)))
(vlax-ename->vla-object (car (entsel)))
acExtendBoth
      )
    )
  )
Thanks,

Ron

[LE]

Hi Ron;

Can you wrap your code with vl-catch-all-xxx like:

Code: [Select]

    (if (not
  (vl-catch-all-error-p
    (setq value (vl-catch-all-apply
  'vlax-safearray->list
  (list
    (vlax-variant-value
      (vla-intersectwith
obj1
obj2
acextendboth)))))))

then see if works.

[ronjonp]

Thanks LE....I ended up using inters and it fixed my problem.

[Kerry]

Ron,

How about this ?

Code: [Select]

(VLAX-INVOKE (VLAX-ENAME->VLA-OBJECT (CAR (ENTSEL)))
             "intersectwith"
             (VLAX-ENAME->VLA-OBJECT (CAR (ENTSEL)))
             ACEXTENDBOTH
)

[Kerry]

Ron,
Not really off Topic :

Are both objects selected lines (or straignt polylines) rather than any other object.

A little known factoid about  the IntersectWith Method is that it will return ALL intersections for curved objects.
For instance draw 2 intersecting circles and run the code I posted ( or your initial code)

Code: [Select]

(SETQ datalist (VLAX-INVOKE (VLAX-ENAME->VLA-OBJECT (CAR (ENTSEL)))
                            "intersectwith"
                            (VLAX-ENAME->VLA-OBJECT (CAR (ENTSEL)))
                            ACEXTENDBOTH
               )
)
With My code you will get something like
(44407.4 3271.38 0.0 42033.4 6814.93 0.0)
... just a collection of reals ..

Run it through a translator like this ;

Code: [Select]

(DEFUN kdub:datalist->points (datalist sublistSize / tmp return Index)
    (SETQ Index 0)
    (FOREACH var datalist
        (SETQ tmp (APPEND tmp (LIST var)))
        (IF (ZEROP (REM (SETQ Index (1+ Index)) sublistSize))
            (SETQ return (CONS tmp return)
                  tmp    nil
            )
        )
    )
    (REVERSE return)
)

(kdub:datalist->points datalist 3)
Will return ALL the intersection points, something like
((44407.4 3271.38 0.0) (42033.4 6814.93 0.0))


... has some possibilities, heh?

[Kerry]

Ron,
or something like this may be more efficient as a translator ...
I've used this functionality to interrogate intersection between a line (say) and a block.

Code: [Select]

(DEFUN kdub:datalist->Coordinates (datalist / coordinates)
    (IF (> (LENGTH datalist) 3)
        (WHILE (CADDR datalist)
            (SETQ coordinates (CONS (LIST (CAR datalist)
                                          (CADR datalist)
                                          (CADDR datalist)
                                    )
                                    coordinates
                              )
                  datalist    (CDDDR datalist)
            )
        )
        ;; else
        (SETQ coordinates datalist)
    )
    coordinates
)

[ronjonp]

Kerry,

Thanks for all your replies..I'll mess around with these on Monday Have a nice weekend.