Topic: Check drawing for dynamic Block?

[Jürg Menzi]

Hi All

Is there a way to check a drawing, without open the file in AutoCAD, for 'is it dynamic block'?
Comparable with the reading of the drawing file version.
I Know, the other way is temporary add the Block file with ObjectDBX and read the flag but...

Cheers

[irneb]

You don't need to insert the DWG to find out if it's a DB, but you do need ObjectDBX. Find the model-space block of the DWg and see if its DB setting is on E.g.

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun IsDWG-DB-p (filename / acver dbx blk db)
3.   (if (and (setq dbx (vla-getinterfaceobject (vlax-get-acad-object)
4.                                              (if (< (setq acver (atoi (getvar "ACADVER"))) 16)
5.                                                "ObjectDBX.AxDbDocument"
6.                                                (strcat "ObjectDBX.AxDbDocument." (itoa acver)))))
7.            (setq filename (findfile filename))
8.            (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-Open (list dbx filename))))
9.            (not (vl-catch-all-error-p (setq blk (vl-catch-all-apply 'vla-Item (list (vla-get-Blocks dbx) "*Model_Space"))))))
10.     (setq db (= (vla-get-IsDynamicBlock blk) :vlax-true)))
11.   (foreach obj '(dbx blk) (vl-catch-all-apply 'vlax-release-object (list (eval obj))))
12.   db)

Unfortunately I don't know of a way to read the raw DWG and find this info. It depends on where in the file the MS block's definition is saved.

[Lee Mac]

Here is another version:

Code - Auto/Visual Lisp: [Select]

1. (defun _dynamicblockfile-p ( dwg / doc lst rtn )
2.     (setq rtn
3.         (and (setq dwg (findfile dwg))
4.             (or
5.                 (setq doc
6.                     (cdr
7.                         (assoc (strcase dwg)
8.                             (vlax-for doc (vla-get-documents (vlax-get-acad-object))
9.                                 (setq lst (cons (cons (strcase (vla-get-fullname doc)) doc) lst))
10.                             )
11.                         )
12.                     )
13.                 )
14.                 (and
15.                     (setq doc
16.                         (vla-getinterfaceobject (vlax-get-acad-object)
17.                             (if (< (atoi (getvar 'acadver)) 16)
18.                                 "ObjectDBX.AxDbDocument"
19.                                 (strcat "ObjectDBX.AxDbDocument." (itoa (atoi (getvar 'acadver))))
20.                             )
21.                         )
22.                     )
23.                     (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-open (list doc dwg))))
24.                 )
25.             )
26.             (= :vlax-true (vla-get-isdynamicblock (vla-get-modelspace doc)))
27.         )
28.     )
29.     (if (= 'vla-object (type doc))
30.         (vlax-release-object doc)
31.     )
32.     rtn
33. )

[pBe]

.

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun IsDWG-DB-p (filename / acver dbx blk db)
3. ....)

Here is another version:

Code - Auto/Visual Lisp: [Select]

1. (defun _dynamicblockfile-p ( dwg / doc lst rtn )
2.    ........

Nice LM /Irné   


I still have much to learn from you guys 

[Lee Mac]

Nice LM   

Thanks pBe! 

[Jürg Menzi]

Thank you both!

Cheers

[irneb]

You're welcome. And thanks for the compliment.
 
Though I wish there was some raw thing to read like the file version inside the DWG file. That would mean this could work on Mac as well. As it is the ObjectDBX & ActiveX functions preclude any usuage on an "Apple-CAD"  .

[Jürg Menzi]

Here is another version:

Code - Auto/Visual Lisp: [Select]

1. ...
2.                 (setq doc
3.                     (cdr
4.                         (assoc (strcase dwg)
5.                             (vlax-for doc (vla-get-documents (vlax-get-acad-object))
6.                                 (setq lst (cons (cons (strcase (vla-get-fullname doc)) doc) lst))
7.                             )
8.                         )
9.                     )
10.                 )
11. ...
12.  

Lee Mac, a last question:
The sense of the quoted part above is to check the current drawing for open documents they possibly are Dyn Blocks - correct?

Cheers and Thanks again

[Lee Mac]

Here is another version:

Code - Auto/Visual Lisp: [Select]

1. ...
2.                 (setq doc
3.                     (cdr
4.                         (assoc (strcase dwg)
5.                             (vlax-for doc (vla-get-documents (vlax-get-acad-object))
6.                                 (setq lst (cons (cons (strcase (vla-get-fullname doc)) doc) lst))
7.                             )
8.                         )
9.                     )
10.                 )
11. ...
12.  

Lee Mac, a last question:
The sense of the quoted part above is to check the current drawing for open documents they possibly are Dyn Blocks - correct?

Almost -
Assuming MDI mode, if the supplied drawing filename is already open in AutoCAD (and hence resides in the Documents Collection), the use of the Open method on the ObjectDBX Document will fail as the drawing will be read-only. My code is checking the Documents Collection for the drawing file and, if present, will use the Document Object of the open file before creating the ObjectDBX Document.

[irneb]

Perhaps then this code should suffice:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun IsDWG-DB-p (filename / acver dbx blk db)
3.   (if (and (setq dbx (vla-getinterfaceobject (vlax-get-acad-object)
4.                                              (if (< (setq acver (atoi (getvar "ACADVER"))) 16)
5.                                                "ObjectDBX.AxDbDocument"
6.                                                (strcat "ObjectDBX.AxDbDocument." (itoa acver)))))
7.            (setq filename (findfile filename))
8.            (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-Open (list dbx filename :vlax-true))))
9.            (not (vl-catch-all-error-p (setq blk (vl-catch-all-apply 'vla-Item (list (vla-get-Blocks dbx) "*Model_Space"))))))
10.     (setq db (= (vla-get-IsDynamicBlock blk) :vlax-true)))
11.   (foreach obj '(dbx blk) (vl-catch-all-apply 'vlax-release-object (list (eval obj))))
12.   db)

I.e. always open it in read-only mode. Especially since the defun is not supposed to modify anything inside the DWG file.
 
Sorry, haven't tested - but would a normal ObjectDBX open still work if another session / user has the file open?

[Jürg Menzi]

@Lee Mac:
Aah, that's it. Thank you.

@irneb:
The open method fails in this case.

Cheers

[irneb]

This is very strange ... one would expect opening the file as readonly through DBX would allow it to open even if someone else has it open already.
 
So what can one do in this case? Even Lee's code will fail if the DWG is opened in another session / by another user.

[Jürg Menzi]

So what can one do in this case?

Because I use ObjectDBX mostly for unattended jobs, the program writes a log file. If the open method fails, an entry will be written with file name and error message.

Even Lee's code will fail if the DWG is opened in another session / by another user.

Yes, thats correct.

Cheers

[irneb]

Sorry, yes I understand about logging errors and so. I'm just posting to see if someone else has an answer which would still open the file in read-only mode, since in my case there's lots of change that another user would have at least one of the DWGs open. Apparently ODBX just does not handle this.

[T.Willey]

I don't think there is anything in Lisp alone that can open a drawing in read-only mode, without opening it in the Acad window session.  This is one reason why I went to .Net.  If someone wanted to they could write some .Net code for lisp to open a drawings database only in read-only mode.