Topic: Check if blank is an actual (core) command.

[alanjt]

Is it possible to check if a specific command is actually a command (not LISP) within AutoCAD?

eg.
Line command:
(and LINE)

[gile]

Hi,

Using getcname function:
(getcname "line")

[Lee Mac]

That's a new one to me - merci beaucoup Gilles 

[pBe]

unless somewhere alongthe way somebody did this inside a vlx file

Code: [Select]

(defun sample ()
  (princ "\nHello Swamp")
  (princ))

Code: [Select]

(vlax-add-cmd "sample" "sample")
(getcname "sample")
"_SAMPLE"

[Matt__W]

It apparently doesn't work for XPLODE.

Command: (getcname "xplode")
nil

[Lee Mac]

That's only an alias though:

Code: [Select]

_$ (getcname "explode")
"_EXPLODE"

[alanjt]

Hi,

Using getcname function:
(getcname "line")

Thanks, Gile.

That's only an alias though:

Code: [Select]

_$ (getcname "explode")
"_EXPLODE"

XPlode and Explode are not the same.

[alanjt]

I was playing around with one of those situations where you are forced to use command to visually place something and I scratched this out...

Code: [Select]

(defun AT:Command (cmd / *error* c e n lst)
  (defun *error* (msg) (and c (setvar 'CMDECHO c)) (reverse lst))
  (setq e (entlast))
  (setq c (getvar 'CMDECHO))
  (setvar 'CMDECHO 1)
  (command cmd)
  (while (eq 1 (logand 1 (getvar 'CMDACTIVE))) (command PAUSE))
  (or (equal (setq n e) (entlast)) (while (setq n (entnext n)) (setq lst (cons n lst))))
  (*error* nil)
)

[pBe]

what about the other way around? check if a command is a lisp?

Code: [Select]

(defun LC (cmd)
(foreach i (atoms-family 1)
  (if (EQ (strcase cmd) I)
    (print (strcat "Lisp Command Found: " i)))(princ)
  )
)
(LC "C:sample")
(LC "sample")
(LC "C:XPLODE")

[Crank]

what about the other way around? check if a command is a lisp?

Code: [Select]

(defun LC (cmd)
(foreach i (atoms-family 1)
  (if (EQ (strcase cmd) I)
    (print (strcat "Lisp Command Found: " i)))(princ)
  )
)
(LC "C:sample")
(LC "sample")
(LC "C:XPLODE")

In the macros of my CUI , I don't use atoms-family to check if a lisp is present, but I just use:

Code: [Select]

(if (not c:example)(load "example"))

But now I wonder: Is it possible to check if a command has been added through a .dll , or if the .dll has been loaded ?

[gile]

But now I wonder: Is it possible to check if a command has been added through a .dll , or if the .dll has been loaded ?

For .NET defined commands, I use getcname too.

[pBe]

In the macros of my CUI , I don't use atoms-family to check if a lisp is present, but I just use:

Code: [Select]

(if (not c:example)(load "example"))

But now I wonder: Is it possible to check if a command has been added through a .dll , or if the .dll has been loaded ?

I undertsand, what i'm getting at is trying to find out if a lisp with the same name as an ALIAS (pgp) is loaded. if somewhere along the way somebody loads a lisp command that  supercedes the ALIAS i would somehow unload it and not the other way around, strange huh?   

[Crank]

@ gile: Cool!

@pBe: Roger

[LE3]

But now I wonder: Is it possible to check if a command has been added through a .dll , or if the .dll has been loaded ?

For .NET defined commands, I use getcname too.

I have used this in the past, but from the ARX side:

Code: [Select]

AcEdCommandStack* pCmdStack = AcEdCommandStack::cast(acrxSysRegistry()->at(ACRX_COMMAND_DOCK));
AcEdCommand *pCmd = pCmdStack->lookupGlobalCmd(_T("CommandName")); // name of the command to look for

Have not tried the C# route but after a quick look appears that there is a wrapper now for the above as: CommandStack - no idea if works or the usage signature.


HTH.-

[Lee Mac]

Sorry to drag up old code, but I just wanted to notify that the following:

Code: [Select]

(defun AT:Command ... )

Won't work if the last created entity is an attributed block, e.g.:

Code: [Select]

_$ (mapcar '(lambda ( x ) (cdr (assoc 0 (entget x)))) (AT:Command "LINE"))
("ATTRIB" "ATTRIB" "SEQEND" "LINE" "LINE" "LINE")
I propose:

Code: [Select]

(defun AT:Command2 ( cmd / *error* cm e1 e2 e3 ls )

    (defun *error* ( msg ) (if cm (setvar 'CMDECHO cm)) (reverse ls))

    (if (setq e1 (entlast) e2 e1)
        (while (setq e3 (entnext e2)) (setq e2 e3))
        (setq e2 t)
    )
    (setq cm (getvar 'CMDECHO))
    (setvar 'CMDECHO 1)
    (command cmd)
    (while (= 1 (logand 1 (getvar 'CMDACTIVE)))
        (command pause)
    )   
    (if (not (equal e1 (entlast)))
        (while (setq e2 (entnext e2)) (setq ls (cons e2 ls)))
    )
    (*error* nil)
)
Now:

Code: [Select]

_$ (mapcar '(lambda ( x ) (cdr (assoc 0 (entget x)))) (AT:Command2 "LINE"))
("LINE" "LINE" "LINE")