Topic: Part of code to make XREF path full instead of relative

[HasanCAD]

There is 2 point about this part of code
- When finish the path comes as small letters I want It capital, I used strcase but not working I think that the issue in vla-put-path
- Any comments will be appreciated

Code - Auto/Visual Lisp: [Select]

1. (defun selx (/ blk name xrefs)                              ;LEE-mac.com
2.    (while (setq blk (tblnext "BLOCK" (not blk)))
3.       (if (> (logand 4 (cdr (assoc 70 blk))) 0)
4.          (progn
5.             (setq name  (cdr (assoc 2 blk))
6.                   xrefs (if xrefs
7.                            (strcat xrefs "," name)
8.                            name
9.                         )
10.             )
11.          )
12.       )
13.    )
14.    (ssget "X" (list '(0 . "INSERT") (cons 2 xrefs)))
15. )
16. (setq cntX 0)
17.  
18. (if (sslength (setq ssBlk (selx)))
19.    (progn
20.       (while
21.          (setq blk (ssname ssBlk cntX))
22.            (setq blk (vlax-ename->vla-object blk))
23.            (setq blkPth (vla-get-path blk))
24.            (setq blknm (vla-get-name blk))
25.            (if (= (vl-string-elt blkPth 0) 46)
26.               (command "_.-xref" "_pathType" blknm "full")
27.            )
28.            (setq blkPth (strcase (vla-get-path blk)))
29.            (vla-put-path blk blkPth)
30.            (vla-update blk)
31.            (setq cntX (1+ cntX))
32.       )
33.    )
34. )
35.  

edit kdub-> formatting to code=cadlisp-7
fix title spelling

[Kerry]

Can you try again to explain your problem.

ie
I expect this : < example>
I get this : < example >

From a quick perusal, the code should work without fault.

[Kerry]

Just for my Curiosity ..
Why Do you want the Saved Path to be in uppercase instead of the case returned by (findfile ... )

Regards

[HasanCAD]

...
edit kdub-> formatting to code=cadlisp-7
fix title spelling

- Thanks kdub I believe that it is better than before
- see my sign 

Can you try again to explain your problem.

ie
I expect this : < example>
I get this : < example >

From a quick perusal, the code should work without fault.

- The code working without fault, and I asking for comments
- I tried again and working well.   

And faced another issue, I want to replace a part of path with another part

Full path

Code: [Select]

\\10.120.200.11\projects\GEN\3120B01\BASE\Col-Grids&SE\3120B01-XCOFO.dwgI want to replace

Code: [Select]

\\10.120.200.11\projects\with

Code: [Select]

X:\

[HasanCAD]

Just for my Curiosity ..
Why Do you want the Saved Path to be in uppercase instead of the case returned by (findfile ... )

Regards

Some of our projects are prototype, Means the same building repeated in more than one site. And capital and small letters confusing me while change the path using Reference manager. So I want all letters case are capital.
For example

This is BASE path

Code - Text: [Select]

1. X:\GEN\3120\PROTOTYPE\BASE\3120B01-XCOFO.dwg

This is BASE path

Code - Text: [Select]

1. X:\GEN\3120\PROTOTYPE\1111\3120B01-C-S101.dwg
2. X:\GEN\3120\PROTOTYPE\2222\3120B01-C-S101.dwg
3. X:\GEN\3120\PROTOTYPE\3333\3120B01-C-S101.dwg

[ronjonp]

Give this a try:

Code - Auto/Visual Lisp: [Select]

1. (defun _changexrefpath (/ i newpath p xrpath)
2.   (vl-load-com)
3.   (setq p "\\\\10.120.200.11\\PROJECTS\\")
4.   (setq i (strlen p))
5.   (vlax-for x (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
6.     (if (and (minusp (vlax-get x 'isxref))
7.              (setq xrpath (strcase (vlax-get x 'path)))
8.              (vl-string-search p xrpath)
9.              (setq newpath (strcat "X:\\" (substr xrpath i)))
10.              (findfile newpath)
11.         )
12.       (vl-catch-all-error-p (vl-catch-all-apply 'vla-put-path (list x newpath)))
13.     )
14.   )
15.   (princ)
16. )

*Found Typo

[HasanCAD]

Give this a try:

Code - Auto/Visual Lisp: [Select]

1. (defun _changexrefpath (/ i newpath p xrpath)
2.   (vl-load-com)
3.   (setq p "\\\\10.120.200.11\\PROJECTS\\")
4.   (setq i (strlen p))
5.   (vlax-for x (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
6.     (if (and (minusp (vlax-get x 'isxref))
7.              (setq xrpath (strcase (vlax-get x 'path)))
8.              (vl-string-search p xrpath)
9.              (setq newpath (strcat "X:\\" (substr xrpath i)))
10.              (findfile newpath)
11.         )
12.       (vl-catch-all-error-p (vl-catch-all-apply 'vla-put-path (list x newpath)))
13.     )
14.   )
15.   (princ)
16. )

*Found Typo

Gives error

Code: [Select]

_CHANGEXREFPATH
_$
; error: bad argument type: (or stringp symbolp): nil
_$ By the way I changed G:\\ to X:\\

[Kerry]

Untested :

Code - Auto/Visual Lisp: [Select]

1.  
2. (defun _changexrefpath (/ newpath path1 xrpath old new)
3.    (setq new "G:\\")
4.    (setq old "//10.120.200.11\\PROJECTS\\")
5.    (vlax-for x
6.              (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))
7.              )
8.       (if (minusp (vlax-get x 'isxref))
9.          (if (and (setq xrpath (strcase (vlax-get x 'path)))
10.                   (vl-string-search old xrpath)
11.                   (setq newpath (vl-string-subst
12.                                    new
13.                                    old
14.                                    xrpath
15.                                 )
16.                   )
17.                   (findfile newpath)
18.              )
19.             (vl-catch-all-error-p
20.                (vl-catch-all-apply 'vla-put-path (list x newpath))
21.             )
22.          )
23.       )
24.    )
25.    (princ)
26. )
27.  
28. ;; (_changexrefpath)
29.  
30.  

added:
just an option now that ronjonp's typo is fixed