Topic: Can lisp create rgb-color chart

[bchapman]

Anyone ever try to do this:

Create a true color chart using lisp. I know there's 256^3 rgb color possibilities out there.... for 16,194,277 options....

Can lisp create a node, or object, offset it a little distance, and change the color by one number automatically.  It would be roughly 4024 rows high, 4024 columns wide. Could cad even pull this off?

node 1 = 256,256,256
node 2 = 256,256,255
node 3 = 256,256,254

Or perhaps increase the color spacing to make the changes more severe like:

256,256,256
256,256,250
etc

Just a thought...

[RGUS]

Wish it could... but my take a 96 inch monitor!

[bchapman]

lol... think I'm gonna try to figure this one out... think this would be cool

[Lee Mac]

Since there are three variables: (R,G,B) the chart should be three dimensional - i.e. a cube.

Here are programs for the three planes of such a cube:

RG Plane:

Code: [Select]

(defun c:rgsquare ( / c x y )
    (setq c 16776960)
    (repeat (setq x 256)
        (repeat (setq y 256)
            (entmake (list '(0 . "POINT") (list 10 x y) (cons 420 c)))
            (setq y (1- y)
                  c (- c 256)
            )
        )
        (setq x (1- x))
    )
    (princ)
)
GB Plane:

Code: [Select]

(defun c:gbsquare ( / c x y )
    (setq c 65535)
    (repeat (setq x 256)
        (repeat (setq y 256)
            (entmake (list '(0 . "POINT") (list 10 x y) (cons 420 c)))
            (setq y (1- y)
                  c (1- c)
            )
        )
        (setq x (1- x))
    )
    (princ)
)
RB Plane:

Code: [Select]

(defun c:rbsquare ( / c x y )
    (setq c 16711935)
    (repeat (setq x 256)
        (repeat (setq y 256)
            (entmake (list '(0 . "POINT") (list 10 x y) (cons 420 c)))
            (setq y (1- y)
                  c (1- c)
            )
        )
        (setq x (1- x)
              c (- c 65280)
        )
    )
    (princ)
)
And here is a program to generate the cube itself, though I don't have the computing power to generate 16,777,216 points in AutoCAD...

Code: [Select]

(defun c:rgbcube ( / c x y z )
    (setq c 16777215)
    (repeat (setq x 256)
        (repeat (setq y 256)
            (repeat (setq z 256)
                (entmake (list '(0 . "POINT") (list 10 x y z) (cons 420 c)))
                (setq z (1- z)
                      c (1- c)
                )
            )
            (setq y (1- y))
        )
        (setq x (1- x))
    )
    (princ)
)
Alternatively, combining all three planes:

Code: [Select]

(defun c:rgbchart ( / c x y z )
    (setvar 'pdmode 0)
    (setq c 16776960)
    (repeat (setq x 256)
        (setq x (1- x))
        (repeat (setq y 256)
            (setq y (1- y))
            (entmake (list '(0 . "POINT") (list 10 x y 0) (cons 420 c)))
            (setq c (- c 256))
        )
    )
    (setq c 65535)
    (repeat (setq y 256)
        (setq y (1- y))
        (repeat (setq z 256)
            (setq z (1- z))
            (entmake (list '(0 . "POINT") (list 10 0 y z) (cons 420 c)))
            (setq c (1- c))
        )
    )
    (setq c 16711935)
    (repeat (setq x 256)
        (setq x (1- x))
        (repeat (setq z 256)
            (setq z (1- z))
            (entmake (list '(0 . "POINT") (list 10 x 0 z) (cons 420 c)))
            (setq c (1- c))
        )
        (setq c (- c 65280))
    )
    (command "_.-view" "_neiso" "_.zoom" "_e")
    (princ)
)

[gile]

Hi,

And here is a program to generate the cube itself, though I don't have the computing power to generate 16,777,216 points in AutoCAD...

Generating 16,777,216 points in AutoCAD is certainly not a so good idea...

Here's my attempt for the rgb planes (Lee's rgbchart):

Code - Auto/Visual Lisp: [Select]

1. (defun c:rgbPlanes (/ i j)
2.   (setvar 'pdmode 0)
3.   (repeat (setq i 256)
4.     (setq i (1- i))
5.     (repeat (setq j 256)
6.       (setq j (1- j))
7.       (entmakex (list '(0 . "point") (list 10 i j 0) (cons 420 (+ (lsh i 16) (lsh j 8)))))
8.       (entmakex (list '(0 . "point") (list 10 i 0 j) (cons 420 (+ (lsh i 16) j))))
9.       (entmakex (list '(0 . "point") (list 10 0 i j) (cons 420 (+ (lsh i 8) j))))
10.     )
11.   )
12.   (command "_view" "_neiso")
13.   (princ)
14. )

The same with F#
 (EDIT: replaced "doc.SendStringToExecute("_-view _neiso ", false, false, false);" with a more efficient statement.

Code - F#: [Select]

1. [<CommandMethod("rgbplanes")>]
2. let rgbPlanes () =
3.     let doc = Application.DocumentManager.MdiActiveDocument
4.     let db = doc.Database
5.     Application.SetSystemVariable("pdmode", 0)
6.     use tr = db.TransactionManager.StartTransaction()
7.     let ms = db.CurrentSpaceId.GetObject(OpenMode.ForWrite) :?> BlockTableRecord
8.     let addPoint x y z =
9.         let pt = new DBPoint(new Point3d(float x, float y, float z))
10.         pt.Color <- Color.FromRgb(byte x, byte y, byte z)
11.         ms.AppendEntity(pt) |> ignore
12.         tr.AddNewlyCreatedDBObject(pt, true)
13.     for i in 0 .. 255 do
14.         for j in 0 .. 255 do
15.             addPoint i j 0
16.             addPoint i 0 j
17.             addPoint 0 i j
18.     use view = new ViewTableRecord()
19.     view.CenterPoint <- Point2d.Origin;
20.     view.Height <- 600.
21.     view.ViewDirection <- new Vector3d(1., 1., 1.);
22.     ed.SetCurrentView(view)
23.     tr.Commit()

[Lee Mac]

Here's my attempt for the rgb planes (Lee's rgbchart):

Nice gile - I thought there might be a way to make it more succinct 

[David Bethel]

Did AutoDESK ever update grdraw or grvecs to accept RGB colors?  -David

[Lee Mac]

Did AutoDESK ever update grdraw or grvecs to accept RGB colors?  -David

Not that I am aware of...

[gile]

A DesignScript implementation.
The code is quite concise but it runs very slow...

Code: [Select]

import("ProtoGeometry.dll");

class PointColor
{
    Point : Point;
    constructor ByCoordinates(x : int, y : int, z : int)
    {
        Point = Point.ByCoordinates(x, y, z);
        Point.Color = Color.ByARGB(0, x, y, z);
    }
}

pointsRG = PointColor.ByCoordinates((0..255)<1>, (0..255)<2>, 0);
pointsRB = PointColor.ByCoordinates((0..255)<1>, 0, (0..255)<2>);
pointsGB = PointColor.ByCoordinates(0, (0..255)<1>, (0..255)<2>);

[bchapman]

You experts (aka geniuses) make this stuff seem too easy lol.  My CPU almost processed the 3d Cube per your code LEE but I couldn't resist clicking...crashed it where you see below. Going to try again when I don't want to click on anything lol.

Since there are three variables: (R,G,B) the chart should be three dimensional - i.e. a cube.

Here are programs for the three planes of such a cube:

RG Plane:

Code: [Select]

(defun c:rgsquare ( / c x y )
    (setq c 16776960)
    (repeat (setq x 256)
        (repeat (setq y 256)
            (entmake (list '(0 . "POINT") (list 10 x y) (cons 420 c)))
            (setq y (1- y)
                  c (- c 256)
            )
        )
        (setq x (1- x))
    )
    (princ)
)
GB Plane:

Code: [Select]

(defun c:gbsquare ( / c x y )
    (setq c 65535)
    (repeat (setq x 256)
        (repeat (setq y 256)
            (entmake (list '(0 . "POINT") (list 10 x y) (cons 420 c)))
            (setq y (1- y)
                  c (1- c)
            )
        )
        (setq x (1- x))
    )
    (princ)
)
RB Plane:

Code: [Select]

(defun c:rbsquare ( / c x y )
    (setq c 16711935)
    (repeat (setq x 256)
        (repeat (setq y 256)
            (entmake (list '(0 . "POINT") (list 10 x y) (cons 420 c)))
            (setq y (1- y)
                  c (1- c)
            )
        )
        (setq x (1- x)
              c (- c 65280)
        )
    )
    (princ)
)
And here is a program to generate the cube itself, though I don't have the computing power to generate 16,777,216 points in AutoCAD...

Code: [Select]

(defun c:rgbcube ( / c x y z )
    (setq c 16777215)
    (repeat (setq x 256)
        (repeat (setq y 256)
            (repeat (setq z 256)
                (entmake (list '(0 . "POINT") (list 10 x y z) (cons 420 c)))
                (setq z (1- z)
                      c (1- c)
                )
            )
            (setq y (1- y))
        )
        (setq x (1- x))
    )
    (princ)
)
Alternatively, combining all three planes:

Code: [Select]

(defun c:rgbchart ( / c x y z )
    (setvar 'pdmode 0)
    (setq c 16776960)
    (repeat (setq x 256)
        (setq x (1- x))
        (repeat (setq y 256)
            (setq y (1- y))
            (entmake (list '(0 . "POINT") (list 10 x y 0) (cons 420 c)))
            (setq c (- c 256))
        )
    )
    (setq c 65535)
    (repeat (setq y 256)
        (setq y (1- y))
        (repeat (setq z 256)
            (setq z (1- z))
            (entmake (list '(0 . "POINT") (list 10 0 y z) (cons 420 c)))
            (setq c (1- c))
        )
    )
    (setq c 16711935)
    (repeat (setq x 256)
        (setq x (1- x))
        (repeat (setq z 256)
            (setq z (1- z))
            (entmake (list '(0 . "POINT") (list 10 x 0 z) (cons 420 c)))
            (setq c (1- c))
        )
        (setq c (- c 65280))
    )
    (command "_.-view" "_neiso" "_.zoom" "_e")
    (princ)
)

[bchapman]

Hey Gile, how do I run the script below?

Thanks!

A DesignScript implementation.
The code is quite concise but it runs very slow...

Code: [Select]

import("ProtoGeometry.dll");

class PointColor
{
    Point : Point;
    constructor ByCoordinates(x : int, y : int, z : int)
    {
        Point = Point.ByCoordinates(x, y, z);
        Point.Color = Color.ByARGB(0, x, y, z);
    }
}

pointsRG = PointColor.ByCoordinates((0..255)<1>, (0..255)<2>, 0);
pointsRB = PointColor.ByCoordinates((0..255)<1>, 0, (0..255)<2>);
pointsGB = PointColor.ByCoordinates(0, (0..255)<1>, (0..255)<2>);

[gile]

Hey Gile, how do I run the script below?

You have to download and install DesignScript (AutoCAD 2013 64 bits on Windows 7 only).