Topic: Target property in Viewport

[Lee Mac]

I have been trying to modify the target property for a viewport, for a LISP I am helping a guy with, but I don't seem to be having much luck.

I have wrapped the business end of the code in a vl-catch-all-apply, so I dont expect an error, but, even when testing without this wrapper, I don't get an error, just nothing happens to the target point.

Perhaps I am barking up the wrong tree, but any help is appreciated.

Lee

Code: [Select]

(defun c:MacVP (/ ent1 ent2 Obj1 Obj2)
  (vl-load-com)

  (while
    (progn
      (setq ent1 (car (entsel "\nSelect Source Viewport: ")))
      (cond ((eq 'ENAME (type ent1))
             (if (eq "VIEWPORT" (cdadr (entget ent1)))
               (while
                 (progn
                   (setq ent2 (car (entsel "\nSelect Second Viewport: ")))
                   (cond ((eq 'ENAME (type ent2))
                          (if (not (eq "VIEWPORT" (cdadr (entget ent2))))
                            (princ "\n** Object is not a Viewport **")))
                         (t (princ "\n** No Viewport Selected **")))))
               (princ "\n** Object is not a Viewport **")))
            (t (princ "\n** No Viewport Selected **")))))

  (vl-catch-all-apply
    (function
      (lambda ( )
        (foreach prop '(Target Center)
          (vlax-put-property
            (setq Obj2 (vlax-ename->vla-object ent2)) prop
              (vlax-3D-point
                (append
                  (list
                    (car
                      (vlax-get
                        (setq Obj1 (vlax-ename->vla-object ent1)) prop)))
                  (cdr (vlax-get Obj2 prop))))))
        (vla-put-width Obj2 (vla-get-Width Obj1)))))

  (princ))


[T.Willey]

It changes the ' target ' property on my test.

[Lee Mac]

Thanks for the response Tim.

On mine, the target property is always (0,0,0) no matter how the objects inside are moved. 

[Spike Wilbury]

no idea what it does....  

but on the little test i did, it overlap two vp's

so it does something.... here


edit: tested on a2009

[T.Willey]

Thanks for the response Tim.

On mine, the target property is always (0,0,0) no matter how the objects inside are moved. 

I'm in '06 if that matters at all.

[Lee Mac]

Sorry guys,

I should've explained a bit more.. 

Two Viewports should be aligned by x-coordinate, and the widths of both should be equal. Also, the modelspace view (target, I think) should be aligned also by X coordinate -- but this is the part I am struggling to achieve.

I find that no matter what the modelspace view is, the target property on every VP is always '(0 0 0).

Thanks for the continued support,

Lee

[Spike Wilbury]

Sorry guys,

I should've explained a bit more.. 

Two Viewports should be aligned by x-coordinate, and the widths of both should be equal. Also, the modelspace view (target, I think) should be aligned also by X coordinate -- but this is the part I am struggling to achieve.

I find that no matter what the modelspace view is, the target property on every VP is always '(0 0 0).

Thanks for the continued support,

Lee

mention your acadver

[T.Willey]

I think the only way to get the viewport center is to activate it, and then grab the system variable ' viewctr '.

[Lee Mac]

Sorry guys,

I should've explained a bit more.. 

Two Viewports should be aligned by x-coordinate, and the widths of both should be equal. Also, the modelspace view (target, I think) should be aligned also by X coordinate -- but this is the part I am struggling to achieve.

I find that no matter what the modelspace view is, the target property on every VP is always '(0 0 0).

Thanks for the continued support,

Lee

mention your acadver

Ahh yes - ACAD 2010.

I think the only way to get the viewport center is to activate it, and then grab the system variable ' viewctr '.

Good idea, I'll give it a go mate

Lee

[Lee Mac]

Ok Tim,

I have tried your method, but to no avail unfortunately

Here is my current code:

Code: [Select]

(defun c:MacVP (/ ent1 ent2 Obj1 Obj2 ctr doc)
  (vl-load-com)

  (while
    (progn
      (setq ent1 (car (entsel "\nSelect Source Viewport: ")))
      (cond ((eq 'ENAME (type ent1))
             (if (eq "VIEWPORT" (cdadr (entget ent1)))
               (while
                 (progn
                   (setq ent2 (car (entsel "\nSelect Second Viewport: ")))
                   (cond ((eq 'ENAME (type ent2))
                          (if (not (eq "VIEWPORT" (cdadr (entget ent2))))
                            (princ "\n** Object is not a Viewport **")))
                         (t (princ "\n** No Viewport Selected **")))))
               (princ "\n** Object is not a Viewport **")))
            (t (princ "\n** No Viewport Selected **")))))

  (vl-catch-all-apply
    (function
      (lambda ( )
        (vlax-put-property
          (setq Obj2 (vlax-ename->vla-object ent2)) 'Center
            (vlax-3D-point
              (append
                (list
                  (car
                    (vlax-get
                      (setq Obj1 (vlax-ename->vla-object ent1)) 'Center)))
              (cdr (vlax-get Obj2 'Center)))))
        (vla-put-width Obj2 (vla-get-Width Obj1))
        (vlax-invoke-method Obj1 'Display :vlax-true)
        (vla-put-MSpace
          (setq doc
            (vla-get-ActiveDocument
              (vlax-get-acad-object))) :vlax-true)
        (setq ctr (vla-getVariable doc "VIEWCTR"))
        (mapcar
          (function
            (lambda (Obj Arg)
              (vlax-invoke-method Obj 'Display Arg)))
          (list Obj1 Obj2) '(:vlax-false :vlax-true))
        (vla-ZoomCenter
          (vlax-get-acad-object) ctr 1.)
        (mapcar
          (function
            (lambda (vp)
              (vla-put-Displaylocked vp :vlax-true)))
          (list Obj1 Obj2))
        (vla-Display Obj2 :vlax-false)
        (mapcar
          (function
            (lambda (Obj)
              (vlax-put-property Obj 'ViewportOn :vlax-true)))
          (list Obj1 Obj2)))))

  (princ))



[Crank]

Lee,

I'm not sure what you're trying to accomplish, but I think you should take a look at the code of aspace.lsp and vpsync.lsp (express tools).

[Lee Mac]

Thanks for the suggestion Crank - I didn't know those functions existed 'til now...   

I have tried them, but they don't seem to perform as I want this LISP to... perhaps this cannot be done 

[T.Willey]

I have tried them, but they don't seem to perform as I want this LISP to... perhaps this cannot be done 

It can be done.   

Just explain to us in words what you want, and I'm sure we can get it.  It you did already, then point me back to it, and we shall see what we can come up with.

[Lee Mac]

Where there's a will there's a way 

I explained the majority of the problem in reply #5, but if you need further clarification - just shout at me 

[T.Willey]

Here you go.  I think it does what you want.

Code: [Select]

(defun c:Testing (/ Sel MnList SecList tempPt tempSc ActDoc)
   
    (if
        (and
            (setq Sel (entsel "\n Select main viewport: "))
            (setq MnList (cons (cdr (assoc 69 (entget (car Sel)))) (vlax-ename->vla-object (car Sel))))
            (setq Sel (entsel "\n Select second viewport: "))
            (setq SecList (cons (cdr (assoc 69 (entget (car Sel)))) (vlax-ename->vla-object (car Sel))))
        )
        (progn
            (vlax-put
                (cdr SecList)
                'Width
                (vlax-get (cdr MnList) 'Width)
            )
            (vlax-put
                (cdr SecList)
                'Center
                (cons
                    (car (vlax-get (cdr MnList) 'Center))
                    (cdr (vlax-get (cdr SecList) 'Center))
                )
            )
            (vlax-put (setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object))) 'MSpace :vlax-true)
            (setvar 'CVport (car MnList))
            (setq tempPt (getvar 'ViewCtr))
            (setvar 'CVport (car SecList))
            (setq tempSc (vlax-get (cdr SecList) 'CustomScale))
            (vlax-invoke
                (vlax-get-Acad-Object)
                'ZoomCenter
                (cons
                    (car tempPt)
                    (cdr (getvar 'ViewCtr))
                )
                1.
            )
            (vlax-put (cdr SecList) 'CustomScale tempSc)
            (vla-put-MSpace ActDoc :vlax-false)
        )
    )
    (princ)
)

Funny thing I just found out.

(vlax-put ActDoc 'MSpace :vlax-false)  -  will Not work, but
(vla-put-MSpace ActDoc :vlax-false)  -  will.