Topic: Undo is not working in my routine

[Tharwat]

Hello .

Here is a routine that I have just finished writing it , but the start undo besides end undo functions are not working with it after
invoking the routine .

Any thoughts please ?

Code: [Select]

(defun c:TesT (/ *error* acdoc Blocks)
; Tharwat 07. 03. 2011
  (vl-load-com)
  (defun *error* (msg)
    (and (vla-EndUndoMark acdoc))
    (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
        (princ (strcat "\n** Error: " msg " **"))
    )
    (princ)
  )
  (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
  (vla-StartUndoMark acdoc)
  (vlax-for Blocks
            (vla-get-blocks
              (setq
                acdoc (vla-get-activedocument (vlax-get-acad-object))
              )
            )
    (if (and (eq (vla-get-isXref Blocks) :vlax-false)
             (eq (vla-get-isLayout Blocks) :vlax-false)
        )
      (vlax-for vl Blocks
        (vla-put-color vl 256)
      )
    )
  )
  (vla-regen acdoc acActiveViewport)
  (vla-EndUndoMark acdoc)
   (princ)
)

Thanks.

Tharwat

[Tharwat]

Actually the undo is working , but I've got to regenall after the undo invokes .

That's odd isn't it ? 

[alanjt]

Actually the undo is working , but I've got to regenall after the undo invokes .

That's odd isn't it ? 

Not really. You had to execute a regen to display your changes.

[Tharwat]

Actually the undo is working , but I've got to regenall after the undo invokes .

That's odd isn't it ? 

Not really. You had to execute a regen to display your changes.

Right , So it's normal to regen after undoing .

Thanks

[alanjt]

Actually the undo is working , but I've got to regenall after the undo invokes .

That's odd isn't it ? 

Not really. You had to execute a regen to display your changes.

Right , So it's normal to regen after undoing .

Thanks

[Tharwat]

OK, the same issue but with single selection set .

This routine is not responding as needed .  :realmad:

So any guidance ?

Code: [Select]

(defun c:TesT (/ acdoc ss )
; Tharwat 07. 03. 2011
  (vl-load-com)
  (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
  (if (setq ss (ssget "_+.:S" '((0 . "INSERT"))))
    (vlax-for Blocks
              (vla-item (vla-get-blocks acdoc) (vlax-ename->vla-object (ssname ss 0)))
      (if (and (eq (vla-get-isXref Blocks) :vlax-false)
               (eq (vla-get-isLayout Blocks) :vlax-false)
          )
        (vlax-for vl Blocks
          (vla-put-color vl 256)
        )))
    (princ)
  )
  (vla-regen acdoc acActiveViewport)
  (princ)
)

Thanks.

Tharwat

[pBe]

Code: [Select]

(defun c:TesT (/ acdoc ss )
; Tharwat 07. 03. 2011
  (vl-load-com)
  (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
  (if (setq ss (ssget "_+.:S" '((0 . "INSERT"))))
    (vlax-for Blocks
              (vla-item (vla-get-blocks acdoc) [color=blue](vla-get-effectivename [/color] (vlax-ename->vla-object (ssname ss 0))))
          (vla-put-color blocks 256)
        )
    (princ)
  )
  (vla-regen acdoc acActiveViewport)
  (princ)
)
I could have sworn this code was resolved at CADTUTOR forum Tharwat .. anyhoo , remove some unecessary codes on your post, unless you have a block/xref inside your block, but thats another matter altogether...  

[Tharwat]

I could have sworn this code was resolved at CADTUTOR forum Tharwat .. anyhoo , remove some unecessary codes on
your post, unless you have a block/xref inside your block, but thats another matter altogether...  

Thank you for that clarification .

And I do not remember if these codes were resolved before in Cadtutor , where I a part of the thread ?

If there were , I would not ask .

Appreciated a lot pBe.

[AIberto]

@Tharwat

Hi Tharwat.

Have you find ways to solve this problem yet?  REGEN after UNDO  . use reactor  ?

[ronjonp]

@Tharwat

Hi Tharwat.

Have you find ways to solve this problem yet?  REGEN after UNDO  . use reactor  ?

Look into VLA-UPDATE.

[Tharwat]

@Tharwat

Hi Tharwat.

Have you find ways to solve this problem yet?  REGEN after UNDO  . use reactor  ?

Hi,
I did not solve that issue in that time but I think now I can write a reactor function to regen the document if a user called the undo command and of course if the function Undoreactor-on is already invoked.

Try the following:

Code - Auto/Visual Lisp: [Select]

1. (defun c:UndoReactor-on nil
2.   ;; Tharwat 26.Apr.2016        ;;
3.   (if (vl-some '(lambda (r) (= (vlr-data r) "undo:me"))
4.                (cdar (vlr-reactors :vlr-command-reactor))
5.                )
6.     (alert "Reactor is already running !")
7.     (vlr-command-reactor
8.       "undo:me"
9.       '((:vlr-commandEnded . UndoMe))
10.       )
11.     )
12.   (princ)
13.   )
14. ;;                                              ;;
15. (defun c:UndoReactor-off nil
16.   (if (vl-some
17.         '(lambda (r) (and (= (vlr-data r) "undo:me") (vlr-remove r)))
18.         (cdar (vlr-reactors :vlr-command-reactor))
19.         )
20.     (alert "Reactor is Deactivated now !")
21.     (princ "\nReactor in not yet activated !")
22.     )
23.   (princ)
24.   )
25. ;;                                              ;;
26. (defun Undome (r c)
27.   (if (and (eq (vlr-data r) "undo:me")
28.            (wcmatch (strcase (car c)) "UNDO,U")
29.            )
30.     (progn
31.       (vla-regen (vla-get-activedocument (vlax-get-acad-object)) acActiveViewport)
32.       (princ "\nRegen generated by a reactor ...")
33.       )
34.     )
35.   (princ)
36.   )
37.  

[AIberto]

Hip, Hip Hurray  .A great  reactor function . Thank you Tharwat.

[Tharwat]

Hip, Hip Hurray  .A great  reactor function . Thank you Tharwat.

You are welcome AIberto.