Topic: Drafting Settings

[Coder]

Hello .

The value of my current osmode is 4143 and the MidPoint option is checked ( is on ) .

How can I know MidPoint option is check or not in my drafting settings through the value of the osmode  ?

Many thanks

[kruuger]

Hello .

The value of my current osmode is 4143 and the MidPoint option is checked ( is on ) .

How can I know MidPoint option is check or not in my drafting settings through the value of the osmode  ?

Many thanks

Code: [Select]

(defun c:test ()
  (if (zerop (logand 2 (getvar "osmode")))
    (princ "\n MID snap off")
    (princ "\n MID snap on")
  )
  (princ)
)k.

[pBe]

another

(setvar 'osmode (boole 6 2 (getvar 'osmode)))

Toggle MID on and off

[Coder]

Thank you so much guys ,

That's great .

[CAB]

Here is an oldie.

Code: [Select]

;;  CAB  10/5/2006
;;
;;  Function to return the current osmode setting in the form of a string
;;  If (getvar "osmode") = 175
;;  (get_osmode)  returns   "_end,_mid,_cen,_nod,_int,_per"
;;  Usage
;;  (osnap (getpoint) (get_osmode))
;;
(defun get_osmode (/ cur_mode mode$)
  (setq mode$ "")
  (if (< 0 (setq cur_mode (getvar "osmode")) 16383)
    (mapcar
      '(lambda (x)
         (if (not (zerop (logand cur_mode (car x))))
           (setq mode$ (strcat mode$ (cadr x)))
         )
       )
      '((0 "_non,")  (1 "_end,")   (2 "_mid,")   (4 "_cen,")   (8 "_nod,")
        (16 "_qua,") (32 "_int,")  (64 "_ins,")  (128 "_per,") (256 "_tan,")
        (512 "_nea,")(1024 "_qui,")(2048 "_app,")(4096 "_ext,")(8192 "_par")
       )
    )
  )
  mode$
)

[Coder]

Very nice routine Mr CAB.

Thanks a lot .

[CAB]

You're welcome.

[Dinosaur]

Hello .

The value of my current osmode is 4143 and the MidPoint option is checked ( is on ) .

How can I know MidPoint option is check or not in my drafting settings through the value of the osmode  ?

Many thanks

All are fine codes, but I believe that every possible combination of O-SNAP settings has a unique numerical value for OSMODE.  Thus, if your OSMODE value is indeed found to be 4143 your MidPoint setting must be checked or "ON" by definition.

[mjfarrell]

Hello .


How can I know MidPoint option is check or not ...??

when it doesn't SNAP to an object's Mid-point would be a good check.