Topic: Print results of lisp routine on command line...

[hammonj7]

I am using a lisp routine to toggle some system variables that I change fairly often.  My lisp works just fine...for me.  However, my general users are interested in seeing an acknowledgment of the switch printed to the command line after the command has been executed.  Here is the code I am using:

(defun c:rnm ()
  (if (= (getvar "osmode") 1791)
  (setvar "osmode" 1088) ;Sets object snap mode to insertion point only
  (setvar "osmode" 1791) ;Sets object snap mode to "normal" osmode
    )
  (princ)
    )

Basically, I would like to use (princ "\nOsmode Insertion point set.") or whatever when my little routine runs.  So when it sees 1791 is active it changes it to 1088, then prints a confirmation to the command line, and vice versa.

I have a feeling this is simple, but for some reason the solution elludes me.

Thanks for your help!

 

[deegeecees]

I believe it would be something like this (not tested):

Code: [Select]

(defun c:rnm ()
  (setq result001 (if (= (getvar "osmode") 1791)
     (setvar "osmode" 1088) ;Sets object snap mode to insertion point only
     (setvar "osmode" 1791) ;Sets object snap mode to "normal" osmode
  ))
(print result001)
(princ)
)


[CAB]

To add a princ use this:

Code: [Select]

(defun c:rnm ()
  (if (= (getvar "osmode") 1791)
    (progn
      (setvar "osmode" 1088) ;Sets object snap mode to insertion point only
      (princ "\nOsmode Insertion point only set.")
    )
    (progn
      (setvar "osmode" 1791) ;Sets object snap mode to "normal" osmode
      (princ "\nOsmode set to \"normal\".")
    )
  )
  (princ)
)

AND welcome to The Swamp. 

[hammonj7]

   Thanks guys!  Both solutions work, I will test each out and see which is preferred by the group.

I appreciate your help!

And thanks for the welcome, I hope one day to be able to contribute answers instead of just questions! :whistle:

[Krushert]

And thanks for the welcome, I hope one day to be able to contribute answers instead of just questions! :whistle:

You already have; by asking the question.

Welcome to TheSwamp!

[Lee Mac]

Perhaps another solution - maybe more concise, but assumes that OSMODE is either 1791 or 1088 to begin with, else toggles the bits surrounding those in addition to the key values.

Code: [Select]

(defun c:rnm nil
  (princ
    (if
      (= 1791
        (setvar 'OSMODE
          (boole 6 (getvar 'OSMODE) 703)
        )
      )
      "\n<Normal OSnap>"
      "\n<Insertion Set>"
    )
  )
  (princ)
)