Topic: Get random number between 2 numbers

[BazzaCAD]

Is there a better why of doing this?

Code: [Select]

;;;Random number generation function - based on the linear
;;; congruential method as presented in Doug Cooper's book
;;; Condensed Pascal, pp. 116-117.
;;; Returns a random number between 0 and 1.
(defun randomize (/ modulus multiplier increment random)
  (if (not daed_seed)
    (setq daed_seed (getvar "DATE"))
  )
  (setq modulus    65536
        multiplier 25173
        increment  13849
        daed_seed  (rem (+ (* multiplier daed_seed) increment) modulus)
        random     (/ daed_seed modulus)
  )
)

(defun RandNumBtwn2Nums (in out / num)
  (while (not (and (setq num (fix (* 100 (randomize))))
              (>= num in)
              (<= num out)
         ))
  )
  num
)


[MP]

Wasn't that one penned by Kenny Ramage?

Here's one I have --

Code: [Select]

(defun _Random ( )

    ;;  Original lisp version attributable to Paul Kahut,
    ;;  who translated an algorythm from a Visual C 4.1
    ;;  library. Abused by MP so it's self initializing
    ;;  and returns a float between 0 and 1 rather than
    ;;  an int.

    (/
        (+ 2147483648
            (setq *randomseed*
                (+
                    (*
                        (if (numberp *randomseed*)
                            (fix *randomseed*)
                            (getvar "millisecs")
                        )
                        214013
                    )
                    2531011
                )
            )
        )
        4294967295.0
    )   
)

[BazzaCAD]

thx but that only returns a number between 0 & 1 not between two given numbers...

[VovKa]

Code: [Select]

(+ in (* (- out in) (randomize)))


[JohnK]

Here are the only one(s) i got (looks much the same as yers).

Code: [Select]

(defun getrandnum ( minNum maxNum / randnum )
    ;; Getrandnum returns a real number between minNum and maxNum.
    ;;
    ;; By: Stig Madsen
    (defun randnum ( / modulus multiplier increment random)
      ;; Randnum.lsp
      ;; Returns a random number.
      ;; Written by Paul Furman, 1996.
      ;; Based on algorithm by Doug Cooper, 1982.
      (if (not seed)
        (setq seed (getvar "DATE")))
      (setq modulus    65536
                multiplier 25173
                increment  13849
                seed  (rem (+ (* multiplier seed) increment) modulus)
                random (/ seed modulus)) )
    (if (not (< minNum maxNum))
      (progn
        (setq tmp minNum
              minNum maxNum
              maxNum tmp
              )
        )
      )
    (setq random (+ (* (randnum) (- maxNum minNum)) minNum))
    )

[It's Alive!]

http://www.theswamp.org/index.php?topic=13837.0 

[BazzaCAD]

cool thx guys.

[taner]

Code: [Select]

;;; ==================================================================
;;; 求随机数(0~1)－－ｂｙ　狂刀
(defun txt-rnd ()        ; 随机数种子
  (* (rem (getvar "cputicks") 1e3) 1e-3)
)
;;; ==================================================================
;;; 求ｎ个ａ～ｂ随机数列表----ｂｙ　狂刀
(defun txt-rnd-rlst (a b n / c lst)    ; 随机数表
  (setq c (- b a))
  (repeat n
    (setq lst (cons (+ a (* (txt-rnd) c)) lst))
  )
)
;;; ==================================================================
;;; 返回在a~b內的n個随机整数的列表
(defun txt-rnd-ilst (a b n / lst c)    ; 随机整数表
  (setq c (- b a))
  (repeat n
    (setq lst (cons (fix (+ a (* (txt-rnd) c))) lst))
  )
)
;;; ==================================================================
(defun txt-rnd-i (a b)        ; 单个随机整数
  (car (txt-rnd-ilst a b 1))
)
(defun txt-rnd-r (a b)        ; 单个随机数
  (car (txt-rnd-rlst a b 1))
)
;;; ==================================================================
;;; 随机取出表中元素
(defun txt-rnd-lst (lst / len n rndoflst)
  (if (> (setq len (length lst))
0
      )
    (setq n (txt-rnd-i 0 len)
  rndoflst (nth n lst)
    )
  )
  rndoflst
)
;;; ==================================================================

[Cathy]

xkcd:

[Cathy]