Topic: Problem with grread and allkeys

[mkweaver]

I understand that grread with bit 8 (allkeys) set should allow my routine to capture the escape key being pressed.  However, the routine below still gives me an "; error: Function cancelled", when I press the escape key.

What am I missing here?

Code: [Select]

(defun c:test2()
    (while (and ;loop until escape is pressed
   (setq readinfo (grread T (+ 1 2 4 8)))
   (not (and (= 2 (car readinfo))
     (= 27 (cadr readinfo))
)
   )
)
    (princ (strcat "\n" (vl-princ-to-string readinfo)))
    )
    (princ (strcat "\n\n" (vl-princ-to-string readinfo)))
  (princ)
  )
Mike

[CAB]

It may not display the error message but you still need to trap escape.
Here is one of my old test routines.

Code - Auto/Visual Lisp: [Select]

1. ;;  With trap for ESCape by CAB
2.  
3. (defun c:test2()
4.   (while ; stay in loop until one of the COND statements return nil
5.     (progn
6.       (setq input (vl-catch-all-apply 'grread (list T (+ 1 2 0)))
7.     (cond
8.       ((vl-catch-all-error-p input)
9.      (princ "\nPressed escape ")
10.      nil ; exit
11.       )
12.       ((= 5 (car input)) ; pointing device
13.        (cond
14.          ((and LastPT (< (distance (cadr input) LastPT) 0.0001))) ; no update if same point
15.          ((setq ent (nentselp (setq LastPT (cadr input))))
16.       (setq obj (vlax-ename->vla-object (car ent)))
17.       (princ (strcat "\nFound a " (vla-get-objectname obj) " at "(vl-princ-to-string (cadr ent))))
18.    )
19.        )
20.        t ; stay in loop
21.       )
22.       ((= 2 (car input)) ; Keyboard input
23.        (princ (vl-prin1-to-string input))
24.        t ; stay in loop
25.        )
26.       ((= 3 (car input))  ; Selected 3d point
27.        (if (setq ent (nentselp (cadr input)))
28.    (progn
29.       (setq obj (vlax-ename->vla-object (car ent)))
30.       (princ (strcat "\nFound a " (vla-get-objectname obj) " at the point selected: "(vl-princ-to-string (cadr ent))))
31.       )
32.    )
33.        t ; stay in loop
34.        )
35.       )
36.      )
37.     ) ; while
38.   (princ)
39.   )

[roy_043]

@ CAB: there is a parentheses missing on line 6.