Topic: Groups

[V-Man]

Can anyone tell me how you can explode a group? Basically I got some text that is made into a group. I would like to explode the group.

[Guest]

Command: -group
Enter a group option
[?/Order/Add/Remove/Explode/REName/Selectable/Create] <Create>: e

Enter a group name or [?]:

[VVA]

Posting by kpblc here http://www.autocad.ru/cgi-bin/f1/board.cgi?t=22733Nt
It is translated on English

Code: [Select]

;|=============================================================================
*    Grouping and ungrouping
*    Call:
*  grouping  nil -> ungrouping. t -> grouping
*    Usage:
(kpblc-univ-grouping t)    ;grouping
(kpblc-univ-grouping nil)  ;ungrouping
=============================================================================|;
(defun kpblc-univ-grouping (grouping   /          selset     error_catch
                            item       counter    group      sub_item )
  (defun error_catch (msg)
    (vla-endundomark *kpblc-activedoc*)
    (princ msg)
    ) ;_ end of defun
  (vl-load-com)
  (if (not *kpblc-activedoc*)
    (setq *kpblc-activedoc* (vla-get-activedocument (vlax-get-acad-object)))
    ) ;_ end of if
  (vla-startundomark *kpblc-activedoc*)
  (setq *error* error_catch
        counter 0
        ) ;_ end of setq
  (princ "\nSelect object")
  (if (not (setq selset (ssget "_I")))
    (setq selset (ssget))
    ) ;_ end of if
  (while (and selset (setq item (ssname selset counter)))
    (setq counter (1+ counter))
    (if (and (assoc 330 (entget item))
             (setq group (cdr (assoc 330 (entget item))))
             (eq (cdr (assoc 0 (entget group))) "GROUP")
             ) ;_ end of and
      (progn
        (setq group (vlax-ename->vla-object group))
        (vlax-for sub_item (vla-item (vla-get-groups *kpblc-activedoc*)
                                     (vla-get-name group)
                                     ) ;_ end of vla-item
          (ssadd (vlax-vla-object->ename sub_item) selset)
          ) ;_ end of vlax-for
        (entdel (vlax-vla-object->ename group))
        ) ;_ end of progn
      ) ;_ end of if
    ) ;_ end of while
  (if grouping
    (if (vl-cmdf "_.-group" "_create" "*" "" selset "")
      (princ "\nGrouping successfully")
      (princ "\nError grouping object")
      ) ;_ end of if
    ) ;_ end of if
  (sssetfirst nil nil)
  (vla-endundomark *kpblc-activedoc*)
  (princ)
  ) ;_ end of defun

;;Group object
(defun c:grp ()(kpblc-univ-grouping t))

;;Ungroup (explode) object
(defun c:ung ()(kpblc-univ-grouping nil))
;;Group / Ungroup
(defun c:ugq (/ _answer_)
  (initget "Group Ungroup _ G U")
  (setq _answer_
         (getkword
           "\nSelect actions [Group/Ungroup] <Cancel> : "
           ) ;_ end of getkword
        ) ;_ end of setq
  (if _answer_
    (kpblc-univ-grouping (= _answer_ "G"))
    ) ;_ end of if
  ) ;_ end of defun

(princ "\nType Grp for grouping
        \n     Ung for ungrouping
        \n     Ugq for group/ungroup in command line")


[V-Man]

thanks guys for the quick responses.

[VVA]

>dvarino
Ctrl+H qwick changes value PICKSTYLE with 0 to 1 and back.
 
PICKSTYLE System Variable
Type:  Integer
Saved in:  Registry
Initial value:  1

Controls the use of group selection and associative hatch selection.

0 - No group selection or associative hatch selection
1 - Group selection
2 - Associative hatch selection
3 - Group selection and associative hatch selection
 

[Crank]

Ctrl+H qwick changes value PICKSTYLE with 0 to 1 and back.

I always use CTRL+SHIFT+A

[Guest]

Ctrl+H qwick changes value PICKSTYLE with 0 to 1 and back.

I always use CTRL+SHIFT+A

It depends on your version.  I think back in '04 it was CTRL+H.  I don't seem to recall it working like that in '05 though; could be wrong.

[VVA]

Ctrl+H qwick changes value PICKSTYLE with 0 to 1 and back.

I always use CTRL+SHIFT+A

It depends on your version.  I think back in '04 it was CTRL+H.  I don't seem to recall it working like that in '05 though; could be wrong.

One more good tips in my coin box
>Matt W It's work in 2004 too

[It's Alive!]

Also if you remove CTRL+A from being select all. It will default to toggling the groups