Topic: CMDACTIVE/Reactor Question

[Kerry]

Do you want to keep each backup version ?

[Kerry]

Have a play with something like this :-

Code: [Select]

;;; KDUB_AUTO-SaveTime.lsp
;;; add this to your .MNL file
;;; (or (VL-SYMBOL-VALUE  'kdub:AutoSave) (load "KDUB_AUTO-SaveTime.LSP") )
;;;
(vl-load-com)
(setvar "SaveTime" 10)

(princ (strcat "\n'KDUB_AUTO-SaveTime' loaded, SaveTime set to " (itoa (getvar "SaveTime")) ".\n"))


;; based on Code by James Allen  http://discussion.autodesk.com/forums/message.jspa?messageID=4289494#4289494
;; Revised by KDUB@theSwamp 2010.02.24
;;;  AutoSave makes a copy of AutoCAD's current autosave file.
;;
(defun kdub:autosave (rxrnm           cmdinf          /
                      activedocument  date            savefilename
                      autosavefilename                juliansavetime
                      mwe:getvar
                     )
  ;;---------------------------------------------------------------------- 
;;; Getvar using ActiveX
  (defun mwe:getvar (arglst)
    (vlax-invoke activedocument 'getvariable arglst)
  )
  ;;----------------------------------------------------------------------
  (setq activedocument (vlax-get (vlax-get-acad-object) 'activedocument)
        date           (mwe:getvar "date")
        savefilename   (findfile (mwe:getvar "savefile"))
  )
  (if (and savefilename asv:timetosave (>= date asv:timetosave))
    (progn
      (setq autosavefilename
             (strcat
               (mwe:getvar "savefilepath")
               "\\AutoSave "
               (vl-filename-base (mwe:getvar "dwgname"))
               "_"
               (rtos (* (mwe:getvar "cdate") 1000000) 2 0)
               ".dwg"
             )
      )
      (prompt
        (strcat "\nKDUB_AUTO-SaveTime: Backing up autosave file ...\n"
                autosavefilename
                "\n"
        )
      )
      (if (findfile autosavefilename)
        (vl-file-delete autosavefilename)
      )
      (vl-file-copy savefilename autosavefilename)
      (setq asv:timetosave nil)
    )
  )
  (if (not asv:timetosave)
    (setq ;; one minute is 0.000694444444445 days
          juliansavetime (* (mwe:getvar "savetime") 0.000694444444445)
          asv:timetosave (+ date (* juliansavetime 0.20))
    )
  )
  (princ)
)




;;; Load the AutoSave Reactor
(vlr-command-Reactor "Command reactor" '((:vlr-commandWillStart . KDUB:AutoSave)))

(princ)

[Kerry]

just be prepared to regularly clean out the folder pointed to by (getvar "savefilepath")

[Kerry]

Then there is something like this
http://www.theswamp.org/index.php?topic=17552.msg212071#msg212071

which requires the user to DECIDE to save/backup an archive.

[Chris]

Do you want to keep each backup version ?

I have another program that cleans out the folder on the first of each month, so we have no more than 2 months worth of backups at any point in time. so cleaning it up isnt really a concern.
it sounds like your program is very similar to mine, it checks dates saves the file and creates a backup, however I noticed yours runs on command will start, mine runs on command ended.  Is it better to do one than the other?