Topic: Rename files to attribute within title block

[shollinger]

I am looking for a script or something similar to rename several files to the dwg. no. attribute with-in the title block.  Currently file names are piping line numbers but upon submission to client they have to be renamed to client specific file names.(drawing numbers).  Any ideas?

Stephen
shollinger@rdcon.com

[Kerry]

You'll need to provide a sample drawing or the attribute tag names
if you want more than a confirmation it can be done
and generic description of how to do it.

.. doing a Save-as rather than a rename may be more expedient.

[ronjonp]

This should get you going...not heavily tested:

To use call (batchrename "nameofblock" "tagname")

Have fun 

Code: [Select]

(defun rjp-dir (message / sh folder result)
  (setq sh (vla-getInterfaceObject
     (vlax-get-acad-object)
     "Shell.Application"
   )
  )
  (setq folder
(vlax-invoke-method
   sh 'BrowseForFolder 0 message 0)
  )
  (vlax-release-object sh)
  (if folder
    (progn
      (setq result
     (vlax-get-property
       (vlax-get-property folder 'Self)
       'Path
     )
      )
      (if (/= (substr result (strlen result)) "\\")
(setq result (strcat result "\\"))
result
      )
    )
  )
)

(defun batchrename
       (BLKNAME TAG / ATTS DIR DOC FILES ODBX RENAME VNUM X)
  (setq dir   (rjp-dir "Select a folder to process drawings")
files (mapcar '(lambda (x)
(strcat dir x)
       )
      (vl-directory-files dir "*.dwg" 0)
      )
vnum  (substr (getvar 'acadver) 1 2)
doc   (vlax-get-acad-object)
odbx  (if (< vnum "16")
(vla-GetInterfaceObject doc "ObjectDBX.AxDbDocument")
(vla-GetInterfaceObject
  doc
  (strcat "ObjectDBX.AxDbDocument." vnum)
)
      )
  )
  (if files
    (foreach dwg files
      (if (vl-catch-all-error-p
    (vl-catch-all-apply 'vla-open (list odbx dwg))
  )
(prompt (strcat "\nCould not open DWG - " dwg))
(progn
  (prompt (strcat "\nProcessing - " dwg))
  (vlax-for l (vla-get-layouts odbx)
    (vlax-for ent (vla-get-block l)
      (if (and (eq (vla-get-objectname ent)
   "AcDbBlockReference"
       )
       (eq (strcase (vla-get-name ent))
   (strcase BLKNAME)
       )
  )
(progn
  (foreach att (vlax-invoke ent 'getattributes)
    (if (eq (vla-get-tagstring att)
    (strcase TAG)
)
      (setq rename (strcat dir
   (vla-get-textstring att)
   ".dwg"
   )
      )
    )
  )
)
      )
    )
  )
  (if (not rename)
    (setq rename (vla-get-name odbx))
  )
  (vl-catch-all-error-p
    (vl-catch-all-apply
      'vla-saveas
      (list odbx rename)
    )
  )
  (setq rename nil)
)
      )
    )
  )
  (princ)
)

(batchrename "RUB_ISO_BORDER" "DWGNO")

[shollinger]

Ron,
Trying to use your code.  Looks like this would be the best route for us here.  I can get it to process the drawings but to no avail will it rename them to the correct value.  Do I need to substitute my block name and tag value in here.  Besides at the call command.
(batchrename "RUB_ISO_BORDER" "DWGNO")

[ronjonp]

If you post a sample drawing (as Kerry mentioned) this would be much easier to troubleshoot.

Ron

[shollinger]

Thanks again

[ronjonp]

I updated the code above...ran this (batchrename "RUB_ISO_BORDER" "DWGNO") and it worked over here. Let me know if it works for you. Keep in mind that this routine does not process subdirectories.

Ron

[shollinger]

so the change was
(if (not rename)      near the end. 
I have only worked with lisp in the past.  I need to get into this vba.  Much better for the things I need to do around here.  Have any suggestions on tutorials to get me started. 

[ronjonp]

Shollinger,

This is lisp\vlisp not VBA. I loop through the drawings and check to see if the block with the correct tagname exists...if it does the value from the att is extracted and put into the rename variable. If the variable is not set (not rename) then set rename to the original name of the drawing. As far as resources.....right where you're at does not get much better

So I assume this worked for you?

[shollinger]

Ran on a test folder and work perfectly.  I will be able to set this up for multiple departments and there individual needs.   I will look into the links for some vlisp help and get into this.  I will be able to go to owners with ROI.  Thanks again for all your help.

[ronjonp]

Glad it worked for you...