Topic: If statement with inserting dwgs

[MSTG007]

I have a basic routine that inserts details into a blank drawing. I ran into this issue this morning. I ran the routine and in the middle of it; the routine had an error out.

The problem was that the detail got renamed.

So this is my question. Is there an if statement I could use if a detail (That its trying to insert) is not available that it can skip it and go onto the next one?

Code: [Select]

(command "._insert" "//Server1/Details/BEDDING RCP.dwg" "3.4086,18.0777" "" "" "")
(command "._insert" "//Server1/Details/BEDDING PVC.dwg" "10.4322,17.8681" "" "" "")
(command "._insert" "//Server1/Details/SANITARY CROSSOVER & SEPERATION REQ.dwg" "18.2376,12.2324" "" "" "")
(command "._insert" "//Server1/Details/SANITARY CLEANOUT.dwg" "26.9325,12.6906" "" "" "")
(command "._insert" "//Server1/Details/STORM MANHOLE TYPE C.dwg" "18.9855,17.8591" "" "" "")

[rkmcswain]

Perhaps something like this?

Code - Auto/Visual Lisp: [Select]

1. (setq fn "//Server1/Details/SANITARY CROSSOVER & SEPERATION REQ.dwg")
2. (if (findfile fn)
3.   (command "insert" fn ...... )
4. )
5.  

[kpblc]

Another one:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun test (/ err)
3.   (foreach item '((("name" . "//Server1/Details/BEDDING RCP.dwg") ("pt" 3.4086 18.0777))
4.                   (("name" . "//Server1/Details/BEDDING PVC.dwg") ("pt" 10.4322 17.8681))
5.                   ;; <...>
6.                   )
7.     (if (findfile (cdr (assoc "name" item)))
8.       (vla-insertblock (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
9.                        (vlax-3d-point (cdr (assoc "pt" item)))
10.                        (cdr (assoc "name" item))
11.                        1.
12.                        1.
13.                        1.
14.                        0.
15.                        ) ;_ end of vla-InsertBlock
16.       (setq err (cons (cdr (assoc "name" item)) err))
17.       ) ;_ end of if
18.     ) ;_ end of foreach
19.   (if err
20.     (princ
21.       (strcat "\nThese blocks didn't inserted:"
22.               (apply (function strcat) (mapcar (function (lambda (x) (strcat "\n" x))) (vl-sort err '<)))
23.               ) ;_ end of strcat
24.       ) ;_ end of princ
25.     ) ;_ end of if
26.   (princ)
27.   ) ;_ end of defun

[ur_naz]

insert from anywhere, can be smartly used with mapcar or foreach then inserting from the same directory

Code - Auto/Visual Lisp: [Select]

1. ;; (insert-blk '(0 0) "BEDDING RCP.dwg" "//Server1/Details/")
2. (defun insert-blk (pt blk_name blk_path / blk_fullname)
3.     (setq blk_fullname (strcat blk_path blk_name))
4.     (if (finddile blk_fullname)
5.         (command "._insert" blk_fullname pt "" "" "")
6.         (princ (strcat "\nCant find block - " blk_name))))

[MSTG007]

Thank you guys for all the different ways to do this.