Topic: ssdel or counting

[curmudgeon]

I create a selection set for one purpose only. the way I started out was

Code: [Select]

(setq count 0)
   (repeat (sslength them)
    (setq ent (entget (ssname them count))
  pt_lst nil)

    (cond (/= "TEXT" (cdr (assoc 8 ent)))
  (foreach a ent
   (if (= (car a) 10)
     (setq pt_lst (append pt_lst (list (cdr a))))
   )
  )
    );; end cond
(setq count (+ 1 count))
);;; end repeat
which would work. but I wonder, should I rather skip setting a variable count and just ssdel right before the loop repeats?
I am trying to build good habits because bad ones are so hard to break, and I am not getting any younger.
 :whistle:

[T.Willey]

I don't really think it matters that much.  If I'm not going to use the selection set again, or won't want to use it after the command finishes, then I use ssdel, force of habit, but if you might want to reuse the selection set, then use a counter.

[Lee Mac]

I don't normally use a repeat method to shuffling through SelectionSets, I normally convert the set into a list of entities which is much more manageable, as lists are the basis of LISP programming. Also, the repeat method uses integers to shuffle through the Entity Names, and integers have a 32767 limit.

for example:

Code: [Select]

(vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))

Will return a list of entities in the selection set (ss).

If you have retrieved the selection set through (ssget "_X") method, then there is no need for the vl-remove-if:

hence:

Code: [Select]

(mapcar 'cadr (ssnamex ss))

Hope this helps  

Lee

[CAB]

WHILE is faster.

My choice:

Code: [Select]

(defun c:test(/ i ss ent elst pt_lst)
  (defun get_vertex (elst)
    (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= 10 (car x))) elst))
  )
(setq ss (ssget))
(setq i -1)
(while (setq ent (ssname ss (setq i (1+ i))))
  (if (/= "TEXT" (assoc 8 (setq elst (entget ent))))
     (setq pt_lst
            (cond
              (pt_lst (append (get_vertex elst) pt_lst))
              ((get_vertex elst))))
  )
)
(princ)
)
<edit: bug fix>

[ronjonp]

And my two cents  

Code: [Select]

(if (setq ss (ssget '((8 . "~TEXT"))))
  (progn ;;repeat
         (setq n -1)
         (repeat (sslength ss)
           (setq e (ssname ss (setq n (1+ n))))
           (setq out1 (cons e out1))
         )
         (setq n -1)
         ;;while
         (while (setq e (ssname ss (setq n (1+ n))))
           (setq out2 (cons e out2))
           (ssdel e ss)
         )
         ;;mapcar
         (setq out3 (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))))
  )
)


[Lee Mac]

Nice one Ron, just collaborating the three methods... 

[curmudgeon]

thanks guys. I need time to digest....
 

[gile]

Hi,

I don't normally use a repeat method to shuffling through SelectionSets, I normally convert the set into a list of entities which is much more manageable, as lists are the basis of LISP programming.

You can have a look at this post, even for building a list while and repeat are faster.

[Lee Mac]

Quite a difference I see...  thanks Gile