Topic: DRAWING USAGE TRACKING/LOGGING

[STEVEDALLAS]

This has probably been posted before, but...

Is there a way of tracking who had a drawing open last, etc.?
A program, plug-in, arx, lsp, orther?

We have drawings being worked on? It is getting to the point where we need to know who had it last, and when!

[TimSpangler]

I m sure that a lisp that loads every time a drawing is opened, that creates/ maintains a log in the directory of the drawing would work.  Time opened and by who.  It would at least show who opened the drawing.?

With the help of a reactor You could catch a close  or save and log the user id.?

Just thinking aloud...

[CAB]

Look here
http://www.theswamp.org/index.php?topic=2489.0

You can also search timesheet

[Matt__W]

It is getting to the point where we need to know who had it last, and when!

Sounds like better training is required.   



I've been using the OWNER and DATE MODIFIED columns of Windows Explorer.

[rkmcswain]

I m sure that a lisp that loads every time a drawing is opened, that creates/ maintains a log in the directory of the drawing would work.  Time opened and by who.  It would at least show who opened the drawing.?

Yes. We have used a system like this in the past. I've already forgotten why we enabled it at the time, but I do remember that it worked. Of course, if this is mission critical, then you would probably need something that logged it at the server level.

[mjfarrell]

Sounds like better training is required.   

Couldn't have said it better myself.                 

[MP]

Sounds like better training is required.

Agreed. However, when you're dealing with hundreds of CADD operators, many of which are contractors that parachute in and out of projects, that's not a blanket solution, nor a guarantee they'll honor provided training / standards. Augmenting same with logging is a good defence, allowing you these ease of identify who is violating training and standards for appropriate smack upside the head. Notwithstanding many other uses for logging.

[craigr]

We use the 'Revdate' command.

I have modified the 'save' button to do a 'Revdate' before saving the file. - Of course this doesn't work when they click the X in the upper right corner to close the file.

craigr

[jonesy]

I have to agree with MP.
While training is very important theres always someone who feels the need to do things their own way, meaning to put it right before it goes out.... then theres the looming deadlines issue where the boss in charge drops changes into the caddies lap "last minute" and no-time for  a standards check....
While these issues shouldnt cause problems, I have found that people can/will/do cut corners to please management and get the jobs out on time.
I hate shoddy work, and I have tried to track down the workers on a scheme many times to find out where and when the drawing went wrong mainly to help identify WHO needs training in what subjects...

[deegeecees]

You could "roll your own" tracking system...


...just sayin' is all.

[ronjonp]

You could add something like this to startup:

Code: [Select]

(defun rjp-log2file (path / fname dt tm dttm)
  (setq dt   (rtos (fix (getvar 'cdate)) 2 0)
tm   (rtos (rem (getvar 'cdate) 1) 2 6)
dttm (strcat (substr dt 5 2)
     "-"
     (substr dt 7 2)
     "-"
     (substr dt 1 4)
     "-"
     (substr tm 3 2)
     ":"
     (substr tm 5 2)
     )
  )
  (if (and (= (getvar 'dwgtitled) 1)
   (vl-file-directory-p path)
   (setq fname (open (strcat path "\\DWGS_Opened.log") "a"))
      )
    (progn
      (write-line
(strcat (getenv "username")
","
dttm
","
(getvar 'dwgprefix)
""
(getvar 'dwgname)
)
fname
      )
      (close fname)
    )
  )
  (princ)
)
(rjp-log2file "c:")

[deegeecees]

^^^Exactly!^^^

[TimSpangler]

Yeah just like that ^^^^  But we have people that open dwg's all the time with out making changes.  A reactor may be needed to  catch a save??

[T.Willey]

Here is a reactor I did a while ago.  It tells you how long a drawing has been open, and if it was saved.  It could be better, but it was just a test back when I wanted to look into reactors.  Change the file name/location to suit you needs.

Code: [Select]

(if (not GlbVarTimeString)
    (progn
        (setq DateStr (rtos (getvar "cdate") 2 16))
        (setq GlbVarTimeString
            (strcat
                (substr DateStr 5 2)
                "/"
                (substr DateStr 7 2)
                "/"
                (substr DateStr 1 4)
                ","
                (substr DateStr 10 2)
                ":"
                (substr DateStr 12 2)
                ","
                (getvar "dwgprefix")
                (getvar "dwgname")
                ","
            )
        )
        (setq DateStr nil)
    )
)
(if (not GlbReactorBeginClose)
    (setq GlbReactorBeginClose (vlr-dwg-reactor "TimeSheet" '((:vlr-BeginClose . DwgToBeClosed))))
)
(if (not GlbReactorSaveComplete)
    (setq GlbReactorSaveComplte (vlr-dwg-reactor "TimeSheet" '((:vlr-SaveComplete . SaveCompleted))))
)
;-----------------------------------------------------------------------------------------------------------
(defun SaveCompleted (React DwgName / DateStr)
   
    (setq DateStr (rtos (getvar "cdate") 2 16))
    (setq GlbVarSaveTime (strcat (substr DateStr 10 2) ":" (substr DateStr 12 2) ","))
)
;-------------------------------------------------------------------------------------------------------------
(defun DwgToBeClosed (React DwgName / DateStr TextFile New Opened)
   
    (if (equal (getvar "dwgtitled") 1)
        (progn
            (setq DateStr (rtos (getvar "cdate") 2 16))
            [color=red](if (not (setq TextFile (findfile "TimeSheet.csv")))[/color]
                (progn
                    (setq New T)
                    [color=red](setq TextFile "C:\\Custom2006\\TimeSheet.csv")[/color]
                )
            )
            (setq Opened (open TextFile "a"))
            (if New
                (write-line "Date,Time Opened,File Name,Last Saved,Closed Time" Opened)
            )
            (write-line
                (strcat
                    GlbVarTimeString
                    (if GlbVarSaveTime
                        GlbVarSaveTime
                        "Not saved!,"
                    )
                    (substr DateStr 10 2)
                    ":"
                    (substr DateStr 12 2)
                )
                Opened
            )
            (close Opened)
        )
    )
)


[alanjt]

here's one i posted a while back.

http://www.theswamp.org/index.php?topic=22668.0