Topic: Display number color of objects

[vnanhvu]

Anyone know how to display number color of objects without to Layer properti Manager? Ex.: I have layer 1 ( color bylayer set: red ( 1 ), i know color number of layer 1 without open Layer properties manager.
Thanks for all !

[alanjt]

Code: [Select]

(cdr (assoc 62 (tblsearch "LAYER" <LayerName>)))

[vnanhvu]

Can you help me with your code become complete command. Because  the knowledge that my limited and  sorry about messing with this.
Thanks again

[kruuger]

?

Code: [Select]

(defun c:CL (/ OB)
  (if (setq OB (entsel "\nSelect object: "))
    (princ
      (strcat
        "\nNumber color of object is: "
        (itoa
          (cdr
            (assoc 62
              (tblsearch "LAYER"
                (cdr (assoc 8 (entget (car OB))))
              )
            )
          )
        )
      )
    )
    (princ "\n** Nothing selected **")
  )
  (princ)
)maybe also CTRL+1 or QPMODE 
k.

[vnanhvu]

Thank you very much. Would be perfect if you could display on green, not  under command.
Thanks again !

[kruuger]

Thank you very much. Would be perfect if you could display on green, not  under command.
Thanks again !

what display on green ?
k.

[vnanhvu]

Sorry no  " green " --->>" screen "  Dísplay same my pic upload

[kruuger]

Sorry no  " green " --->>" screen "  Dísplay same my pic upload

Code: [Select]

(defun c:CL (/ OB)
  (if (setq OB (entsel "\nSelect object: "))
    (alert ;;; replace with princ
      (strcat
....?

[CAB]

You can use this routine.
http://www.lee-mac.com/dinfo.html

[vnanhvu]

With Lee's Lisp display color object " bylayer", no display " color bylayer "  I hope you develope kruuger's lisp that can display dialog color ( this only display color number on command line )

[alanjt]

Code: [Select]

(defun c:TEst (/ _color ent data)

  (defun _color (n)
    (if (numberp n)
      (cond ((cdr (assoc n
                         '((0 . "ByBlock")
                           (1 . "Red")
                           (2 . "Yellow")
                           (3 . "Green")
                           (4 . "Cyan")
                           (5 . "Blue")
                           (6 . "Magenta")
                           (7 . "White")
                           (256 . "ByLayer")
                          )
                  )
             )
            )
            ((itoa n))
      )
    )
  )

  (if (setq ent (car (entsel "\nSelect object to display layer's color: ")))
    (alert (strcat "Object Layer: "
                   (cdr (assoc 8 (setq data (entget ent))))
                   "\nLayer color: "
                   (_color (cdr (assoc 62 (tblsearch "LAYER" (cdr (assoc 8 data))))))
                   "\nObject color: "
                   (cond ((_color (cdr (assoc 62 data))))
                         ("ByLayer")
                   )
           )
    )
  )
  (princ)
)

[CAB]

In Lee's routine replace with this sub-function.

Code: [Select]

  ;;  CAB version
  (defun _GetColour ( e / c )   
    (if (setq c (cdr (assoc 62 e)))     
      (cond
        (
          (cdr
            (assoc c
             '(
                (0 . "ByBlock")
                (1 . "Red")
                (2 . "Yellow")
                (3 . "Green")
                (4 . "Cyan")
                (5 . "Blue")
                (6 . "Magenta")
                (7 . "White")
              )
            )
          )
        )
        ( (itoa c) )
      )
      (strcat "ByLayer -> " (itoa (cdr (assoc 62 (tblsearch "LAYER" (cdr (assoc 8 e))))))) ;;  CAB change
    )
  )

[vnanhvu]

Thank Alanjt, Cab and Kruuger very much. Wished everyone happy 

[irneb]

Or even going a bit further:

Code: [Select]

;;  CAB/Irné version
(defun _GetColour (e / _GetColorName c)
  (defun _GetColorName (c) ;Irné change
    (cond
      (
       (cdr
         (assoc c
                '(
                  (0 . "ByBlock")
                  (1 . "Red")
                  (2 . "Yellow")
                  (3 . "Green")
                  (4 . "Cyan")
                  (5 . "Blue")
                  (6 . "Magenta")
                  (7 . "White")
                 )
         )
       )
      )
      ((itoa c))
    )
  )
  (if (setq c (cdr (assoc 62 e)))
    (_GetColorName c)
    (strcat "ByLayer -> " (_GetColorName (cdr (assoc 62 (tblsearch "LAYER" (cdr (assoc 8 e)))))))
    ;;  CAB change
  )
)Now it displays "Bylayer -> Green" instead of "Bylayer -> 4"  :whistle:

[Lee Mac]

Cheers guys, I'll consider these changes for the next version 

[irneb]

Or even a smaller change:

Code: [Select]

;;  CAB/Recursive version
(defun _GetColour (e / c)
  (if (setq c (cdr (assoc 62 e)))
    (cond
      (
       (cdr
         (assoc c
                '(
                  (0 . "ByBlock")
                  (1 . "Red")
                  (2 . "Yellow")
                  (3 . "Green")
                  (4 . "Cyan")
                  (5 . "Blue")
                  (6 . "Magenta")
                  (7 . "White")
                 )
         )
       )
      )
      ((itoa c))
    )
    (strcat "ByLayer -> " (_GetColour (tblsearch "LAYER" (cdr (assoc 8 e))))) ;Irné change to recursive
    ;;  CAB change
  )
)