Topic: put drawings to one dwg file

[smileforrest]

hi guys,
 Can anyone put drawings to one dwg file without open the drawings, on the contrary, LeeMac has writed a program which can put layers into drawings .http://lee-mac.com/layerstodrawings.html
thanks

[Coder]

Hi
You can use INSERT command.

[Kerry]

Hi
You can use INSERT command.

You're assuming the OP wants the drawings added into the currently open drawing ... that is not obvious from the question.

[Coder]

Hi
You can use INSERT command.

You're assuming the OP wants the drawings added into the currently open drawing ... that is not obvious from the question.

Yes that is what I thought 

[smileforrest]

Thanks to Coder and Kerry for your attention, my inspiration is come from coworking, maybe one person can work on one or two layers independently, finally, put everyone's achievement（dwg files containing desired layers ） together! When I read LeeMac's progarme, here come the idea!

[HasanCAD]

Give this a try

Code - Auto/Visual Lisp: [Select]

1. (defun c:InsertAll1 ( / dir doc extn spc )
2.  
3.     (setq extn "dwg") ;; Extension of files to Insert e.g "dwg"
4.  
5.     (if (setq dir (LM:DirectoryDialog (strcat "Select Directory of " (strcase extn) " Files to Insert") nil 512))
6.         (progn
7.             (setq doc (vla-get-activedocument (vlax-get-acad-object))
8.                   spc (vlax-get-property doc (if (= 1 (getvar 'cvport)) 'paperspace 'modelspace))
9.             )
10.             (foreach file (vl-directory-files dir (strcat "*." extn) 1)
11.                 (vla-insertblock spc (vlax-3D-point '(0.0 0.0 0.0)) (strcat dir "\\" file) 1.0 1.0 1.0 0.0)
12.             )
13.             (vla-regen doc acallviewports)
14.         )
15.         (princ "\n*Cancel*")
16.     )
17.     (princ)
18. )
19.  
20. ;;-------------------=={ Directory Dialog }==-----------------;;
21. ;;                                                            ;;
22. ;;  Displays a dialog prompting the user to select a folder   ;;
23. ;;------------------------------------------------------------;;
24. ;;  Author: Lee Mac, Copyright © 2011 - www.lee-mac.com       ;;
25. ;;------------------------------------------------------------;;
26. ;;  Arguments:                                                ;;
27. ;;  msg  - message to display at top of dialog                ;;
28. ;;  dir  - root directory (or nil)                            ;;
29. ;;  flag - bit coded flag specifying dialog display settings  ;;
30. ;;------------------------------------------------------------;;
31. ;;  Returns:  Selected folder filepath, else nil              ;;
32. ;;------------------------------------------------------------;;
33.  
34. (defun LM:DirectoryDialog ( msg dir flag / Shell Fold Self Path )
35.     (vl-catch-all-apply
36.         (function
37.             (lambda ( / ac HWND )
38.                 (if
39.                     (setq Shell (vla-getInterfaceObject (setq ac (vlax-get-acad-object)) "Shell.Application")
40.                           HWND  (vl-catch-all-apply 'vla-get-HWND (list ac))
41.                           Fold  (vlax-invoke-method Shell 'BrowseForFolder (if (vl-catch-all-error-p HWND) 0 HWND) msg flag dir)
42.                     )
43.                     (setq Self (vlax-get-property Fold 'Self)
44.                           Path (vlax-get-property Self 'Path)
45.                           Path (vl-string-right-trim "\\" (vl-string-translate "/" "\\" Path))
46.                     )
47.                 )
48.             )
49.         )
50.     )
51.     (if Self  (vlax-release-object  Self))
52.     (if Fold  (vlax-release-object  Fold))
53.     (if Shell (vlax-release-object Shell))
54.     Path
55. )
56.  
57. (vl-load-com) (princ)
58.  
59.  
60.  

Anotherone

Code - Auto/Visual Lisp: [Select]

1. (defun c:InsertAll2 (/ _bbUL _bbUR space temp dir lst)
2.   ;; Insert all file(s) of specified type and within directory of selected file
3.   ;; Alan J. Thompson
4.  
5.   (defun _bbUL (o / a b)
6.     (vla-getboundingbox o 'a 'b)
7.     (list (car (vlax-safearray->list a)) (cadr (vlax-safearray->list b)) 0.)
8.   )
9.  
10.   (defun _bbUR (o / a b) (vla-getboundingbox o 'a 'b) (vlax-safearray->list b))
11.  
12.   (setq space (vlax-get (cond (*AcadDoc*)
13.                               ((setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
14.                         )
15.                         (if (eq (getvar 'CVPORT) 1)
16.                           'paperspace
17.                           'modelspace
18.                         )
19.               )
20.   )
21.  
22.   (if (setq temp (getfiled "Select file type to import" (getvar 'DWGPREFIX) "" 2))
23.     (foreach file (vl-directory-files
24.                     (setq dir (vl-filename-directory temp))
25.                     (strcat "*" (vl-filename-extension temp))
26.                     1
27.                   )
28.       (if (cadr (setq lst
29.                        (cons (vlax-invoke
30.                                space
31.                                'insertblock
32.                                '(0. 0. 0.)
33.                                (strcat dir "\\" file)
34.                                1.
35.                                1.
36.                                1.
37.                                0.
38.                              )
39.                              lst
40.                        )
41.                 )
42.           )
43.         (vlax-invoke (car lst) 'move (_bbUL (car lst)) (mapcar '+ (_bbUR (cadr lst)) '(1. 0. 0.)))
44.       )
45.     )
46.   )
47.   (princ)
48. )

And This one

Code - Auto/Visual Lisp: [Select]

1. (defun c:insertblks (/ d doc lst pt pt1 dir)
2.   (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))
3.   (if
4.     (and (setq
5.        dir (vl-filename-directory
6.          (getfiled "Select a DWG" (getvar 'dwgprefix) "dwg" 8)
7.            )
8.      )
9.      (setq lst (vl-directory-files dir "*.dwg"))
10.      (setq pt1 (getpoint "\nSelect point for first block: "))
11.      (setq d
12.         (distance (getpoint pt1 "\nSelect distance to space blocks: ")
13.               pt1
14.         )
15.      )
16.     )
17.      (foreach b    lst
18.        (vla-insertblock
19.      (if (= (getvar 'cvport) 1)
20.        (vla-get-paperspace doc)
21.        (vla-get-modelspace doc)
22.      )
23.      (vlax-3d-point (setq pt1 (polar pt1 0.0 d)))
24.      (strcat dir "\\" b)
25.      1
26.      1
27.      1
28.      0.0
29.        )
30.      )
31.   )
32.   (princ)
33. )

[smileforrest]

Thank you HasanCAD,

The first routine runs well，and dwgs inserted become blocks;
The soncend routine cann't run, and when choose dwgs we need choose one by one ,cann't choose multifiles one time.

thanks again.