Topic: bent ! or what ?

[Kerry]

Geeze I love my job !

Code: [Select]

(KB:ASSERT
    '(OR
      (VL-SYMBOL-VALUE 'GML:MTLColumnSetout)
      (AND       
       (OR (VL-SYMBOL-VALUE 'GML:MaterialConfig) (MATERIAL:INITIALISE))
       GML:MTLHeaderName
       (SETQ
        tmpTagList
        (_MATERIAL_column_Setout
         (SSGET "X" (LIST (CONS 0 "INSERT") (CONS 2 GML:MTLHeaderName)))
        )
       )
       (SETQ
        GML:MTLColumnSetout
        (MAPCAR '(LAMBDA (pair) (CONS (CAR pair) (READ (CDR pair)))) tmpTagList)
       )
      )
     )
    "Unable to Initialise Material Column Settings"
)
;;-----------------------------------------
(defun kb:assert (teststatement message)
  (if (not (eval teststatement))
    (progn (kb:display-message
             " **** Assertion Failure"
             (if message
               message
               (list (vl-prin1-to-string teststatement) " ==>> nil/null")
             )
           )
           ;; decide what to do here later ?
           (if KG:debug_on
             (princ "  ")
             (exit)
           )
    )
  )
  (princ)
)
;;-----------------------------------------
(defun kb:display-message (prefix mess)
  (mapcar 'princ
          (list "\n"
                (if (= (type prefix) 'str)
                  prefix
                  "; **** ERROR"
                )
                ": "
          )
  )
  (if (vl-consp mess)
    (mapcar 'princ mess)
    (princ mess)
  )
  (princ)
)
;;;----------------------------------------------------------------------------
 (DEFUN _MATERIAL_column_Setout (ss / obj)
     (IF (SETQ obj (SSNAME ss 0))
         (MAPCAR
             '(LAMBDA (att) (CONS (VLA-GET-TAGSTRING att) (VLA-GET-TEXTSTRING att)))
             (VLAX-INVOKE (VLAX-ENAME->VLA-OBJECT obj) 'getconstantattributes)
         )
     )
 )
;;;---------------------------------------------------------------------------- 


[Kerry]

The algorithm looked something like this { but scribbled on a couple of sheets of A4 paper }

Test  Global variable exists .. if so move along

else  do we know the block name
if not, initialise { read ini file based on project }

test if the header block exists,
if so read the hidden attributes into a pairs list
convert the string values in the pair list into reals.

If anything fails, skip out and go home.

Depending on the block , returns something like this :
(("QTY" . 37.5) ("REMARK" . 128.5) ("MASS" . 191.5) ("LENGTH" . 121.5) ("DESC" . 42.5) ("TAG" . 15))

which are X ordinates for placing MText in columns in a material List

[CAB]

Geeze I love my job !

And quite good at too.