Topic: Reload Linetype in accadoc.lsp ?

[Zykl0]

Hello,

I am trying to reload every linetype automaticly when I open a drawing according to the drawing measurement units.
The two first line (insunits and snapunit) work flawlessly, however the reload linetype doesn't work.

Any workaround?

Code: [Select]

(cond ((= (getvar "MEASUREMENT") 0) ;MEASUREMENT=0 (inches)
            (setvar "insunits" 1)
            (command "snapunit" "12,12")
            (command "._linetype" "_load" "*" "acad" "")
           )
           ((= (getvar "MEASUREMENT") 1) ;MEASUREMENT=1 (millimeters)
            (setvar "insunits" 4)
            (command "snapunit" "300,300")
            (command "._linetype" "_load" "*" "acadiso" "")
           )
     ) ;_ cond


[roy_043]

You will have to loop over the line types that are already defined.
You can use the (tblnext "ltype" ...) for that.

[Zykl0]

Doesn't work, maybe I do it wrong?

Code: [Select]

(cond ((= (getvar "MEASUREMENT") 0) ;MEASUREMENT=0 (inches)
            (tblnext "ltype")
            (command "._linetype" "_load" "*" "acad" "")
           )
           ((= (getvar "MEASUREMENT") 1) ;MEASUREMENT=1 (millimeters)
            (tblnext "ltype")
            (command "._linetype" "_load" "*" "acadiso" "")
           )
     ) ;_ cond


[roy_043]

Coding is more than copy+paste. Why don't you study the mentioned function first.

[Kerry]

I use this

Code - Auto/Visual Lisp: [Select]

1. (COMMAND "EXPERT" 5 "LINETYPE" "L" "*" "ACADiso" "" )

[Zykl0]

the command (command "._linetype" "_load" "*" "acadiso" "") or (COMMAND "EXPERT" 5 "LINETYPE" "L" "*" "ACADiso" "" ) work flawlessly in a macro, in another lisp or directly in the command prompt. I don't get it why it doesn't work in acadoc.lsp

[ronjonp]

the command (command "._linetype" "_load" "*" "acadiso" "") or (COMMAND "EXPERT" 5 "LINETYPE" "L" "*" "ACADiso" "" ) work flawlessly in a macro, in another lisp or directly in the command prompt. I don't get it why it doesn't work in acadoc.lsp

(command "._linetype" "_load" "*" "acadiso" "")  will only work if you're not redefining existing linetypes ... otherwise it will prompt "Linetype "SomeLineTypeName" is already loaded.  Reload it? <Y> y". Use Kerry's suggestion.

[Lee Mac]

Try the following in your acaddoc.lsp:

Code - Auto/Visual Lisp: [Select]

1. (defun ltredef ( / lin val var )
2.     (setq var '(cmdecho expert)
3.           val  (mapcar 'getvar var)
4.           lin  (if (zerop (getvar 'measurement)) "acad" "acadiso")
5.     )
6.     (mapcar 'setvar var '(0 5))
7.     (command "_.-linetype" "_L" "*" lin "")
8.     (mapcar 'setvar var val)
9.     (princ)
10. )
11. (if (= 'list (type s::startup))
12.     (setq s::startup (append s::startup '((ltredef))))
13.     (defun-q s::startup nil (ltredef))
14. )
15. (princ)

The above is untested.

[Kerry]

<...> I don't get it why it doesn't work in acadoc.lsp

That exact (my) code is from a file that is used daily by several offices and has been for at least 10 years.

I just now added it to an acaddoc.lsp and it works without fail on several test drawings

[MP]

I use this

Code - Auto/Visual Lisp: [Select]

1. (COMMAND "EXPERT" 5 "LINETYPE" "L" "*" "ACADiso" "" )

Hate stepping on toes but if going the simplified route may I suggest:

(command "cmdecho" 0 "expert" 5 ".linetype" "_L" "*" "ACADiso" "" "expert" 0 "cmdecho" 1)

[Kerry]

Hi Michael,
No fear !

I do all my housekeeping before and after that call ... but yes, housekeeping is needed.

[MP]

I do all my housekeeping before and after that call ...

I've no doubt, I recognize the snip is but one line from likely hundreds or more.

Cheers!

[roy_043]

I didn't know about the use of "EXPERT" in this context. But I have also misinterpreted the word 'reload' in the OP. So there actually are people out there who want ALL linetypes from acad(iso).lin in their drawings...