Topic: Copy with initget

[mohan]

Dear Colleagues;

Please help to fix the route

Code - Auto/Visual Lisp: [Select]

1. (defun c:471st ( / ans cpy cpy1)
2. (princ "\nInitializing...")
3.    (initget 1 "Select Select-All")
4.    (setq ans (getkword "\nChoose your option as [Select/Select-All]: "))
5. (cond ((= ans "Select-all") (setq cpy (ssget "_x" '((410 . "Model"))))
6.                                (command "_.copybase" "_non" '(0 0) cpy "")
7.        )
8.      
9.       ((= ans "Select") (setq cpy1 (ssget))
10.                                    (command "_.copybase" "_non" '(0 0) cpy1 "")
11.        
12.        ))
13. (princ (strcat "\nmohan total of " (itoa (sslength cpy)) " Object(s) were copied with 0,0 base ... " )) (princ))

[Lee Mac]

"Select-all" should be "Select-All" for a start.

[mhupp]

I would just remove the initget entirely. So it ask for a selection and makes a copy. If nothing is selected it will then use the select all option on the current tab. could use some error handling if nothing is selected from the select all option.

Code - Auto/Visual Lisp: [Select]

1. (defun c:471st (/ cpy)
2.   (prompt "\nMake your Selection: ")
3.   (if (setq cpy (ssget))
4.     (command "_.copybase" "_non" '(0 0) cpy "")
5.     (progn
6.       (if (setq cpy (ssget "_X" (list (cons 410 (getvar 'CTAB))))) ;works on current tab instead of just model.
7.         (command "_.copybase" "_non" '(0 0) cpy "")
8.         (prompt "\nNothing Found")
9.       )
10.     )
11.   )
12.   (if cpy
13.     (prompt (strcat "\n" (itoa (sslength cpy)) " Object(s) were copied with 0,0 base ... " ))
14.   )
15.   (princ)
16. )

EDIT (Jon): Fixed Code tags.

[JohnK]

I would approach the task more like this:

Code - Auto/Visual Lisp: [Select]

1. (defun c:471st ( / ss)
2.   (princ "\nInitializing...")
3.   (initget 0 "Select Select-All")
4.   (setq ss
5.         (cond
6.           ((getkword "\nOption: [Select/Select-All] <Select-All>: ")
7.            (ssget))
8.           ((ssget "_x" '((410 . "Model"))))
9.           )
10.         )
11.   (command "_.copybase" "_non" '(0 0) ss "")
12.   (princ (strcat "\nmohan total of " (itoa (sslength ss)) " Object(s) were copied with 0,0 base ... " ))
13.   (princ)
14.   )

[mohan]

I would approach the task more like this:

Wonderful - 

[mohan]

I would just remove the initget entirely. So it ask for a selection and makes a copy. If nothing is selected it will then use the select all option on the current tab. could use some error handling if nothing is selected from the select all option.

It works for selecting object, but gives error for without selecting anything & press enter

[mhupp]

Tested the code inside BricsCAD Should work now.

[mohan]

Tested the code inside BricsCAD Should work now.

Now it works fine.