; Marc'Antonio Alessi, Italy - http://alessi.xoom.it//alessi/
;
; Function: ALE_UtlFilesGetFolders
;
; Version 1.00 - 09/06/2006
;
; Description:
; Returns a list of subdirectories found in the specified directory,
; the return values contain trailing double-backslashes (\\)
; if RecFlg = T > scan the entire structure
;
; Arguments:
; In_Pat = A string containing an existing path
; do not need trailing double-backslashes
; if nil or "" uses the current directory.
; RecFlg = flag > T = scan the entire structure
; > nil = do not scan
;
; Examples:
; (ALE_UtlFilesGetFolders "C:\\Temp" nil)
; (ALE_UtlFilesGetFolders "C:\\Temp\\" T)
;
; Return Values:
; [LIST] A list of subdirectories if successful.
;
(defun ALE_UtlFilesGetFolders (In_Pat RecFlg / FilNam OutLst)
(or
(wcmatch In_Pat "*[\\/]")
(setq In_Pat (strcat In_Pat "\\"))
)
(if RecFlg
(ALE_UtlFilesGetFolders_Aux In_Pat)
(foreach ForElm (cddr (vl-directory-files In_Pat nil -1))
(setq OutLst (cons (strcat In_Pat ForElm "\\") OutLst))
)
)
(reverse OutLst)
)
;
; Function: ALE_UtlFilesGetFolders_Aux
; Auxiliary function for: ALE_UtlFilesGetFolders
;
(defun ALE_UtlFilesGetFolders_Aux (In_Pat)
(foreach ForElm (cddr (vl-directory-files In_Pat nil -1))
(setq
FilNam (strcat In_Pat ForElm "\\")
OutLst (cons FilNam OutLst)
)
(ALE_UtlFilesGetFolders_Aux FilNam)
)
)
;
; Function: ALE_UtlFilesGetFiles
;
; Version 1.01 - 09/06/2006
;
; Description:
; Returns a list of files found in the specified directory,
; if RecFlg = T > scan the entire structure
;
; Arguments:
; In_Pat = A string containing an existing path
; do not need trailing double-backslashes
;
; FlsSpc = The desired file or files, can contain wildcard characters
; ("*" and "?"), all files > *.*
; RecFlg = flag > T = scan the entire structure
; > nil = do not scan
;
; Examples:
; (ALE_UtlFilesGetFiles "C:\\Temp\\" "*.dwg" nil)
; (ALE_UtlFilesGetFiles "C:\\Temp\\" "*.dwg" T)
;
; Return Values:
; [LIST] A list of files if successful
;
(defun ALE_UtlFilesGetFiles (In_Pat FlsSpc RecFlg / OutLst)
(or
(wcmatch In_Pat "*[\\/]")
(setq In_Pat (strcat In_Pat "\\"))
)
(foreach ForElm (vl-directory-files In_Pat FlsSpc 1)
(setq OutLst (cons (strcat In_Pat ForElm) OutLst))
)
(if RecFlg
(foreach ForElm (ALE_UtlFilesGetFolders In_Pat RecFlg)
(foreach ForEl2 (vl-directory-files ForElm FlsSpc 1)
(setq OutLst (cons (strcat ForElm ForEl2) OutLst))
)
)
)
(reverse OutLst)
)
