Topic: Civil3D - Zoom to Structure Command?

[MSTG007]

Does anyone know what the Zoom to Structure command is? (Rather than opening the toolspace etc)?

Thanks guys!

[Jeff_M]

There is no command for this. It's done with programming when selecting that option in Prospector. A small lisp could likely be written to do this, though.

[MSTG007]

I was looking at possibly adding this in a VBA Excel (using sendkeys).

[Jeff_M]

Do you have the Position of the structure in Excel? If so, you could use the normal Autocad Zoom Center command and pass the X & Y values to it. Here is a quickly written lisp that will do this within C3D, user must enter the name of the structure. Command name is zm2struc

Code - Auto/Visual Lisp: [Select]

1. (defun c:zm2struc (/ *ACAD* C3D C3DDOC LOCATION NTWRK NTWRKS PROD PRODSTR PT STRC STRCNAME STRUCTURES)
2.   (vl-load-com)
3.   (setq prod (vlax-product-key))
4.   (setq prodStr (strcat "AeccXUiPipe.AeccPipeApplication"
5.                         (cond ((vl-string-search "\\R17.0\\" prod)
6.                                ".4.0"
7.                               )
8.                               ;;2007
9.                               ((vl-string-search "\\R17.1\\" prod)
10.                                ".5.0"
11.                               )
12.                               ;;2008
13.                               ((vl-string-search "\\R17.2\\" prod)
14.                                ".6.0"
15.                               )
16.                               ;;2009
17.                               ((vl-string-search "\\R18.0\\" prod)
18.                                ".7.0"
19.                               )
20.                               ;;2010
21.                               ((vl-string-search "\\R18.1\\" prod)
22.                                ".8.0"
23.                               )
24.                               ;;2011
25.                               ((vl-string-search "\\R18.2\\" prod)
26.                                ".9.0"
27.                               )
28.                               ;;2012
29.                               ((vl-string-search "\\R19.0\\" prod)
30.                                ".10.0"
31.                               )
32.                               ;;2013
33.                               ((vl-string-search "\\R19.1\\" prod)
34.                                ".10.3"
35.                               )
36.                               ;;2014
37.                               (t "")
38.                         )
39.                 )
40.   )
41.   (if (and (setq *acad* (vlax-get-acad-object))
42.            (setq C3D (vla-getinterfaceobject *acad* prodStr))
43.            (setq C3Ddoc (vla-get-activedocument C3D))
44.       )
45.     (progn
46.       (setq ntwrks (vlax-get c3ddoc 'pipenetworks))
47.       (setq strcname (getstring "\nStructure name to zoom to: " t))
48.       (vlax-for ntwrk ntwrks
49.         (if (not strc)
50.           (progn
51.             (vl-catch-all-apply '(lambda ()
52.             (setq structures (vlax-get ntwrk 'structures))
53.             (setq strc (vlax-invoke structures 'item strcname))
54.                                    )
55.               '())
56.           )
57.         )
58.       )
59.       (if strc
60.         (progn
61.           (setq location (vlax-get strc 'position))
62.           (setq pt (list (vlax-get location 'x) (vlax-get location 'y)))
63.           (command "zoom" "c" pt "")
64.         )
65.         (progn
66.           (princ (strcat "\nStructure \"" strcname "\" not found."))
67.         )
68.       )
69.     )
70.   )
71.   (princ)
72. )
73.  
74.  

[MSTG007]

Way cool. Is there a way to place a zoom factor in? (If I am zoomed out / it centers the screen on the structure. If I zoom in closer it zooms right to it.
Again. WAY COOL. Thank you!

Code: [Select]

(defun c:zm2st (/ *ACAD* C3D C3DDOC LOCATION NTWRK NTWRKS PROD PRODSTR PT STRC STRCNAME STRUCTURES)
(vl-load-com)
(setq prod (vlax-product-key))
(setq prodStr (strcat "AeccXUiPipe.AeccPipeApplication"
(cond ((vl-string-search "\\R17.0\\" prod)
       ".4.0"
      )
      ;;2007
      ((vl-string-search "\\R17.1\\" prod)
       ".5.0"

      )

      ;;2008

      ((vl-string-search "\\R17.2\\" prod)

       ".6.0"
      )

      ;;2009

      ((vl-string-search "\\R18.0\\" prod)

       ".7.0"
      )

      ;;2010

      ((vl-string-search "\\R18.1\\" prod)

       ".8.0"

      )

      ;;2011

      ((vl-string-search "\\R18.2\\" prod)

       ".9.0"
      )

      ;;2012

      ((vl-string-search "\\R19.0\\" prod)
       ".10.0"

      )

      ;;2013

      ((vl-string-search "\\R19.1\\" prod)

       ".10.3"

      )

      ;;2014
      (t "")

)

)

  )

  (if (and (setq *acad* (vlax-get-acad-object))

   (setq C3D (vla-getinterfaceobject *acad* prodStr))

   (setq C3Ddoc (vla-get-activedocument C3D))

      )

    (progn

      (setq ntwrks (vlax-get c3ddoc 'pipenetworks))

      (setq strcname (getstring "\nStructure name to zoom to: " t))

      (vlax-for ntwrk ntwrks

(if (not strc)

  (progn

    (vl-catch-all-apply '(lambda ()

    (setq structures (vlax-get ntwrk 'structures))

    (setq strc (vlax-invoke structures 'item strcname))

   )
      '())

  )

)

      )

      (if strc

(progn

  (setq location (vlax-get strc 'position))

  (setq pt (list (vlax-get location 'x) (vlax-get location 'y)))

(command "zoom" "c" pt "")

)

(progn

  (princ (strcat "\nStructure \"" strcname "\" not found."))

)

      )

    )

  )

  (princ)

)
 

 



[Jeff_M]

To set a scale factor, replace the empty "" in this line:
(command "zoom" "c" pt "")
with your desired factor. Or, remove the "" entirely and it will prompt you for the scale factor.

[MSTG007]

sweet! Thank you again!