Author Topic: ==={Challenge}===Find the ridge lines of sloped roof (Read 108251 times)

ribarm · « **Reply #270 on:** January 14, 2024, 06:49:37 PM »

@pkohut

Thanks for interes into this topic... I think I've slightly improved speed of "roof2d-new-new-new.lsp"... The newest version is called "roof2d-new-new-new-n.lsp" and it's posted in ZIP I uploaded at cadtutor download section... Nothing spectacular - removing testing subs for checking for correct finish, added 2 subs - (offd) with (chkcircinside-dist) and adding shorter chk for correct finish in single line :
(vl-every (function (lambda ( x ) (vl-some (function (lambda ( y ) (equal x y 1e-6))) (unique (mapcar (function cadr) lil))))) pl)

That's all from me for now...
Like BIGAL - every millisecond counts...

M.R.

kdub_nz · « **Reply #271 on:** January 14, 2024, 07:34:08 PM »

@ribarm

Quote

posted in ZIP I uploaded at cadtutor download section

I'm old and cranky, so . .

why do you assume that everyone is a member there, and would travel to pick it up ??

I'm noticing this attitude more and more.

This is a peer to peer forum where responsibility to roles is expected to be honoured, and an example set for newer members.

Regards,

pkohut · « **Reply #272 on:** January 14, 2024, 10:17:01 PM »

Quote from: ribarm on January 14, 2024, 06:49:37 PM

That's all from me for now...
Like BIGAL - every millisecond counts...
M.R.

Sadly, I think, 12 years chasing those milliseconds has given you tunnel vision against better solutions.

ribarm · « **Reply #273 on:** January 15, 2024, 02:27:14 AM »

Quote from: kdub_nz on January 14, 2024, 07:34:08 PM

@ribarm

Quote
posted in ZIP I uploaded at cadtutor download section

I'm old and cranky, so . .

why do you assume that everyone is a member there, and would travel to pick it up ??

I'm noticing this attitude more and more.

This is a peer to peer forum where responsibility to roles is expected to be honoured, and an example set for newer members.

Regards,

I don't understand...
Shell I post *.ZIP here?

OK. You can find it here : https://www.theswamp.org/index.php?topic=41837.msg619616#msg619616 in attachment...

ribarm · « **Reply #274 on:** January 22, 2024, 11:01:01 AM »

I've succedded only few lines more on tst.dwg which is packed in *.ZIP... The problem is (processlil) sub function of "roof-2chk-nnnnnnn.lsp" that has (cond) which is doing things from start until hit first that satisfies condition... But in my case we don't know is firstly one be correct choice or some else that also satisfies condition but not placed above the one it hits firstly... What is also different is that I used now "lstt" variable for storing solutions and "lst" is points of LWPOLYLIINE data with angles and adjacent plane prints... So since I made possible on that specific case to acomplish little better results, I am satisfied... As no one is not interested to improve and fix what's done, I may say that I am finished here...
It was my pleasure to lead conversation on this challenge - we all learned something from it...
Thanks for reading and stay well and happy...
M.R.

ribarm · « **Reply #275 on:** January 24, 2024, 03:53:40 PM »

I abandoned (cond) in (processlil) sub and made it more concise and acceptable to what I tried to achieve... But something still isn't good - in my tst.dwg it draws only few lines and doesn't complete solution... I am afraid that I can't swim out of mug that is draining me... For now I am abandning coding, but am posting in code tags, so that concise version can be seen and maybe someone can chime in and reply with constructive idea(s)...

Code - Auto/Visual Lisp: [Select]

(defun c:roof-2chk-nnnnnnnnnn-s ( / *error* vl-load rlw unioncollinearplaneprints unique inside-p distp2t _vl-sort numbpos offd chkcircinside-dist chkcircinside collinear-pp searchipss processlil process ti s dm lw lwi pl ppl pli tl utl lst llst lstt ll zz x y ip ips ipss pos ang angp flag d t1 t2 tt1 tt2 tt k n att pll lil lilx lil1 lil2 )
 
  (defun *error* ( m )
    ;(command-s "_.-OVERKILL" "_ALL" "" "_T" "_Y" "")
    (if (and lwi (not (vlax-erased-p lwi)))
      (if (= (type lwi) (quote ename))
        (entdel lwi)
        (vla-delete lwi)
      )
    )
    (while (= 8 (logand 8 (getvar (quote undoctl))))
      (if (not (vl-cmdf "_.UNDO" "_E"))
        (if doc
          (vla-endundomark doc)
        )
      )
    )
    (prompt "\nElapsed time : ") (prompt (rtos (- (car (_vl-times)) ti) 2 20)) (prompt " milliseconds...")
    (prompt "\nFor UNDO - type \"UNDO\" - \"Back\" option...")
    (if m
      (prompt m)
    )
    (princ)
  )
 
  (defun vl-load nil
    (or cad
      (if vlax-get-acad-object
        (setq cad (vlax-get-acad-object))
        (progn
          (vl-load-com)
          (setq cad (vlax-get-acad-object))
        )
      )
    )
    (or doc (setq doc (vla-get-activedocument cad)))
    (or alo (setq alo (vla-get-activelayout doc)))
    (or spc (setq spc (vla-get-block alo)))
  )
 
  (defun rlw ( lw / e x1 x2 x3 x4 x5 x6 )
    ;; by ElpanovEvgeniy
    (if (= (cdr (assoc 0 (setq e (entget lw)))) "LWPOLYLINE")
      (progn
        (foreach a1 e
          (cond
            ( (= (car a1) 10) (setq x2 (cons a1 x2)) )
            ( (= (car a1) 40) (setq x4 (cons (cons 41 (cdr a1)) x4)) )
            ( (= (car a1) 41) (setq x3 (cons (cons 40 (cdr a1)) x3)) )
            ( (= (car a1) 42) (setq x5 (cons (cons 42 (- (cdr a1))) x5)) )
            ( (= (car a1) 210) (setq x6 (cons a1 x6)) )
            ( t (setq x1 (cons a1 x1)) )
          )
        )
        (entmod
          (append (reverse x1)
            (append
              (apply (function append)
                (apply (function mapcar)
                  (cons (function list)
                    (list x2
                      (cdr (reverse (cons (car x3) (reverse x3))))
                      (cdr (reverse (cons (car x4) (reverse x4))))
                      (cdr (reverse (cons (car x5) (reverse x5))))
                    )
                  )
                )
              )
              x6
            )
          )
        )
        (entupd lw)
      )
    )
  )
 
  (defun unioncollinearplaneprints ( tl / a b tll )
    (while (setq a (car tl))
      (setq b (vl-remove-if-not (function (lambda ( x ) (and (collinear-pp (car a) (cadr a) (car x)) (collinear-pp (car a) (cadr a) (cadr x))))) tl))
      (setq tll (cons a tll))
      (if b
        (setq tl (vl-remove-if (function (lambda ( x ) (vl-some (function (lambda ( y ) (equal x y 1e-6))) b))) tl))
        (setq tl (cdr tl))
      )
    )
    tll
  )
 
  (defun unique ( lst / a ll )
    (while (setq a (car lst))
      (if (vl-some (function (lambda ( x ) (equal x a 1e-2))) (cdr lst))
        (setq ll (cons a ll) lst (vl-remove-if (function (lambda ( x ) (equal x a 1e-2))) (cdr lst)))
        (setq ll (cons a ll) lst (cdr lst))
      )
    )
    (reverse ll)
  )
 
  (defun inside-p ( p lw lwi )
    (< (distance p (vlax-curve-getclosestpointto lwi p)) (distance p (vlax-curve-getclosestpointto lw p)))
  )
 
  (defun distp2t ( p gg / i d )
    (if (setq i (inters p (polar p (+ (angle (car gg) (cadr gg)) (* 0.5 pi)) 1.0) (car gg) (cadr gg) nil))
      (setq d (distance p i))
    )
  )
 
  (defun _vl-sort ( lst func )
    (mapcar
      (function (lambda ( x ) (nth x lst)))
      (vl-sort-i lst func)
    )
  )
 
  (defun numbpos ( n len )
    (cond
      ( (< n len)
        n
      )
      ( (> n len)
        (- n len)
      )
      ( t 0 )
    )
  )
 
  (defun offd ( ip tl / ff d dl )
 
    (defun ff ( ip d )
      (if (not (chkcircinside-dist ip d))
        (progn
          (setq dl (vl-remove-if (function (lambda ( x ) (equal d x 1e-6))) dl))
          (ff ip
            (setq d
              (vl-some
                (function
                  (lambda ( x )
                    (if
                      (>
                        (-
                          (length dl)
                          (length (vl-remove-if (function (lambda ( y ) (equal x y 1e-5))) dl))
                        ) 2
                      )
                      x
                    )
                  )
                )
                (_vl-sort dl (function >))
              )
            )
          )
        )
        d
      )
    )
 
    (setq dl
      (mapcar
        (function
          (lambda ( x )
            (distance ip
              (inters
                ip
                (polar ip (+ (* 0.5 pi) (angle (car x) (cadr x))) 1.0)
                (car x)
                (polar (car x) (angle (car x) (cadr x)) 1.0)
                nil
              )
            )
          )
        )
        tl
      )
    )
    (setq d
      (vl-some
        (function
          (lambda ( x )
            (if
              (>
                (-
                  (length dl)
                  (length (vl-remove-if (function (lambda ( y ) (equal x y 1e-5))) dl))
                ) 2
              )
              x
            )
          )
        )
        (_vl-sort dl (function >))
      )
    )
    (ff ip d)
  )
 
  (defun chkcircinside-dist ( pp dist / ci ipp ippl params pts tst )
    (if (and pp dist)
      (progn
        (setq ci (entmakex (list (cons 0 "CIRCLE") (cons 10 pp) (cons 40 dist))))
        (setq params (list 0.0 (/ pi 6.0) (/ pi 3.0) (* 0.5 pi) (* 2.0 (/ pi 3.0)) (* 5.0 (/ pi 6.0)) pi (* 7.0 (/ pi 6.0)) (* 4.0 (/ pi 3.0)) (* 1.5 pi) (* 5.0 (/ pi 3.0)) (* 11.0 (/ pi 6.0))))
        (if (setq ipp (vlax-invoke (vlax-ename->vla-object ci) (quote intersectwith) (vlax-ename->vla-object lw) acextendnone))
          (progn
            (while ipp
              (setq ippl (cons (list (car ipp) (cadr ipp)) ippl))
              (setq ipp (cdddr ipp))
            )
            (if ippl
              (setq params (append params (mapcar (function (lambda ( x ) (vlax-curve-getparamatpoint ci x))) ippl)))
            )
            (setq pts (apply (function append) (mapcar (function (lambda ( x ) (list (vlax-curve-getpointatparam ci (- x 0.1)) (vlax-curve-getpointatparam ci (+ x 0.1))))) params)))
            (if (vl-every (function (lambda ( x ) (inside-p x lw lwi))) pts)
              (setq tst (cons t tst))
              (setq tst (cons nil tst))
            )
          )
          (progn
            (setq pts (apply (function append) (mapcar (function (lambda ( x ) (list (vlax-curve-getpointatparam ci (- x 0.1)) (vlax-curve-getpointatparam ci (+ x 0.1))))) params)))
            (if (vl-every (function (lambda ( x ) (inside-p x lw lwi))) pts)
              (setq tst (cons t tst))
              (setq tst (cons nil tst))
            )
          )
        )
        (if (and ci (not (vlax-erased-p ci)))
          (entdel ci)
        )
      )
    )
    (apply (function and) tst)
  )
 
  (defun chkcircinside ( pp tll / dd )
    (if (and pp tll)
      (if (setq dd (offd pp tll))
        (chkcircinside-dist pp dd)
      )
    )
  )
 
  (defun collinear-pp ( p1 p2 p3 )
    ( (lambda ( a b c )
        (or
          (equal (+ a b) c 1e-8)
          (equal (+ b c) a 1e-8)
          (equal (+ c a) b 1e-8)
        )
      )
      (distance p1 p2) (distance p2 p3) (distance p1 p3)
    )
  )
 
  (defun searchipss ( lst / x y ip d dm ipss )
    (setq ll lst dm 1e+308)
    (if (setq x (car lstt))
      (progn
        (setq ll (vl-remove-if (function (lambda ( z ) (vl-some (function (lambda ( a ) (equal (car z) a 1e-6))) (mapcar (function cadr) lil)))) ll))
        (while (setq y (car ll)) 
          (setq ll (cdr ll))
          (if
            (and x y 
              (setq ip (inters (car x) (polar (car x) (cadr x) 1.0) (car y) (polar (car y) (cadr y) 1.0) nil))
              (not (equal ip (car x) 1e-6))
              (not (equal ip (car y) 1e-6))
            )
            (if (not (equal (setq d (distance ip (caar lil))) 0.0 1e-3))
              (if (and d (< d dm) (chkcircinside ip utl))
                (setq ipss (list ip x y) dm d)
              )
            )
          )
        )
      )
    )
    ipss
  )
 
  (defun processlil ( t1 t2 ipss angp / n ang ips ip lilx )
    (if (and t1 t2 ipss (not (equal t1 t2 1e-6)))
      (progn
        (if (setq ip (inters (car t1) (cadr t1) (car t2) (cadr t2) nil))
          (setq ang (angle (car ipss) ip))
        )
        (if (equal ang angp 1e-6)
          (progn
            (setq n (length tl))
            (foreach tt tl
              (if
                (and
                  (vl-some (function (lambda ( x ) (equal x (car tt) 1e-6))) (mapcar (function cadr) lil))
                  (vl-some (function (lambda ( x ) (equal x (cadr tt) 1e-6))) (mapcar (function cadr) lil))
                )
                (setq tl (vl-remove tt tl))
              )
            )
            (if (= n (length tl))
              (cond
                ( (and (vl-some (function (lambda ( x ) (or (equal x (caar tl) 1e-6) (equal x (cadar tl) 1e-6)))) (mapcar (function cadr) lil)) (not (vl-some (function (lambda ( x ) (or (equal x (car (last tl)) 1e-6) (equal x (cadr (last tl)) 1e-6)))) (mapcar (function cadr) lil))))
                  (setq tl (cdr tl))
                )
                ( (and (vl-some (function (lambda ( x ) (or (equal x (car (last tl)) 1e-6) (equal x (cadr (last tl)) 1e-6)))) (mapcar (function cadr) lil)) (not (vl-some (function (lambda ( x ) (or (equal x (caar tl) 1e-6) (equal x (cadar tl) 1e-6)))) (mapcar (function cadr) lil))))
                  (setq tl (reverse (cdr (reverse tl))))
                )
              )
            )
            (if (= n (length tl))
              (setq tl (vl-remove (caddar lstt) tl))
            )
            (setq t1 (car tl))
            (setq t2 (last tl))
            (if (setq ip (inters (car t1) (cadr t1) (car t2) (cadr t2) nil))
              (setq ang (angle (car ipss) ip))
            )
          )
        )
        (setq ips (list (car ipss) ang t1 t2))
        (if ips
          (progn
            (setq lstt (cons ips lstt))
            (foreach p pl
              (if (equal (angle p (car ips)) (cadr (assoc p lst)) 1e-6)
                (if (not (vl-position (list (car ips) p) lil))
                  (setq lilx (cons (list (car ips) p) lilx))
                )
              )
            )
            (if (not (vl-position (list (car ips) (caar lil)) lil))
              (setq lilx (cons (list (car ips) (caar lil)) lilx))
            )
          )
        )
      )
    )
    (list lilx ang)
  )
 
  (defun process ( lst att / done flag ll ip x y ips ipss d pos zz dm angp lilxa tt tll t1 t2 k )
    (progn
      (while (not done)
        (setq ips nil)
        (if (not flag)
          (progn
            (setq ll lst ips nil dm 1e+308)
            (while (setq x (car ll))
              (setq ll (cdr ll))
              (setq y (car ll))
              (if (and x y (setq ip (inters (car x) (polar (car x) (cadr x) 1.0) (car y) (polar (car y) (cadr y) 1.0) nil)) (inside-p ip lw lwi))
                (if (< (setq d (min (distp2t ip (caddr x)) (distp2t ip (last y)))) dm)
                  (setq ips (list ip x y) dm d)
                )
              )
            )
            (setq pos (vl-position (cadr ips) lst))
            (if pos
              (repeat (numbpos pos (length pl))
                (setq lst (append (cdr lst) (list (car lst))))
                (setq tl (append (cdr tl) (list (car tl))))
                (setq pl (append (cdr pl) (list (car pl))))
                (setq pli (append (cdr pli) (list (car pli))))
              )
            )
            (setq tt (vl-remove-if (function (lambda ( x ) (= (length (vl-remove-if (function (lambda ( y ) (equal x y 1e-6))) (list (caddr (cadr ips)) (cadddr (cadr ips)) (caddr (caddr ips)) (cadddr (caddr ips))))) 2))) (list (caddr (cadr ips)) (cadddr (cadr ips)) (caddr (caddr ips)) (cadddr (caddr ips)))))
            (setq zz (car (vl-remove-if (function (lambda ( x ) (vl-some (function (lambda ( y ) (equal x y 1e-6))) tt))) (list (caddr (cadr ips)) (cadddr (cadr ips)) (caddr (caddr ips)) (cadddr (caddr ips))))))
            (setq tl (vl-remove-if (function (lambda ( x ) (equal x zz 1e-6))) tl))
            (if (and (car ips) (car (cadr ips)) (car (caddr ips)))
              (cond
                ( (= att 1)
                  (setq lil (cons (list (car ips) (car (caddr ips))) lil))
                  (setq lil (cons (list (car ips) (car (cadr ips))) lil))
                )
                ( t
                  (setq lil (cons (list (car ips) (car (cadr ips))) lil))
                  (setq lil (cons (list (car ips) (car (caddr ips))) lil))
                )
              )
            )
            (setq ang (angle (car ips) (inters (caar tt) (cadar tt) (caadr tt) (cadadr tt) nil)))
            (setq lstt (cons (list (car ips) ang (car tt) (cadr tt)) lstt))
          )
        )
        (setq flag t)
        (if (not k)
          (setq k 1)
          (setq k (1+ k))
        )
        (if (= k 1)
          (setq tl (vl-remove (caddar lstt) tl))
          (foreach tt tl
            (if
              (and
                (vl-some (function (lambda ( x ) (equal x (car tt) 1e-6))) (mapcar (function cadr) lil))
                (vl-some (function (lambda ( x ) (equal x (cadr tt) 1e-6))) (mapcar (function cadr) lil))
              )
              (setq tl (vl-remove tt tl))
            )
          )
        )
        (setq t1 (car tl))
        (setq t2 (last tl))
        (setq ipss nil)
        (setq ipss (searchipss lst))
        (if ipss
          (if (setq lilxa (processlil t1 t2 ipss (cadar lstt)))
            (setq lil (append (car lilxa) lil) ang (cadr lilxa))
          )
        )
        (if
          (or
            (= k (length pl))
            (vl-every (function (lambda ( x ) (vl-some (function (lambda ( y ) (equal x y 1e-6))) (mapcar (function cadr) lil)))) pl)
          )
          (setq done t)
        )
      )
      (unique lil)
    )
  )
 
  (or (and cad doc alo spc) (vl-load))
  (while (= 8 (logand 8 (getvar (quote undoctl))))
    (if (not (vl-cmdf "_.UNDO" "_E"))
      (if doc
        (vla-endundomark doc)
      )
    )
  )
  (if (not (vl-cmdf "_.UNDO" "_BE"))
    (if doc
      (vla-startundomark doc)
    )
  )
  (prompt "\nPick closed polygonal LWPOLYLINE on unlocked layer...")
  (if (setq s (ssget "_+.:E:S:L" (list (cons 0 "LWPOLYLINE") (cons -4 "&=") (cons 70 1) (cons -4 "<not") (cons -4 "<>") (cons 42 0.0) (cons -4 "not>"))))
    (progn
      (setq ti (car (_vl-times)))
      (setq lw (ssname s 0))
      (vlax-invoke (vlax-ename->vla-object lw) (quote offset) -1e-3)
      (setq lwi (entlast))
      (if (> (vlax-curve-getarea lwi) (vlax-curve-getarea lw))
        (progn
          (rlw lw)
          (entdel lwi)
          (vlax-invoke (vlax-ename->vla-object lw) (quote offset) -1e-3)
          (setq lwi (entlast))
        )
      )
      (setq pl (mapcar (function cdr) (vl-remove-if (function (lambda ( x ) (/= (car x) 10))) (entget lw))))
      (setq pli (mapcar (function cdr) (vl-remove-if (function (lambda ( x ) (/= (car x) 10))) (entget lwi))))
      (while (not (equal (car pl) (car pli) 0.1))
        (setq pli (append (cdr pli) (list (car pli))))
      )
      (setq tl (mapcar (function (lambda ( a b ) (list a b))) pl (append (cdr pl) (list (car pl)))))
      (setq utl (unioncollinearplaneprints tl))
      (setq lst (mapcar (function (lambda ( a b c d ) (list a (angle a b) c d))) pl pli (cons (last tl) (reverse (cdr (reverse tl)))) tl))
      (setq llst lst)
      (while (< att 3)
        (if (not att)
          (setq att 1)
          (setq att (1+ att))
        )
        (setq lst llst)
        (setq lil (process lst att))
        (if (= att 1)
          (setq lil1 lil)
          (setq lil2 lil)
        )
      )
      (if (> (length lil1) (length lil2))
        (setq lil lil1)
        (setq lil lil2)
      )
      (foreach li lil
        (if (and (car li) (cadr li) (not (equal (car li) (cadr li) 1e-6)))
          (entmake (list (cons 0 "LINE") (cons 10 (car li)) (cons 11 (cadr li))))
        )
      )
    )
  )
  (*error* nil)
)
 

Regards, stay well and happy (coding)...
M.R.

ribarm · « **Reply #276 on:** February 03, 2024, 10:21:40 PM »

I've compiled *.lsp files packed in .\2D\ribarm\...

*.des files are for BricsCAD
*.VLX files are for AutoCAD

It is actually just slightly faster then before, so I am hoping that someone working with *.arx, *.brx or *.dll will jump in and give it a try for those files that are compiled... 2droof-final.lsp does not need conversion as it's running fast enough that only searching errn, errm combination is unknown, but when it finds it - it's superfast...
Routines packed in *.ZIP you can find here : https://www.theswamp.org/index.php?topic=41837.msg619616#msg619616

So long from me, thanks in advance, M.R.

ribarm · « **Reply #277 on:** February 22, 2024, 11:44:14 AM »

I am pushing this topic from bottom to top... I said thanks in advance in hope that someone may come to solution with *.arx, *.brx, or *.dll...

EDIT : Meanwhile, I've removed my poor attempts and left only those things that are good... I've managed to speed up just slightly : roof2d-new-new-new-nn.lsp by changing (if) into (cond) statements and my last one is called : roof2d-new-new-new-nnn.lsp...
So basically I want speeding up even more faster : roof2d-new-new-new-nnn.lsp by using Dot Net or Object Arx... Also I want this if it's possible with : roof2d-new-new-solutions.lsp, but only if it doesn't disturb translator as it's even more complex than roof2d-new-new-new-nnn.lsp

Regards, M.R.

ribarm · « **Reply #278 on:** February 29, 2024, 09:19:47 AM »

I've run on example which it couldn't solve with previous release... I've fixed it and changed names of main files... Now they are :

- roof2d-new-nn.lsp (if variant)
- roof2d-new-nnn.lsp (cond (= t t) variant)
- roof2d-new-nnnn.lsp (cond t variant)
- roof2d-new-solutions.lsp (cond (= t t) variant)
- roof2d-new-solutions-n.lsp (cond t variant)
Those routines that can solve roof2d-mistake.dwg
And there are also old ones that can solve almost everything else (99%) - except roof2d-mistake.dwg
They start with :
- roof2d-new-new-*.lsp

In archive there you can find *.des and *.VLX of these mentioned *.lsp files...

So long from me,
Regards, stay well and happy...
M.R.

EDIT : Additional *.dwg for testing is posted here : https://www.theswamp.org/index.php?topic=59312.msg619513#msg619513

ribarm · « **Reply #279 on:** February 29, 2024, 07:08:17 PM »

I've updated roof2d*.lsp with just roof2d.lsp, roof2d.des and roof2d.VLX... It should solve everything, but I had to slow it down with testing subs for checking weather solution is good or bad... If it's bad, it restarts and finish as good... That is double timing if even more as it creates duplicate lines which are upon finish OVERKILL-ed...

Regards, M.R.

~~P.S. Can someone look at it and remove duplication, so that OVERKILL line doesn't need to be neccessary...~~

ribarm · « **Reply #280 on:** March 03, 2024, 11:01:52 AM »

In previous post are my latest revisions, and assuming to testing results posted on DWG here : https://www.theswamp.org/index.php?topic=59312.msg619513#msg619513 , my (cond) version is faster than (if) version, so I'd like that you download *.ZIP in previous post and translate "roof2d-new-nnnn.lsp" and if there are time (it works desiring speed) to translate "roof2d-new-solutions-n.lsp" into adequate *.arx, or *.brx, or *.dll for versions of AutoCAD 2022 and BricsCAD V23...

This all is just my humble request if someone have time or want to earn some reputation here on theswamp.org...

ribarm · « **Reply #281 on:** March 05, 2024, 01:48:35 PM »

Change of plan...
As far as I could test my versions, I've found too many lacks... So now request is to work with proved as good and that is chlh_jd's code that is checking errn and errm - loops until it finds correct solution... So we need translation "2droof-final.lsp" into corresponding *.arx, *.brx or *.dll...
You can see where mistakes in calculation with my versions are in this testing DWG and I suggest strongly that you download it as you should have something for checking... Link : https://www.theswamp.org/index.php?topic=59312.msg619513#msg619513

Regards,
M.R.

ribarm · « **Reply #282 on:** March 05, 2024, 03:03:14 PM »

I've made slight changes for person who download it lastly - there was 1 download...
Sorry, I can't test and correct so quickly...

M.R.

kdub_nz · « **Reply #283 on:** March 05, 2024, 03:51:44 PM »

I downloaded the drawing and the code.
Haven't looked at the code.

The times shown on the 'reasonably shaped' profiles is faster than I'd expected.
The times for the complex profiles is still pretty good, in my opinion.

Just how fast should these profiles be solved, in your expectation ?

The average breathing rate for healthy humans is between 12 and 20 breaths per minute
At a mean of 16 that is 3,750 milliseconds per breath.

If a program takes 3 breaths is it slow or is the problem data complicated ?

If it performs 7 times in one breath, is the program fast or is the problem data simple ?

If it fails, does the speed matter ?

Regards,

BIGAL · « **Reply #284 on:** March 05, 2024, 06:43:45 PM »

Agree with Kdub_nz what is fast ?

A task for a client 3 hours manual edit, first go 20 minutes, current version 2 minutes for same task, time includes popping Alert messages so user can see its working, 1000+ objects 5 steps. Alerts about 20 seconds apart. Could do acet progress bar but its fast enough.

A typical house is what maybe 8 roof panels max, mine only has 4. Your code would be almost instant at that level.

News:

Author Topic: ==={Challenge}===Find the ridge lines of sloped roof (Read 108251 times)

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

kdub_nz

Re: ==={Challenge}===Find the ridge lines of sloped roof

pkohut

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

kdub_nz

Re: ==={Challenge}===Find the ridge lines of sloped roof

BIGAL

Re: ==={Challenge}===Find the ridge lines of sloped roof