Topic: selection (ssget)?

[iradic]

Hi...

I modified existing - old lisp ... to join lines arcs and plines.

It uses ssget to get objects to join. Now how do I check what happened to objects in selection set (how many objects joined)? My guess is if they are still in drawing then they are not joined right?

Here is the code...

Code: [Select]

;;;   PJOIN.LSP  V1.1 by Zoltan Toth
;;;
;;;   Description:
;;;   This program takes any number of LINES, ARCS and/or
;;;   LWPOLYLINES and joins
;;;   them into a single LWPOLYLINE if the objects are contiguous.
;;;

;; define program name & localize variables
(defun c:pjoin (/ sfirst sset ename etype
                 *error* oldcmd
                 )
  (defun *error* (s / enum)
    (setq enum (itoa (getvar "errno")))
    (command)(command)
    (command "._undo" "_end")
    (if (not (member s '(nil "console break" "Function canelled" "quit / exit abort")))
      (progn
        (princ (strcat "\nError: # " enum " - " s
                       "\nUndoing..."))
        (command "._undo" "1")
        )
      )
    (if oldcmd (setvar "cmdecho" oldcmd))
    )

  (setq oldcmd (getvar "CMDECHO")) ;save current command echo status
  (setvar "cmdecho" 0) ;turn off command echoing
  (command "._undo" "_group") ;start undo group

  ;; get objects to join into a single LWPOLYLINE
  (prompt "\nSelect first object:")
  (setq sfirst nil)
  (while (not sfirst)
         (if (not (setq sfirst (ssget "_:S" '((-4 . "<OR")
                                              (0 . "LINE")
                                              (0 . "LWPOLYLINE")
                                              (0 . "ARC")
                                              (-4 . "OR>")))))
           (princ "\nSelect LINE, LWPOLINE or ARC...")
           )
         )
  (prompt "\nSelect objects to join into a polyline:")
  (setq sset
        (ssget '((-4 . "<OR")
                 (0 . "LINE")
                 (0 . "LWPOLYLINE")
                 (0 . "ARC")
                 (-4 . "OR>")))
        )
  (if (and sset sfirst)
    (progn
      (setq ename (ssname sfirst 0)) ;get name of first object
      (setq etype (cdr (assoc 0 (entget ename)))) ;get object type
      (ssadd ename sset)

      ;; if first object is a LWPOLYLINE ...
      (if (= "LWPOLYLINE" etype)
        ;; then: join objects into POLYLINE
        (command "._PEDIT" ename "_J" sset "" "")
        ;; else: convert object and join them
        (command "._PEDIT" ename  "_Y" "_J" sset "" "")
        )
      )
    (prompt "\nNo objects selected.")
    )

  (*error* nil)
  (princ)
  )


[daron]

You're joining them through command options. Autocad is taking care of removing the old objects for you, so no, they are not still in the drawing. They've been removed. However, if what you're asking is how to know how many objects are joined in order to princ that to the command line at the end, place a (setq amount (sslength ssget)) before the first if statement and a (princ (strcat "\n" (itoa amount) " objects joined")) just before the *error* portion or somewhere in there.

[iradic]

Thanks...

But I don't think it will return number of joined objects ... just the number of object in sset - that doesn't mean they are joined.
It seems they are still in sset after command "pedit" is done no matter they are not in the drawing anymore...

[T.Willey]

Maybe check the amount of vertices before you issue the pedit command for the pline you are going to select, and then check it after.  If it had two before, and three after, then one got joined.

/idea

[CAB]

Maybe this.

Code: [Select]

;;;   PJOIN.LSP  V1.1 by Zoltan Toth
;;;
;;;   Description:
;;;   This program takes any number of LINES, ARCS and/or
;;;   LWPOLYLINES and joins
;;;   them into a single LWPOLYLINE if the objects are contiguous.
;;;

;; define program name & localize variables
(defun c:pjoin (/ sfirst sset ename etype
                 *error* oldcmd
                 )
  (defun *error* (s / enum)
    (setq enum (itoa (getvar "errno")))
    (command)(command)
    (command "._undo" "_end")
    (if (not (member s '(nil "console break" "Function canelled" "quit / exit abort")))
      (progn
        (princ (strcat "\nError: # " enum " - " s
                       "\nUndoing..."))
        (command "._undo" "1")
        )
      )
    (if oldcmd (setvar "cmdecho" oldcmd))
    )

  (setq oldcmd (getvar "CMDECHO")) ;save current command echo status
  (setvar "cmdecho" 0) ;turn off command echoing
  (command "._undo" "_group") ;start undo group

  ;; get objects to join into a single LWPOLYLINE
  (prompt "\nSelect first object:")
  (setq sfirst nil)
  (while (not sfirst)
         (if (not (setq sfirst (ssget "_:S" '((-4 . "<OR")
                                              (0 . "LINE")
                                              (0 . "LWPOLYLINE")
                                              (0 . "ARC")
                                              (-4 . "OR>")))))
           (princ "\nSelect LINE, LWPOLINE or ARC...")
           )
         )
  (prompt "\nSelect objects to join into a polyline:")
  (setq sset
        (ssget '((-4 . "<OR")
                 (0 . "LINE")
                 (0 . "LWPOLYLINE")
                 (0 . "ARC")
                 (-4 . "OR>")))
        )
  (if (and sset sfirst)
    (progn
      (setq ename (ssname sfirst 0)) ;get name of first object
      (setq etype (cdr (assoc 0 (entget ename)))) ;get object type
      (ssadd ename sset)
      (setq cnt 0)

      ;; if first object is a LWPOLYLINE ...
      (if (= "LWPOLYLINE" etype)
        (progn
          (setq cnt (1+ cnt))
        ;; then: join objects into POLYLINE
        (command "._PEDIT" ename "_J" sset "" "")
        )
        ;; else: convert object and join them
        (command "._PEDIT" ename  "_Y" "_J" sset "" "")
        )
      ;;  check for deleted enames
       (setq i -1)
       (while (setq ename (ssname sset (setq i (1+ i))))
         (or (entget ename) (setq cnt (1+ cnt)))
       )
      (prompt (strcat "\nNumber of objects joined is " (itoa cnt) ))
      )
    (prompt "\nNo objects selected.")
    )

  (*error* nil)
  (princ)
  )

[sinc]

As near as I can make out, the only purpose of this routine is to suppress the message that asks you "Object is not a polyline; do you want to turn it into one?" when you have lines or arcs in your selection set.  Is that the case?

If so, you can get the same effect by just setting PEDITACCEPT to 1.  Then the behavior of PEDIT JOIN is same as in this routine, and this routine is not needed.

[iradic]

Thanks for the solution ... and the tip...

'cnt' should be initialized too...

Thanks again

[iradic]

Here is the final version:

Code: [Select]

;;;   Based on PJOIN.LSP v1.1 by Zoltan Toth
;;;
;;;   Description:
;;;   This program takes any number of LINES, ARCS and/or LWPOLYLINES,
;;;   joins them into a single LWPOLYLINE if the objects are contiguous
;;;   and reports number of joined objects.
;;;

;;; define program name & localize variables
(defun c:pjoin (/ sfirst sset ename etype i cnt)

  ;; get objects to join into a single LWPOLYLINE
  (prompt "\nSelect first object:")
  (setq sfirst nil)
  (while (not (setq sfirst
                    (ssget "_:S" '((-4 . "<OR")
                                   (0 . "LINE")
                                   (0 . "LWPOLYLINE")
                                   (0 . "ARC")
                                   (-4 . "OR>")))))
         (princ " Select LINE, LWPOLINE or ARC...")
         )

  (setq ename (ssname sfirst 0)) ;get name of first object
  (redraw ename 3)

  (prompt "\nSelect objects to join into a polyline:")
  (while (not (setq sset
                    (ssget '((-4 . "<OR")
                             (0 . "LINE")
                             (0 . "LWPOLYLINE")
                             (0 . "ARC")
                             (-4 . "OR>")))))
         (princ "Select LINE, LWPOLINE or ARC...")
         )

  (redraw ename 4)

  (if (and sset sfirst)
    (progn
      (setq etype (cdr (assoc 0 (entget ename)))) ;get object type
      (ssdel ename sset) ;correct report

      ;; if first object is a LWPOLYLINE ...
      (if (= "LWPOLYLINE" etype)
        ;; then: join objects into LWPOLYLINE
        (command "._PEDIT" ename "_J" sset "" "")
        ;; else: convert object and join them
        (command "._PEDIT" ename  "_Y" "_J" sset "" "")
        )

      ;; check for deleted enames and report
      (setq i -1 cnt 0)
      (while (setq ename (ssname sset (setq i (1+ i))))
             (or (entget ename) (setq cnt (1+ cnt))))
      (prompt (strcat (itoa cnt) " joined, "
                      (itoa (- i cnt)) " left"))
      )
    (prompt "\nNo objects selected")
    )
  )

(princ "\nPJOIN - join contiguous plines, lines and arcs")
(princ)

Thanks for your help bye