Topic: Select Entity at End Problem

[Rabbit]

I need to use Lisp to select an entity (arc, line, leader, lwpolyline or spline) and then select the endpoint of that entity near the selection point.  I've use ENTSEL to get the entity information and the click point, but I can't figure out a way to get the enpoint nearest to that click to insert a donut entity, which obtains the layer properties of the selected entity.

What pointers do you guys have?

Sincerely,
Rabbit

[Kerry]

for the line

distance from pick point to dxf 10
distance from pick point to dxf 11

if to dxf10 is the shorter distance, dxf10 is nearest.


the other entitys will use a similar methodology.

Regards,

[Rabbit]

Codes 10 and 11 don't work for arcs.  I'm going to have to search for a bit of code for getting the endpoints of arcs.

[David Bethel]

For the most part, each entity type will require it's own calculation.  3DFACEs SOLIDs and TRACEs could share a function.  Some entity types would be impossible to calculate ( Circle ).  Some would be very difficult.  -David

[jaydee]

I use this

(setq npt (car (cdr (entsel))))
(setq endpt (osnap npt "end"))
(command "_.insert" donutblk endpt "" "" "")

[Lee Mac]

I would be inclined to use vlax-curve-getstartpoint / vlax-curve-getendpoint since these will work for all curve entities.

Then compare the distances between each point and your selection point to determine which to use.

[ronjonp]

I would be incline to use vlax-curve-getstartpoint / vlax-curve-getendpoint since these will work for all curve entities.

Then compare the distances between each point and your selection point to determine which to use.

X2

Here's a quick example:

Code: [Select]

(defun c:epsp (/ e p)
  (and (setq e (entsel))
       (setq p (cadr e))
       (setq e (car e))
       (not (vl-catch-all-error-p (vl-catch-all-apply 'vlax-curve-getendpoint (list e))))
       (setq p (caar (vl-sort (mapcar '(lambda (x) (list x (distance p x)))
      (list (vlax-curve-getendpoint e) (vlax-curve-getstartpoint e))
      )
      '(lambda (a b) (< (cadr a) (cadr b)))
     )
       )
       )
       (entmakex (list (cons 0 "CIRCLE") (cons 10 p) (cons 40 0.5)))
  )
  (princ)
)

[Rabbit]

Sometimes the simplest answers are the best

(setq *DOT*Wire (entsel "\nSelect wire near end for insertion point of dot: "))
  (setq *DOT*WireEntity (car *DOT*Wire))
  (setq *DOT*WireEndPoint (osnap (car (cdr *DOT*Wire)) "end"))
  (setq *DOT*WireLayer (cdr (assoc 8 (entget *DOT*WireEntity))))
  (command "-layer" "s" *DOT*WireLayer "")
  (command "donut" 0.0 (/ Dimscl 27) *DOT*WireEndPoint "")

Works perfectly.
Thanks jaydee

[Lee Mac]

Another...

Code: [Select]

(defun c:test ( / ent pnt rad sel )
    (while
        (progn (setvar 'ERRNO 0) (setq sel (entsel))
            (cond
                (   (= 7 (getvar 'ERRNO))
                    (princ "\nMissed, try again.")
                )
                (   (null sel)
                    nil
                )
                (   (listp sel)
                    (if (vl-catch-all-error-p
                            (vl-catch-all-apply 'vlax-curve-getendpoint (list (car sel)))
                        )
                        (princ "\nInvalid Object.")
                        (progn
                            (setq ent (car  sel)
                                  pnt (cadr sel)
                                  rad 0.5
                            )
                            (setq pnt
                                (if (<  (distance pnt (vlax-curve-getstartpoint ent))
                                        (distance pnt (vlax-curve-getendpoint   ent))
                                    )
                                    (vlax-curve-getstartpoint ent)
                                    (vlax-curve-getendpoint   ent)
                                )
                            )
                            (entmakex
                                (list
                                   '(0 . "LWPOLYLINE")
                                   '(100 . "AcDbEntity")
                                   '(100 . "AcDbPolyline")
                                   '(90 . 2)
                                   '(70 . 1)
                                    (cons 43 rad)
                                    (cons 10 (polar pnt pi (/ rad 2.0)))
                                   '(42 . 1)
                                    (cons 10 (polar pnt 0. (/ rad 2.0)))
                                   '(42 . 1)
                                )
                            )
                        )
                    )
                )
            )
        )
    )
    (princ)
)

[jaydee]

Sometimes the simplest answers are the best

Works perfectly.
Thanks jaydee

Hi rabit.
Not sure it the best, if it works for you that what matters.
One thing i found the OSNAP method is not very reliable in some instance where there is a lot of entities closed to the one you pick, then its possible the osnap snap end point to the wrong entity.

Since then i have take up advice from this forum and used/replace osnap options with
vlax-curve-getstartpoint
vlax-curve-getendpoint
It might be difficult to follow initially, but its worth it.

[alanjt]

Or something like this to account for oddly shaped curves where the opposite endpoint is closer to the selection...

Code: [Select]

(defun _ClosestEndPoint (ent pnt / dst)
  (setq dst (vlax-curve-getDistAtPoint
              ent
              (vlax-curve-getClosestPointToProjection ent (trans pnt 1 ent) '(0. 0. 1.))
            )
  )
  (caar
    (vl-sort (list (list (vlax-curve-getStartPoint ent) 0.)
                   (list (vlax-curve-getEndPoint ent)
                         (vlax-curve-getDistAtParam ent (vlax-curve-getEndParam ent))
                   )
             )
             '(lambda (a b) (< (abs (- dst (cadr a))) (abs (- dst (cadr b)))))
    )
  )
)

[roy_043]

@ alanjt:
This 'projection' stuff is not exactly my strong point.
But shouldn't this line:
  (vlax-curve-getClosestPointToProjection ent (trans pnt 1 ent) '(0. 0. 1.))
Be changed to:
  (vlax-curve-getClosestPointToProjection ent (trans pnt 1 0) '(0. 0. 1.))
?
And shouldn't the viewdir somehow play a part in this?

BTW: Good to know that the 'curve' functions will also swallow enames!